matrix weights1, weights2, weights3; // ağırlıkların matrisleri
matrix output1, output2, result; // sinir katmanı çıktılarının matrisleri
input int layer1 = 200; // ilk gizli katmanın büyüklüğü
input int layer2 = 200; // ikinci gizli katmanın büyüklüğü
input int Epochs = 20000; // eğitim dönemlerinin sayısı
input double lr = 3e-6; // öğrenme hızı
input ENUM_ACTIVATION_FUNCTION ac_func = AF_SWISH; // aktivasyon fonksiyonu
//+------------------------------------------------------------------+
//| Komut dosyası başlatma fonksiyonu |
//+------------------------------------------------------------------+
void OnStart()
{
//---
int train = 1000; // eğitim örneklemi büyüklüğü
int test = 10; // test örneklemi büyüklüğü
matrix m_data, m_target;
//--- eğitim örneklemi oluştur
if(!CreateData(m_data, m_target, train))
return;
//--- modeli eğit
if(!Train(m_data, m_target, Epochs))
return;
//--- test örneklemi oluştur
if(!CreateData(m_data, m_target, test))
return;
//--- modeli test et
Test(m_data, m_target);
}
//+------------------------------------------------------------------+
//| Örneklem oluşturma metodu |
//+------------------------------------------------------------------+
bool CreateData(matrix &data, matrix &target, const int count)
{
//--- başlangıç veri ve sonuç matrislerini başlat
if(!data.Init(count, 3) || !target.Init(count, 1))
return false;
//--- başlangıç veri matrisini rastgele değerlerle doldur
data.Random(-10, 10);
//--- eğitim örneklemi için hedef değerleri hesapla
vector X1 = MathPow(data.Col(0) + data.Col(1) + data.Col(1), 2);
vector X2 = MathPow(data.Col(0), 2) + MathPow(data.Col(1), 2) + MathPow(data.Col(2), 2);
if(!target.Col(X1 / X2, 0))
return false;
//--- sonucu geri döndür
return true;
}
//+------------------------------------------------------------------+
//| Model eğitimi metodu |
//+------------------------------------------------------------------+
bool Train(matrix &data, matrix &target, const int epochs = 10000)
{
//--- modeli oluştur
if(!CreateNet())
return false;
//--- modeli eğit
for(int ep = 0; ep < epochs; ep++)
{
//--- ileri besleme geçişi
if(!FeedForward(data))
return false;
PrintFormat("Epoch %d, loss %.5f", ep, result.Loss(target, LOSS_MSE));
//--- geri yayılım ve ağırlık matrisinin güncellenmesi
if(!Backprop(data, target))
return false;
}
//--- sonucu geri döndür
return true;
}
//+------------------------------------------------------------------+
//| Model oluşturma metodu |
//+------------------------------------------------------------------+
bool CreateNet()
{
//--- ağırlık matrislerini başlat
if(!weights1.Init(4, layer1) || !weights2.Init(layer1 + 1, layer2) || !weights3.Init(layer2 + 1, 1))
return false;
//--- ağırlık matrislerini rastgele değerlerle doldur
weights1.Random(-0.1, 0.1);
weights2.Random(-0.1, 0.1);
weights3.Random(-0.1, 0.1);
//--- sonucu geri döndür
return true;
}
//+------------------------------------------------------------------+
//| İleri besleme metodu |
//+------------------------------------------------------------------+
bool FeedForward(matrix &data)
{
//--- başlangıç veri büyüklüğünü kontrol et
if(data.Cols() != weights1.Rows() - 1)
return false;
//--- ilk sinir katmanını hesapla
matrix temp = data;
if(!temp.Resize(temp.Rows(), weights1.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights1.Rows() - 1))
return false;
output1 = temp.MatMul(weights1);
//--- aktivasyon fonksiyonunu hesapla
if(!output1.Activation(temp, ac_func))
return false;
//--- ikinci sinir katmanını hesapla
if(!temp.Resize(temp.Rows(), weights2.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights2.Rows() - 1))
return false;
output2 = temp.MatMul(weights2);
//--- aktivasyon fonksiyonunu hesapla
if(!output2.Activation(temp, ac_func))
return false;
//--- üçüncü sinir katmanını hesapla
if(!temp.Resize(temp.Rows(), weights3.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights3.Rows() - 1))
return false;
result = temp.MatMul(weights3);
//--- sonucu geri döndür
return true;
}
//+------------------------------------------------------------------+
//| Geri yayılım metodu |
//+------------------------------------------------------------------+
bool Backprop(matrix &data, matrix &target)
{
//--- hedef değerler matrisinin büyüklüğünü kontrol et
if(target.Rows() != result.Rows() ||
target.Cols() != result.Cols())
return false;
//--- hesaplanan değerlerin hedeften sapmasını belirle
matrix loss = (target - result) * 2;
//--- gradyanı önceki katmana yay
matrix gradient = loss.MatMul(weights3.Transpose());
//--- son katmanın ağırlık matrisini güncelle
matrix temp;
if(!output2.Activation(temp, ac_func))
return false;
if(!temp.Resize(temp.Rows(), weights3.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights3.Rows() - 1))
return false;
weights3 = weights3 + temp.Transpose().MatMul(loss) * lr;
//--- aktivasyon fonksiyonunun türeviyle hata gradyanını ayarla
if(!output2.Derivative(temp, ac_func))
return false;
if(!gradient.Resize(gradient.Rows(), gradient.Cols() - 1))
return false;
loss = gradient * temp;
//--- gradyanı bir alt katmana yay
gradient = loss.MatMul(weights2.Transpose());
//--- ikinci gizli katmanın ağırlık matrisini güncelle
if(!output1.Activation(temp, ac_func))
return false;
if(!temp.Resize(temp.Rows(), weights2.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights2.Rows() - 1))
return false;
weights2 = weights2 + temp.Transpose().MatMul(loss) * lr;
//--- aktivasyon fonksiyonunun türeviyle hata gradyanını ayarla
if(!output1.Derivative(temp, ac_func))
return false;
if(!gradient.Resize(gradient.Rows(), gradient.Cols() - 1))
return false;
loss = gradient * temp;
//--- ilk gizli katmanın ağırlık matrisini güncelle
temp = data;
if(!temp.Resize(temp.Rows(), weights1.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights1.Rows() - 1))
return false;
weights1 = weights1 + temp.Transpose().MatMul(loss) * lr;
//--- sonucu geri döndür
return true;
}
//+------------------------------------------------------------------+
//| Model test etme metodu |
//+------------------------------------------------------------------+
bool Test(matrix &data, matrix &target)
{
//--- test verileri üzerinde ileri besleme
if(!FeedForward(data))
return false;
//--- model hesaplama sonuçlarını ve doğru değerleri yazdır
PrintFormat("Test loss %.5f", result.Loss(target, LOSS_MSE));
ulong total = data.Rows();
for(ulong i = 0; i < total; i++)
PrintFormat("(%.2f + %.2f + %.2f)^2 / (%.2f^2 + %.2f^2 + %.2f^2) = Net %.2f, Target %.2f", data[i, 0], data[i, 1], data[i, 2],
data[i, 0], data[i, 1], data[i, 2], result[i, 0], target[i, 0]);
//--- sonucu geri döndür
return true;
}
//+------------------------------------------------------------------+
|