Demo_FileReadArray - script para MetaTrader 5

El script realiza la lectura de datos con los precios Bid y Ask desde el archivo creado en el proceso de trabajo del Asesor Experto Demo_FileWriteArray. Se realiza la lectura del archivo binario en la carpeta local del terminal, cuya ubicación se obtiene llamando a la función TerminalInfoString().

PrintFormat("Ruta hacia la carpeta local del terminal: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH)); 

Se lee todo el contenido del archivo usando la función FileReadArray(), depués de lo cual los datos se visualizan en el ciclo.

Código:

//--- muestra la ventana con los parámetros de entrada al lanzar el script
#property script_show_inputs
//--- parámetros de entrada
input string InpFileName="data.bin";
input string InpDirectoryName="SomeFolder";
//+------------------------------------------------------------------+
//| Estructura para almacenar los datos de los precios               |
//+------------------------------------------------------------------+
struct prices
  {
   datetime          date; // fecha
   double            bid;  // precio Bid
   double            ask;  // precio Ask
  };
//+------------------------------------------------------------------+
//| Función de arranque del script                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- matriz de estructuras
   prices arr[];
//--- ruta del archivo
   string path=InpDirectoryName+"//"+InpFileName;
//--- abre el archivo
   ResetLastError();
   int file_handle=FileOpen(path,FILE_READ|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      //--- carga todos los datos del archivo eb la matriz
      FileReadArray(file_handle,arr);
      //--- obtiene el tamaño de la matriz
      int size=ArraySize(arr);
      //--- imprime los datos de la matriz
      for(int i=0;i<size;i++)
         Print("fecha = ",arr[i].date," Bid = ",arr[i].bid," Ask = ",arr[i].ask);
      Print("Cantidad total de datos = ",size);
      //--- cierra el archivo
      FileClose(file_handle);
     }
   else
      Print("Falló la apertura del archivo, error ",GetLastError());
  }