matrix weights1, weights2, weights3; // 重みの行列
matrix output1, output2, result; // ニューラル層出力の行列
input int layer1 = 200; // 最初の隠れ層のサイズ
input int layer2 = 200; // 2番目の隠れ層のサイズ
input int Epochs = 20000; // トレーニングエポック数
input double lr = 3e-6; // 学習率
input ENUM_ACTIVATION_FUNCTION ac_func = AF_SWISH; // 活性化関数
//+------------------------------------------------------------------+
//| スクリプトを開始する関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//---
int train = 1000; // トレーニングサンプルサイズ
int test = 10; // テストサンプルサイズ
matrix m_data, m_target;
//--- トレーニングサンプルを生成する
if(!CreateData(m_data, m_target, train))
return;
//--- モデルをトレーニングする
if(!Train(m_data, m_target, Epochs))
return;
//--- テストサンプルを生成する
if(!CreateData(m_data, m_target, test))
return;
//--- モデルをテストする
Test(m_data, m_target);
}
//+------------------------------------------------------------------+
//| サンプル生成メソッド |
//+------------------------------------------------------------------+
bool CreateData(matrix &data, matrix &target, const int count)
{
//--- 初期データと結果行列を初期化する
if(!data.Init(count, 3) || !target.Init(count, 1))
return false;
//--- 初期データ行列をランダムな値で埋める
data.Random(-10, 10);
//--- トレーニングサンプルの目標値を計算する
vector X1 = MathPow(data.Col(0) + data.Col(1) + data.Col(1), 2);
vector X2 = MathPow(data.Col(0), 2) + MathPow(data.Col(1), 2) + MathPow(data.Col(2), 2);
if(!target.Col(X1 / X2, 0))
return false;
//--- 結果を返す
return true;
}
//+------------------------------------------------------------------+
//| モデルトレーニングメソッド |
//+------------------------------------------------------------------+
bool Train(matrix &data, matrix &target, const int epochs = 10000)
{
//--- モデルを作成する
if(!CreateNet())
return false;
//--- モデルをトレーニングする
for(int ep = 0; ep < epochs; ep++)
{
//--- フィードフォワードパス
if(!FeedForward(data))
return false;
PrintFormat("Epoch %d, loss %.5f", ep, result.Loss(target, LOSS_MSE));
//--- 重み行列の逆伝播と更新
if(!Backprop(data, target))
return false;
}
//--- 結果を返す
return true;
}
//+------------------------------------------------------------------+
//| モデル作成メソッド |
//+------------------------------------------------------------------+
bool CreateNet()
{
//--- 重み行列を初期化する
if(!weights1.Init(4, layer1) || !weights2.Init(layer1 + 1, layer2) || !weights3.Init(layer2 + 1, 1))
return false;
//--- 重み行列にランダムな値を書き込む
weights1.Random(-0.1, 0.1);
weights2.Random(-0.1, 0.1);
weights3.Random(-0.1, 0.1);
//--- 結果を返す
return true;
}
//+------------------------------------------------------------------+
//| フィードフォワードメソッド |
//+------------------------------------------------------------------+
bool FeedForward(matrix &data)
{
//--- 初期データサイズを確認する
if(data.Cols() != weights1.Rows() - 1)
return false;
//--- 1番目のニューラル層を計算する
matrix temp = data;
if(!temp.Resize(temp.Rows(), weights1.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights1.Rows() - 1))
return false;
output1 = temp.MatMul(weights1);
//--- 活性化関数を計算する
if(!output1.Activation(temp, ac_func))
return false;
//--- 2番目のニューラル層を計算する
if(!temp.Resize(temp.Rows(), weights2.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights2.Rows() - 1))
return false;
output2 = temp.MatMul(weights2);
//--- 活性化関数を計算する
if(!output2.Activation(temp, ac_func))
return false;
//--- 3番目のニューラル層を計算する
if(!temp.Resize(temp.Rows(), weights3.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights3.Rows() - 1))
return false;
result = temp.MatMul(weights3);
//--- 結果を返す
return true;
}
//+------------------------------------------------------------------+
//| 逆伝播メソッド |
//+------------------------------------------------------------------+
bool Backprop(matrix &data, matrix &target)
{
//--- ターゲット値の行列のサイズを確認する
if(target.Rows() != result.Rows() ||
target.Cols() != result.Cols())
return false;
//--- 目標値からの計算値の偏差を決定する
matrix loss = (target - result) * 2;
//--- 勾配を前の層に伝播する
matrix gradient = loss.MatMul(weights3.Transpose());
//--- 最後の層の重み行列を更新する
matrix temp;
if(!output2.Activation(temp, ac_func))
return false;
if(!temp.Resize(temp.Rows(), weights3.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights3.Rows() - 1))
return false;
weights3 = weights3 + temp.Transpose().MatMul(loss) * lr;
//--- 活性化関数の導関数によって誤差勾配を調整する
if(!output2.Derivative(temp, ac_func))
return false;
if(!gradient.Resize(gradient.Rows(), gradient.Cols() - 1))
return false;
loss = gradient * temp;
//--- 勾配をより低い層に伝播する
gradient = loss.MatMul(weights2.Transpose());
//--- 2番目の隠れ層の重み行列を更新する
if(!output1.Activation(temp, ac_func))
return false;
if(!temp.Resize(temp.Rows(), weights2.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights2.Rows() - 1))
return false;
weights2 = weights2 + temp.Transpose().MatMul(loss) * lr;
//--- 活性化関数の導関数によって誤差勾配を調整する
if(!output1.Derivative(temp, ac_func))
return false;
if(!gradient.Resize(gradient.Rows(), gradient.Cols() - 1))
return false;
loss = gradient * temp;
//--- 1番目の隠れ層の重み行列を更新する
temp = data;
if(!temp.Resize(temp.Rows(), weights1.Rows()) ||
!temp.Col(vector::Ones(temp.Rows()), weights1.Rows() - 1))
return false;
weights1 = weights1 + temp.Transpose().MatMul(loss) * lr;
//--- 結果を返す
return true;
}
//+------------------------------------------------------------------+
//| モデルテストメソッド |
//+------------------------------------------------------------------+
bool Test(matrix &data, matrix &target)
{
//--- テストデータのフィードフォワード
if(!FeedForward(data))
return false;
//--- モデルの計算結果と真の値を記録する
PrintFormat("Test loss %.5f", result.Loss(target, LOSS_MSE));
ulong total = data.Rows();
for(ulong i = 0; i < total; i++)
PrintFormat("(%.2f + %.2f + %.2f)^2 / (%.2f^2 + %.2f^2 + %.2f^2) = Net %.2f, Target %.2f", data[i, 0], data[i, 1], data[i, 2],
data[i, 0], data[i, 1], data[i, 2], result[i, 0], target[i, 0]);
//--- 結果を返す
return true;
}
//+------------------------------------------------------------------+
|