Demo_FileReadArray - script para MetaTrader 5

O script executa a leitura de dados preços Bid e Ask a partir do arquivo que foi obtido no processo de trabalho do Expert Advisor Demo_FileWriteArray. Leitura realizada a partir do arquivo binário no subdiretório da pasta local do terminal, cuja localização pode ser obtido chamando a função TerminalInfoString()

PrintFormat("O caminho para a pasta local do terminal: %s\\Arquivos\\",TerminalInfoString(TERMINAL_DATA_PATH)); 

Lê o conteúdo do arquivo utilizando a função FileReadArray(), depois de recebidos os dados, eles serão exibidos no ciclo.

Código:

//--- exibir a janela de parâmetros de entrada ao lançar o script
#property script_show_inputs
//--- parâmetros de entrada
input string InpFileName="dados.bin";
input string InpDirectoryName="AlgumaPasta";
//+------------------------------------------------------------------+
//|Estrutura para armazenar dados do preço                           |
//+------------------------------------------------------------------+
struct prices
  {
   datetime          date; // data
   double            bid;  // Bid price
   double            ask;  // Ask price
  };
//+------------------------------------------------------------------+
//| Função iniciar do Script de programa                             |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- estrututa array
   prices arr[];
//--- caminho do arquivo
   string path=InpDirectoryName+"//"+InpFileName;
//--- abrir o arquivo
   ResetLastError();
   int file_handle=FileOpen(path,FILE_READ|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      //--- ler todos os dados do arquivo para o array
      FileReadArray(file_handle,arr);
      //--- obter o tamanho do array
      int size=ArraySize(arr);
      //--- dados de impressão a partir do array
      for(int i=0;i<size;i++)
         Print("Data = ",arr[i].date," Bid = ",arr[i].bid," Ask = ",arr[i].ask);
      Print("Dados total = ",size);
      //--- fechar o arquivo
      FileClose(file_handle);
     }
   else
      Print("Falhou a abertura do arquivo, erro",GetLastError());
  }