matrix weights1, weights2, weights3; // Matrizen der Gewichte
matrix output1, output2, result; // Matrizen der Ausgaben der neuronalen Schicht
input int layer1 = 200; // die Größe der ersten verdeckten Schicht
input int layer2 = 200; // die Größe der zweiten verdeckten Schicht
input int Epochs = 20000; // die Anzahl der Trainingsepochen
input double lr = 3e-6; // Lernrate
input ENUM_ACTIVATION_FUNCTION ac_func = AF_SWISH; // Aktivierungsfunktion
//+------------------------------------------------------------------+
//| Script start Funktion |
//+------------------------------------------------------------------+
void OnStart()
{
//---
int train = 1000; // Größe des Trainingssatzes
int test = 10; // Größe der Teststichprobe
matrix m_data, m_target;
//--- generieren einer Teststichprobe
if(!CreateData(m_data, m_target, train))
return;
//--- Modelltraining
if(!Train(m_data, m_target, Epochs))
return;
//--- generieren der Teststichprobe
if(!CreateData(m_data, m_target, test))
return;
//--- Test des Modells
Test(m_data, m_target);
}
//+------------------------------------------------------------------+
//| Erstellen der Stichprobendaten |
//+------------------------------------------------------------------+
bool CreateData(matrix &data, matrix &target, const int count)
{
//--- Initialisierung der Ausgangsdaten und der Ergebnismatrix
if(!data.Init(count, 3) || !target.Init(count, 1))
return false;
//--- Füllen der Matrix für die Anfangswerte mit Zufallszahlen
data.Random(-10, 10);
//--- Berechnen der Zielwerte für die Trainingsstichprobe
vector X1 = MathPow(data.Col(0) + data.Col(1) + data.Col(1), 2);
vector X2 = MathPow(data.Col(0), 2) + MathPow(data.Col(1), 2) + MathPow(data.Col(2), 2);
if(!target.Col(X1 / X2, 0))
return false;
//--- Ergebnisrückgabe
return true;
}
//+------------------------------------------------------------------+
//| Trainingsmethode des Models |
//+------------------------------------------------------------------+
bool Train(matrix &data, matrix &target, const int epochs = 10000)
{
//--- Modell erstellen
if(!CreateNet())
return false;
//--- Modelltraining
for(int ep = 0; ep < epochs; ep++)
{
//--- Vorwärtsdurchlauf
if(!FeedForward(data))
return false;
PrintFormat("Epoch %d, loss %.5f", ep, result.Loss(target, LOSS_MSE));
//--- Backpropagation und Update der Gewichtsmatrix
if(!Backprop(data, target))
return false;
}
//--- Ergebnisrückgabe
return true;
}
//+------------------------------------------------------------------+
//| Methode für die Modellerstellung |
//+------------------------------------------------------------------+
bool CreateNet()
{
//--- Initialisierung der Gewichtsmatrizen
if(!weights1.Init(4, layer1) || !weights2.Init(layer1 + 1, layer2) || !weights3.Init(layer2 + 1, 1))
return false;
//--- Füllen der Gewichtsmatrizen mit Zufallszahlen
weights1.Random(-0.1, 0.1);
weights2.Random(-0.1, 0.1);
weights3.Random(-0.1, 0.1);
//--- Ergebnisrückgabe
return true;
}
//+------------------------------------------------------------------+
//| Feedforward-Methode |
//+------------------------------------------------------------------+
bool FeedForward(matrix &data)
{
//--- Prüfen der Größe der Ausgangsdaten
if(data.Cols() != weights1.Rows() - 1)
return false;
//--- Berechnen der ersten neuronalen Schicht
matrix temp = data;
if(!temp.Resize(temp.Rows(), weights1.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights1.Rows() - 1))
return false;
output1 = temp.MatMul(weights1);
//--- Berechnen der Aktivierungsfunktion
if(!output1.Activation(temp, ac_func))
return false;
//--- Berechnen der zweiten neuronalen Schicht
if(!temp.Resize(temp.Rows(), weights2.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights2.Rows() - 1))
return false;
output2 = temp.MatMul(weights2);
//--- Berechnen der Aktivierungsfunktion
if(!output2.Activation(temp, ac_func))
return false;
//--- Berechnen der dritten neuronalen Schicht
if(!temp.Resize(temp.Rows(), weights3.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights3.Rows() - 1))
return false;
result = temp.MatMul(weights3);
//--- Ergebnisrückgabe
return true;
}
//+------------------------------------------------------------------+
//| Backpropagation-Methode |
//+------------------------------------------------------------------+
bool Backprop(matrix &data, matrix &target)
{
//--- Prüfen der Größe der Matrix für die Zielwerte
if(target.Rows() != result.Rows() ||
target.Cols() != result.Cols())
return false;
//--- Berechnen der Ableitung der berechneten Zielwerte
matrix loss = (target - result) * 2;
//--- Übertragen der Gradienten zur vorherigen Schicht
matrix gradient = loss.MatMul(weights3.Transpose());
//--- Update der Gewichtsmatrix der letzten Schicht
matrix temp;
if(!output2.Activation(temp, ac_func))
return false;
if(!temp.Resize(temp.Rows(), weights3.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights3.Rows() - 1))
return false;
weights3 = weights3 + temp.Transpose().MatMul(loss) * lr;
//--- Anpassung des Fehlergradienten durch die Ableitung der Aktivierungsfunktion
if(!output2.Derivative(temp, ac_func))
return false;
if(!gradient.Resize(gradient.Rows(), gradient.Cols() - 1))
return false;
loss = gradient * temp;
//--- Übertragen der Gradienten der tieferen Schicht
gradient = loss.MatMul(weights2.Transpose());
//--- Update der Gewichtsmatrix der zweiten verdeckten Schicht
if(!output1.Activation(temp, ac_func))
return false;
if(!temp.Resize(temp.Rows(), weights2.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights2.Rows() - 1))
return false;
weights2 = weights2 + temp.Transpose().MatMul(loss) * lr;
//--- Anpassung des Fehlergradienten durch die Ableitung der Aktivierungsfunktion
if(!output1.Derivative(temp, ac_func))
return false;
if(!gradient.Resize(gradient.Rows(), gradient.Cols() - 1))
return false;
loss = gradient * temp;
//--- Update der Gewichtsmatrix der ersten verdeckten Schicht
temp = data;
if(!temp.Resize(temp.Rows(), weights1.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights1.Rows() - 1))
return false;
weights1 = weights1 + temp.Transpose().MatMul(loss) * lr;
//--- Ergebnisrückgabe
return true;
}
//+------------------------------------------------------------------+
//| Testmethode des Models |
//+------------------------------------------------------------------+
bool Test(matrix &data, matrix &target)
{
//--- Feedforward der Testdaten
if(!FeedForward(data))
return false;
//--- Ausdruck der Ergebnisse der Modellberechnung und der tatsächlichen Werte
PrintFormat("Test loss %.5f", result.Loss(target, LOSS_MSE));
ulong total = data.Rows();
for(ulong i = 0; i < total; i++)
PrintFormat("(%.2f + %.2f + %.2f)^2 / (%.2f^2 + %.2f^2 + %.2f^2) = Net %.2f, Target %.2f", data[i, 0], data[i, 1], data[i, 2],
data[i, 0], data[i, 1], data[i, 2], result[i, 0], target[i, 0]);
//--- Ergebnisrückgabe
return true;
}
//+------------------------------------------------------------------+
|