preview
Свечи FU/AFU/SFU: Определения, код и статистика

Свечи FU/AFU/SFU: Определения, код и статистика

MetaTrader 5 — Трейдинг |
32 0
Ruslan Korolev
Ruslan Korolev

Введение

На графике свечи FU, AFU и SFU могут выглядеть как характерные сигналы разворота. Но как определить эти формации однозначно, так чтобы их можно было разметить индикатором? И как часто они стоят на разворотных экстремумах по сравнению с другими свечами, пробившими High или Low предыдущей свечи?

В статье я задам определения FU, AFU и SFU через данные OHLC и реализую их разметку на MQL5. Затем сравню частоту появления формаций и долю их точных совпадений с подтверждёнными экстремумами ZigZag. Базой сравнения будут все свечи, пробившие экстремум предыдущей свечи.

Сразу уточню границы проверки. Под снятием ликвидности в статье понимается только пробой High или Low предыдущей свечи. По ценам OHLC нельзя узнать, стояли ли за этим уровнем реальные стопы и заявки, поэтому гипотеза о манипуляции маркетмейкера остаётся гипотезой: проверяется только геометрия свечей. Не оцениваются также своевременность сигнала и прибыльность торговли. Практический результат статьи - набор инструментов на MQL5 и Python для разметки формаций и повторения проверки.

В статье мы постараемся ответить на три вопроса:

  1. Как часто встречаются FU, AFU и SFU (доля от всех свечей)?
  2. Как часто каждая из формаций стоит прямо на подтверждённом экстремуме ZigZag по сравнению с другими свечами, пробившими экстремум предыдущей?
  3. Наблюдается ли в данных порядок FU < AFU < SFU по этой доле ("лестница")?


Из чего состоит свеча

Для начала ещё раз вспомним, из чего состоит свеча: весь диапазон свечи (range), верхний и нижний фитиль и тело.

Рис. 1. Анатомия свечи

Обозначения на рис. 1:

  • range (диапазон) = High - Low;
  • body (тело) = |Close - Open|;
  • upper wick (верхний фитиль) = High - max(Open, Close);
  • lower wick (нижний фитиль) = min(Open, Close) - Low;
  • bullish (бычья свеча): Close > Open, тело пустое; bearish (медвежья): Close < Open, тело заштриховано.


Свеча FU

FU — самая простая формация. Для её определения нужны две свечи: [1] — последняя закрытая, [2] — предыдущая. Свеча [1] должна пробить High или Low свечи [2], то есть снять с неё ликвидность. При этом закрытие свечи [1] происходит выше High[2] при медвежьем паттерне или ниже Low[2] при бычьем паттерне. Получается, что, например, медвежья FU предполагает разворот вниз, хотя сама свеча [1] часто бычья и закрылась выше High[2]. Сама по себе такая свеча — продолжение движения вверх: разворот в момент её закрытия ещё не зафиксирован, он только ожидается.

Рис. 2. Медвежья и бычья FU

На рис. 2 слева медвежья FU, справа бычья. [1] — последняя закрытая свеча, [2] — предыдущая. Штрихпунктирная линия — уровень High[2] (для медвежьей) или Low[2] (для бычьей), точечная штриховка — снятая ликвидность, то есть часть свечи [1] за этим уровнем. Close[1] — закрытие свечи [1], у FU оно за снятым уровнем. Стрелка показывает ожидаемый разворот. Цвет тела свечи [1] не важен, важно только, где она закрылась.


Свеча AFU

Свеча AFU (Attempted FU, "попытка FU") - вторая формация. Свеча AFU снимает ликвидность с предыдущей свечи, но не может продавить цену в обратную сторону и закрыться за снятым уровнем. Гипотеза, которую мы проверим в статье: AFU чаще, чем FU, стоит на разворотном экстремуме.

Для AFU нужно то же условие, что для всех свечей FU: свеча [1] пробила High или Low предыдущей свечи [2]. Но закрытие свечи [1] происходит в диапазоне (range) свечи [2]. Границы включаются: закрытие ровно на High[2] или Low[2] тоже считается AFU, у FU и SFU сравнение строгое.

Рис. 3. Медвежья и бычья AFU

Обозначения на рис. 3 те же, что на рис. 2: слева медвежья AFU, справа бычья, штриховка — снятая ликвидность, стрелка — ожидаемый разворот. Отличие от FU одно: Close[1] вернулся внутрь диапазона свечи [2], между Low[2] и High[2].


Свеча SFU

SFU - Strong FU ("сильная FU"). Цена снимает ликвидность, затем свеча уверенно закрывается в противоположном направлении. Предполагается, что это самая сильная из трёх формаций: маркетмейкер собрал необходимый объём ликвидности и готов толкать цену в истинном направлении. Это гипотеза, и в статье мы проверяем её вместе с порядком FU < AFU < SFU. По форме SFU похожа на поглощение, но это не классическое свечное поглощение: проверяется только пробой одного экстремума и закрытие за противоположным, цвет свечей и размер тел не учитываются.

Для SFU нужно то же условие, что для всех свечей FU: свеча [1] пробила High или Low предыдущей свечи [2]. Но закрытие свечи [1] происходит за противоположной границей диапазона (range) свечи [2], то есть свеча [1] перекрывает весь диапазон свечи [2].

Рис. 4. Медвежья и бычья SFU

Обозначения на рис. 4 те же: слева медвежья SFU, справа бычья, штриховка — снятая ликвидность, стрелка — ожидаемый разворот. Close[1] ушёл за противоположную границу свечи [2]: у медвежьей ниже Low[2], у бычьей выше High[2]. Свеча [1] перекрывает весь диапазон свечи [2] вместе с фитилями.


Реализация на MQL5

Определения готовы, теперь переведём их в код. Сначала функции классификации свечей, затем индикатор, который размечает формации на графике, индикатор ZigZag для поиска экстремумов и скрипт, который собирает статистику.

Ищем FU в коде

Напишем две короткие функции. Первая, SweepDir, отвечает на вопрос "сняла ли свеча [1] ликвидность со свечи [2] и с какой стороны". Она возвращает -1, если перебит High[2] (медвежья формация, ждём разворот вниз), +1, если перебит Low[2] (бычья формация), и 0, если снятия нет. Если свеча [1] перебила обе стороны (внешний бар), направление задаём по закрытию. Закрытие ниже Low[2] - медвежий вариант, выше High[2] - бычий. Иначе направление выбирается по ближайшей половине диапазона свечи [2]. Это условность: по ценам OHLC нельзя узнать, какой экстремум был снят первым, поэтому направление части внешних баров задаётся эвристикой.

Вторая функция, IsFU, проверяет условие FU: закрытие находится за снятым экстремумом.

//+------------------------------------------------------------------+
//| Which extreme of candle [2] was swept by candle [1]:             |
//|  -1 = High[2] swept (bearish setup, reversal down expected),     |
//|  +1 = Low[2] swept (bullish setup, reversal up expected),        |
//|   0 = no sweep.                                                  |
//| Outside bar (both sides swept): the side is taken by the close.  |
//+------------------------------------------------------------------+
int SweepDir(const double prevHigh, const double prevLow,
             const double high, const double low, const double close)
  {
   bool sweptHigh = (high > prevHigh);
   bool sweptLow  = (low < prevLow);
//--- no sweep or a degenerate candle (High == Low)
   if(!sweptHigh && !sweptLow) return 0;
   if(high - low <= 0.0)       return 0;
//--- one side swept
   if(sweptHigh && !sweptLow)  return -1;
   if(sweptLow && !sweptHigh)  return +1;
//--- outside bar: the side is taken by the close
   if(close < prevLow)  return -1;
   if(close > prevHigh) return +1;
   return (close < (prevHigh + prevLow) / 2.0) ? -1 : +1;
  }

//+------------------------------------------------------------------+
//| FU: candle [1] closed beyond the swept extreme of candle [2]     |
//+------------------------------------------------------------------+
bool IsFU(const int dir, const double prevHigh, const double prevLow, const double close)
  {
   if(dir == -1) return (close > prevHigh);
   if(dir == +1) return (close < prevLow);
   return false;
  }

Обе функции находятся внутри индикатора FuCandles, о нём ниже.

Ищем AFU в коде

Сторону снятия уже даёт SweepDir, остаётся проверить закрытие внутри диапазона свечи [2]:

//+------------------------------------------------------------------+
//| AFU: candle [1] swept an extreme but closed inside the range     |
//| of candle [2] (Low[2] <= Close[1] <= High[2])                    |
//+------------------------------------------------------------------+
bool IsAFU(const int dir, const double prevHigh, const double prevLow, const double close)
  {
   if(dir == 0) return false;
   return (close >= prevLow && close <= prevHigh);
  }

Ищем SFU в коде

Закрытие за противоположной границей свечи [2]:

//+------------------------------------------------------------------+
//| SFU: candle [1] closed beyond the opposite extreme of candle [2] |
//| (full engulfing)                                                 |
//+------------------------------------------------------------------+
bool IsSFU(const int dir, const double prevHigh, const double prevLow, const double close)
  {
   if(dir == -1) return (close < prevLow);
   if(dir == +1) return (close > prevHigh);
   return false;
  }

Индикатор FuCandles

Индикатор ставит стрелку вниз над High медвежьей свечи и стрелку вверх под Low бычьей. Три переключателя: показывать FU, AFU, SFU. Считаются только закрытые бары: формирующаяся свеча ещё может изменить закрытие. При первом запуске проходим всю историю, дальше только что закрывшийся бар. Кроме двух буферов со стрелками у индикатора есть два скрытых буфера: первый — тип свечи (1 = FU, 2 = AFU, 3 = SFU, 0 = нет формации) и второй — направление (-1 для медвежьей, +1 для бычьей). Через них тип любой свечи можно прочитать из скрипта или советника функцией iCustom, так и работает скрипт сбора данных. Ключевая часть, функция OnCalculate:

//+------------------------------------------------------------------+
//| Type of candle [1] relative to candle [2]                        |
//+------------------------------------------------------------------+
int CandleType(const int dir, const double prevHigh, const double prevLow, const double close)
  {
   if(dir == 0)                             return TYPE_NONE;
   if(IsFU(dir, prevHigh, prevLow, close))  return TYPE_FU;
   if(IsAFU(dir, prevHigh, prevLow, close)) return TYPE_AFU;
   if(IsSFU(dir, prevHigh, prevLow, close)) return TYPE_SFU;
   return TYPE_NONE;
  }

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total, const int prev_calculated,
                const datetime &time[], const double &open[],
                const double &high[], const double &low[], const double &close[],
                const long &tick_volume[], const long &volume[], const int &spread[])
  {
//--- all arrays oldest-first
   ArraySetAsSeries(high,  false);
   ArraySetAsSeries(low,   false);
   ArraySetAsSeries(close, false);
   if(rates_total < 3)
      return 0;
//--- first run: all bars; later: only the bar that has just closed
   int start = (prev_calculated == 0) ? 0 : prev_calculated - 1;
   for(int i = start; i < rates_total; i++)
     {
      //--- clear the bar
      BearArrow[i] = EMPTY_VALUE;
      BullArrow[i] = EMPTY_VALUE;
      Type[i] = TYPE_NONE;
      Dir[i]  = 0;
      //--- no previous candle or the forming bar: nothing to check
      if(i < 1 || i == rates_total - 1)
         continue;
      //--- sweep direction and candle type
      int dir  = SweepDir(high[i - 1], low[i - 1], high[i], low[i], close[i]);
      int type = CandleType(dir, high[i - 1], low[i - 1], close[i]);
      if(type == TYPE_NONE)
         continue;
      Type[i] = type;
      Dir[i]  = dir;
      //--- arrow only for the types switched on
      bool show = (type == TYPE_FU && InpShowFU) || (type == TYPE_AFU && InpShowAFU) ||
                  (type == TYPE_SFU && InpShowSFU);
      if(!show)
         continue;
      if(dir == -1) BearArrow[i] = high[i];
      else          BullArrow[i] = low[i];
     }
   return rates_total;
  }

Полный код индикатора приложен к статье.

Для примеров включаем в индикаторе по одному типу. Типичные FU-свечи:

Рис. 5. Пример участка: свечи FU на EURUSD D1 (индикатор FuCandles, показан только тип FU) и SimpleZigZag

Типичные AFU-свечи:

Рис. 6. Пример участка: свечи AFU на EURUSD D1 (индикатор FuCandles, показан только тип AFU) и SimpleZigZag

Типичные SFU-свечи:

Рис. 7. Пример участка: свечи SFU на EURUSD D1 (индикатор FuCandles, показан только тип SFU) и SimpleZigZag

Индикатор SimpleZigZag

Чтобы проверить, стоит ли свеча на развороте, нужен экстремум вершины или дна. Создадим свой простой индикатор ZigZag с одним параметром. ZigZag разворачивается, если цена прошла против последнего движения n пунктов. Если бар одновременно обновил экстремум и прошёл n пунктов против него, засчитывается обновление экстремума. Считаются только закрытые бары. Последняя точка линии может сдвигаться, пока нога не подтверждена, поэтому в исследование идут только подтверждённые максимумы (буфер 1) и минимумы (буфер 2).

Важно: экстремум подтверждается только после того, как цена ушла от него на n пунктов. Значит, мы проверяем совпадение свечи с разворотом постфактум, а не своевременность сигнала.

Ключевая часть кода, функция разворота и обработчик OnCalculate:

//+------------------------------------------------------------------+
//| Confirm the current extreme and start the opposite leg at bar i  |
//+------------------------------------------------------------------+
void Reverse(int i, double price)
  {
//--- the extreme of the finished leg becomes a confirmed top or bottom
   if(g_dir == +1) SwingHigh[g_extBar] = g_ext;
   else            SwingLow[g_extBar]  = g_ext;
//--- start the opposite leg
   g_dir = -g_dir;
   g_ext = price;
   g_extBar = i;
   ZZ[i] = price;
  }

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total, const int prev_calculated,
                const datetime &time[], const double &open[],
                const double &high[], const double &low[], const double &close[],
                const long &tick_volume[], const long &volume[], const int &spread[])
  {
//--- all arrays oldest-first
   ArraySetAsSeries(high, false);
   ArraySetAsSeries(low,  false);
   if(rates_total < 3)
      return 0;
//--- reversal distance in price units
   double th = InpReversal * _Point;
//--- full recalculation: reset buffers and state; otherwise clear the new bars only
   if(prev_calculated == 0)
     {
      ArrayInitialize(ZZ, 0.0);
      ArrayInitialize(SwingHigh, 0.0);
      ArrayInitialize(SwingLow, 0.0);
      g_dir = 0;
      g_hi = high[0]; g_hiBar = 0;
      g_lo = low[0];  g_loBar = 0;
      g_last = 0;
     }
   else
      for(int k = prev_calculated; k < rates_total; k++)
        { ZZ[k] = 0.0; SwingHigh[k] = 0.0; SwingLow[k] = 0.0; }
//--- closed bars only: the forming bar (rates_total-1) is skipped
   for(int i = g_last + 1; i < rates_total - 1; i++)
     {
      if(g_dir == 0)
        {
         //--- before the first leg: wait until price moves th from the first high or low
         if(high[i] > g_hi) { g_hi = high[i]; g_hiBar = i; }
         if(low[i]  < g_lo) { g_lo = low[i];  g_loBar = i; }
         if(g_hi - g_lo >= th)
           {
            if(g_loBar < g_hiBar)
              { g_dir = -1; g_ext = g_lo; g_extBar = g_loBar; ZZ[g_loBar] = g_lo; Reverse(g_hiBar, g_hi); }
            else
              { g_dir = +1; g_ext = g_hi; g_extBar = g_hiBar; ZZ[g_hiBar] = g_hi; Reverse(g_loBar, g_lo); }
           }
        }
      else if(g_dir == +1)
        {
         //--- leg up: a new high extends the leg; otherwise check the reversal
         if(high[i] > g_ext)              MoveExtreme(i, high[i]);
         else if(g_ext - low[i] >= th)    Reverse(i, low[i]);
        }
      else
        {
         //--- leg down: mirror
         if(low[i] < g_ext)               MoveExtreme(i, low[i]);
         else if(high[i] - g_ext >= th)   Reverse(i, high[i]);
        }
      g_last = i;
     }
   return rates_total;
  }

Параметр n подбираем визуально, чтобы ZigZag захватил большую часть движений, заметных на глаз. Порог задан в пунктах отдельно для каждого символа и таймфрейма, по волатильности он не нормирован. Чувствительность результатов к n в этой статье не проверялась, см. ограничения в конце. Параметры для пятизначных котировок:

Символ D1 H4
EURUSD 1500 750
BTCUSD 6500 3500
EURGBP 800 400

Полный код индикатора приложен к статье (файл SimpleZigZag_v1.mq5).

Скрипт FuCollector

Скрипт сам ничего не вычисляет: он берёт через iCustom тип и направление каждой свечи у индикатора FuCandles и подтверждённые максимумы и минимумы у SimpleZigZag, затем записывает для каждой закрытой свечи одну строку в CSV-файл. Скрипт также формирует сводку и выводит её в журнал "Эксперты": число свечей каждого типа и долю тех, что стоят прямо на экстремуме ZigZag. Отдельно считаются те же показатели для базы - всех свечей со снятием.

Сводки достаточно, чтобы повторить цифры из статьи, CSV нужен для анализа. Файл с именем вида FU_EURUSD_D1.csv (символ и таймфрейм) сохраняется в общую папку терминалов, скрипт печатает полный путь в журнал. Обычно это C:\Users\<имя пользователя>\AppData\Roaming\MetaQuotes\Terminal\Common\Files. Разделитель - запятая, файл открывается в Excel. Ключевая часть, обработка одного бара:

//+------------------------------------------------------------------+
//| Write the CSV row of closed bar i and update the counters        |
//+------------------------------------------------------------------+
void CollectBar(const int f, const MqlRates &r[], const double &type[], const double &dir[],
                const double &zzH[], const double &zzL[], const int i)
  {
   int t = (int)type[i];
   int d = (int)dir[i];
//--- exactly on a confirmed ZigZag extreme in the expected direction:
//--- bearish pattern on a top, bullish pattern on a bottom
   bool onSwing = (d == -1 && zzH[i] > 0.0) || (d == +1 && zzL[i] > 0.0);
//--- CSV row: time,open,high,low,close,type,dir,zz_high,zz_low
   FileWrite(f, TimeToString(r[i].time, TIME_DATE | TIME_MINUTES),
             DoubleToString(r[i].open, _Digits), DoubleToString(r[i].high, _Digits),
             DoubleToString(r[i].low,  _Digits), DoubleToString(r[i].close, _Digits),
             TYPE_NAME[t], d,
             zzH[i] > 0.0 ? DoubleToString(zzH[i], _Digits) : "",
             zzL[i] > 0.0 ? DoubleToString(zzL[i], _Digits) : "");
//--- counters
   g_bars++;
   if(t == 0) return;
   g_sweep++;  g_cnt[t]++;
   if(onSwing) { g_sweepSwing++; g_swing[t]++; }
  }

Свеча "на экстремуме", если медвежья формация стоит прямо на подтверждённой вершине ZigZag, а бычья прямо на дне. Пример сводки для EURUSD D1:

=== EURUSD D1, ZigZag 1500 points, 1751 closed bars ===
type     count   %_bars   on_swing    %_swing
FU         762     43.5         64        8.4
AFU        662     37.8         86       13.0
SFU         90      5.1         18       20.0
base      1514     86.5        168       11.1
CSV: C:\Users\Admin\AppData\Roaming\MetaQuotes\Terminal\Common\Files\FU_EURUSD_D1.csv

Установка и запуск

Все файлы статьи приложены к ней, их список приведён в конце статьи. Порядок установки: распаковать MQL5.zip в каталог данных терминала (или вручную положить индикаторы в папку MQL5\Indicators\FU, скрипт в MQL5\Scripts\FU), затем скомпилировать индикаторы и скрипт в MetaEditor. Если индикаторы лежат в другой папке внутри Indicators, укажите её имя в параметре скрипта Folder (по умолчанию FU). Затем запустите скрипт FuCollector на графике нужного символа и таймфрейма.


Методика проверки

Данные включают EURUSD, BTCUSD и EURGBP (таймфреймы D1 и H4) за период с января 2020 по сентябрь 2026. Графики ниже построены по CSV-файлам скриптом на Python, он тоже приложен. На графиках по горизонтали шесть наборов данных (символ и таймфрейм), по вертикали проценты, цифры над столбиками - значения. Подпись base на графиках означает базу сравнения: все свечи со снятием ликвидности.

Проверяем две вещи: насколько часто встречается каждая формация и как часто она стоит на развороте, то есть прямо на подтверждённом экстремуме ZigZag.

Как проверяем совпадение с экстремумом:

  1. Строим на истории ZigZag (SimpleZigZag, своё n для каждого символа и ТФ) и отмечаем все его экстремумы (максимумы и минимумы).
  2. Для каждой формации смотрим, стоит ли она прямо на экстремуме в сторону ожидаемого разворота: медвежья на вершине, бычья на дне.
  3. Считаем, какая доля формаций каждого типа оказалась на экстремуме.

Примечание. Вершина ZigZag - это свеча с самым высоким High, значит, её High почти всегда выше High предыдущей свечи. То есть вершина почти всегда сама является свечой со снятием. При сравнении со всеми свечами формации будут выглядеть лучше из-за самого факта снятия экстремума, а не из-за принадлежности к FU, AFU или SFU. Поэтому предмет исследования: выделяется ли формация среди свечей со снятием. Для этого соберём базу свечей, и она должна состоять только из свечей со снятием.

  1. То же самое считаем для базы: всех свечей, которые сняли High или Low предыдущей свечи (FU, AFU, SFU вместе). База включает и сам проверяемый тип, поэтому в таблицах есть ещё одна колонка: остальные свечи со снятием, без него.
  2. Сравниваем доли. Для каждой считаем 95% доверительный интервал Уилсона: это интервал для доли, который ведёт себя корректнее обычного "p ± 1.96 σ" при малом числе наблюдений и долях около нуля, формула есть в приложенном fig_summary.py. Если интервалы не пересекаются, разницу считаем статистически заметной. Это грубый ориентир, а не полноценный тест различия долей, к тому же соседние свечи зависят друг от друга, поэтому интервалы приблизительные.


Результаты

Доля формаций среди всех свечей

Цель: выяснить, насколько часто встречается каждая формация. Если формация встречается на каждой третьей свече, это не особое событие, а обычная трендовая свеча.

Вопрос Какая доля всех свечей является FU, AFU, SFU?
Как проверяем Считаем формации каждого типа среди всех закрытых свечей

Рис. 8. Доля свечей FU от всех свечей

Рис. 9. Доля свечей AFU от всех свечей

Рис. 10. Доля свечей SFU от всех свечей

Вывод:

  1. Свечи FU встречаются очень часто: 33-43% всех свечей (рис. 8). По сути, это обычная трендовая свеча, которая закрылась за экстремумом предыдущей.
  2. AFU встречается так же часто, как FU: 34-40% всех свечей (рис. 9), то есть примерно каждая третья свеча.
  3. SFU встречается редко: 5-10% всех свечей (рис. 10), в 3-8 раз реже, чем FU или AFU.
  4. На H4 у EURUSD и EURGBP SFU заметно больше (9-10%), чем на D1 (5-6%). Похоже, дело в торговых сессиях: свеча H4, открывшаяся на старте Лондона, оказывается SFU в 25% случаев на EURUSD и в 36% на EURGBP, в остальные часы не выше 12%. Спокойную азиатскую свечу перекрывает первая лондонская. У BTCUSD перекос меньше, но тоже есть: свеча 16:00, открытие Нью-Йорка, оказывается SFU в 14% случаев против 3-7% в другие часы. Это наблюдение, причина отдельным тестом не проверялась.

Совпадение формаций с экстремумами ZigZag

Цель: проверить, чаще ли формация стоит на развороте, чем любая свеча, которая тоже сняла экстремум предыдущей. Методика описана выше: медвежья формация должна стоять прямо на вершине ZigZag, бычья на дне, база - все свечи со снятием.

FU

Рис. 11. Доля сигналов прямо на экстремуме ZigZag: FU и база (все свечи со снятием)

  • FU оказывается на экстремуме реже средней свечи со снятием, и так во всех 6 наборах (рис. 11):
    FU на экстремуме База (любая свеча со снятием) Остальные свечи со снятием (AFU + SFU)
    Все наборы 6.1% (5.7-6.5) 7.6% (7.3-7.9) 8.9% (8.5-9.3)
    D1 8.4% (7.4-9.6) 10.7% (9.9-11.6) 12.8% (11.6-14.1)
    H4 5.7% (5.3-6.1) 7.1% (6.8-7.4) 8.2% (7.8-8.7)
    • Около 94% FU не стоят на подтверждённом экстремуме (при нашем ZigZag; с другим порогом n цифра будет другой).

      AFU

      Рис. 12. Доля сигналов прямо на экстремуме ZigZag: AFU и база (все свечи со снятием)

      • В отличие от FU, AFU стоит на экстремуме чаще средней свечи со снятием в 5 наборах из 6 (рис. 12). Исключение BTCUSD D1: 6.8% против 7.0%, практически вровень.
        AFU на экстремуме База (любая свеча со снятием) Остальные свечи со снятием (FU + SFU)
        Все наборы 8.6% (8.1-9.0) 7.6% (7.3-7.9) 6.8% (6.5-7.2)
        D1 12.1% (10.8-13.5) 10.7% (9.9-11.6) 9.6% (8.5-10.7)
        H4 8.0% (7.5-8.4) 7.1% (6.8-7.4) 6.4% (6.0-6.7)
        • Эффект небольшой: в целом примерно в 1.1 раза чаще базы и в 1.3 раза чаще остальных свечей со снятием. По всем наборам и на H4 интервалы не пересекаются, разница статистически заметна. На D1 интервалы AFU и базы пересекаются, а с остальными свечами (без AFU) не пересекаются.
        • Около 91% AFU не стоят на подтверждённом экстремуме.

          SFU

          Рис. 13. Доля сигналов прямо на экстремуме ZigZag: SFU и база (все свечи со снятием)

          • SFU стоит на экстремуме чаще средней свечи со снятием во всех 6 наборах (рис. 13).
            SFU на экстремуме База (любая свеча со снятием) Остальные свечи со снятием (FU + AFU)
            Все наборы 10.3% (9.3-11.4) 7.6% (7.3-7.9) 7.3% (7.0-7.6)
            D1 17.0% (13.5-21.2) 10.7% (9.9-11.6) 10.2% (9.4-11.1)
            H4 9.5% (8.5-10.6) 7.1% (6.8-7.4) 6.8% (6.5-7.1)
            • Из трёх формаций SFU совпадает с экстремумом чаще всего: в целом примерно в 1.35 раза чаще базы и в 1.4 раза чаще остальных свечей со снятием, на D1 в 1.6-1.7 раза. Интервалы не пересекаются ни в одной группе, разница статистически заметна. Оговорка: часть этого преимущества заложена в определениях. SFU уже содержит сильное движение обратно за диапазон свечи [2], а ZigZag подтверждает разворот тоже через движение против экстремума.
            • Даже у SFU большинство свечей не стоят на подтверждённом экстремуме: около 90% в целом и около 83% на D1.


              Заключение

              В статье заданы формальные правила для FU, AFU и SFU, реализована их разметка на MQL5 и проверено совпадение формаций с подтверждёнными экстремумами ZigZag. Разворотом считалось только точное совпадение свечи с таким экстремумом в ожидаемом направлении.

              Сведём результаты вместе.

              Тип Доля от всех свечей На экстремуме ZigZag (все наборы) Остальные свечи со снятием По сравнению с базой
              FU 33-43% 6.1% (5.7-6.5) 8.9% (8.5-9.3) реже, в 0.8 раза
              База: любая свеча со снятием - 7.6% (7.3-7.9) - -
              AFU 34-40% 8.6% (8.1-9.0) 6.8% (6.5-7.2) чаще, в 1.1 раза
              SFU 5-10% 10.3% (9.3-11.4) 7.3% (7.0-7.6) чаще, в 1.35 раза (на D1 в 1.6)

              Рис. 14. Лестница FU < AFU < SFU: доля свечей прямо на экстремуме ZigZag

              Ответы на вопросы, поставленные во введении:

              1. Как часто встречаются FU, AFU и SFU? FU и AFU очень часто, примерно каждая третья свеча. Вместе с SFU помечено 79-87% всех свечей. SFU редкая, 5-10%.
              2. Как часто они стоят на экстремуме по сравнению с другими свечами со снятием? Зависит от типа. FU совпадает с экстремумом реже средней свечи со снятием, AFU немного чаще, SFU заметно чаще. Сравнивать нужно со свечами со снятием, а не со всеми свечами: вершина ZigZag почти всегда сама является свечой со снятием.
              3. Наблюдается ли "лестница" FU < AFU < SFU? В нашей выборке да, но без обобщения. Порядок совпал по всем наборам вместе, на D1 и на H4 (рис. 14), и по всем наборам вместе интервалы соседних ступеней не пересекаются. На D1 и H4 по отдельности соседние ступени местами соприкасаются, а по отдельным наборам порядок совпал в 5 из 6: на EURGBP H4 SFU и AFU почти вровень. Строка "все наборы" в основном отражает H4, там в шесть раз больше свечей, чем на D1. Поэтому корректно говорить о совпадении порядка в собранных данных, а не о свойстве формаций вообще.

              Эти проценты описывают исторические совпадения с конкретными экстремумами ZigZag, а не вероятность разворота вообще и не вероятность прибыльной сделки. О своевременности сигнала, а также о намерениях участников, стопах и заявках за экстремумами цены OHLC ничего не говорят. Гипотеза о манипуляции этими данными не подтверждается и не опровергается: проверена только геометрия свечей.

              Практический результат статьи - комплект для повторения проверки: FuCandles размечает формации, SimpleZigZag выделяет экстремумы, FuCollector сохраняет данные в CSV и выводит сводку, скрипты Python строят графики. С ними можно собрать такую же статистику на другом инструменте или таймфрейме, учитывая, что результаты зависят от выбранных параметров и правил ZigZag.


              Ограничения исследования

              • "Снятие ликвидности" здесь — пробой High или Low свечи [2]. Реальные стопы и заявки не проверялись.
              • ZigZag взят в окончательном виде на истории: экстремум известен только после движения на n пунктов от него. Результаты - совпадение с экстремумами постфактум, а не оценка своевременности сигнала. В реальном времени последняя нога может перерисоваться.
              • Критерий "на развороте" сознательно строгий: свеча должна стоять ровно на подтверждённом экстремуме. Разворот на соседней свече и задержанный разворот не засчитываются.
              • Параметр ZigZag n подобран на глаз до подсчёта статистики, задан в пунктах и по волатильности не нормирован. Чувствительность результатов к n не проверялась: при другом n доли "на экстремуме" будут другими, в том числе доли свечей не на экстремуме.
              • Результаты зависят и от реализации ZigZag: правил подтверждения, выбора экстремума, обработки внешних баров.
              • Направление внешнего бара (снял обе стороны) задаётся по закрытию. Это эвристика: по OHLC не видно, какой экстремум снят первым.
              • База сравнения включает сам проверяемый тип, поэтому в таблицах есть колонка "остальные свечи со снятием".
              • Строка "все наборы" смешивает инструменты и таймфреймы, H4 в ней весит больше.
              • Три инструмента, два таймфрейма, 2020-2026 годы. На другие рынки и периоды выводы не следует переносить.
              • Интервалы Уилсона, 95%. Соседние свечи зависят друг от друга, а непересечение интервалов — грубый ориентир, не тест.
              • Мы проверяли только, стоит ли свеча на экстремуме. Прибыльность торговли по этим свечам здесь не проверялась.


              Файлы, приложенные к статье:

              Файл Тип Описание
              FuCandles.mq5 Индикатор Функции SweepDir, IsFU, IsAFU, IsSFU, стрелки на свечах FU, AFU и SFU, скрытые буферы с типом и направлением
              SimpleZigZag_v1.mq5 Индикатор ZigZag с одним параметром
              FuCollector.mq5 Скрипт Читает оба индикатора через iCustom, пишет CSV-файл и сводку в журнал
              fig_stats.py, fig_summary.py, eng_style.py Python Построение графиков по CSV-файлам
              MQL5.zip Архив Все файлы статьи по своим путям: индикаторы в MQL5\Indicators\FU, скрипт в MQL5\Scripts\FU, скрипты Python в MQL5\Files\FU\Python. Распаковать в каталог данных терминала (Файл - Открыть каталог данных), и все файлы окажутся на своих местах
              Прикрепленные файлы |
              FuCandles.mq5 (8.28 KB)
              FuCollector.mq5 (6.79 KB)
              fig_stats.py (1.5 KB)
              fig_summary.py (2.3 KB)
              eng_style.py (3.66 KB)
              MQL5.zip (10.6 KB)
              Торговые инструменты MQL5 (Часть 37): Добавление ленты редактирования свойств отдельных объектов в слой рисования на холсте Торговые инструменты MQL5 (Часть 37): Добавление ленты редактирования свойств отдельных объектов в слой рисования на холсте
              Мы добавляем стек свойств, управляемый дескрипторами, и плавающую ленту, которая привязывается к текущему выделению на слое рисования. В статье рассматриваются список дескрипторов для каждого инструмента, API получения и установки со стороны движка с предварительным просмотром в реальном времени на основе механизма «снимок и восстановление», а также рендереры виджетов для цвета, непрозрачности, ширины линии, стиля линии, шрифтов и видимости уровней. Вы получаете возможность редактировать внешний вид объектов на месте и в режиме реального времени с помощью компактной панели, которую можно перетаскивать.
              Разрабатываем менеджер терминалов (Часть 5): Автоматизация установки Разрабатываем менеджер терминалов (Часть 5): Автоматизация установки
              Добавляем в менеджер создание и настройку экземпляров MetaTrader 5 через браузер. Разбираем подготовку файлов, подключение к торговому счёту и сохранение параметров для повторного запуска. Показываем, как обновлять проект, собирать и распространять сервис сбора состояния терминалов на MQL5, чтобы управлять терминалами без подключения к удалённому рабочему столу.
              Особенности написания экспертов Особенности написания экспертов
              Написание и тестирование экспертов в торговой системе MetaTrader 4.
              Регрессия на основе гауссовских процессов на MQL5: Краткосрочное прогнозирование цен с полосами неопределенности Регрессия на основе гауссовских процессов на MQL5: Краткосрочное прогнозирование цен с полосами неопределенности
              В статье переработана модель прогнозирования на основе гауссовского процесса на чистом MQL5: входные данные характеризуют состояние рынка, а целевые переменные задаются непосредственно как логарифмические доходности за горизонт прогнозирования. В ней используются ядро Матерна 3/2, разложение Холецкого с обеспечением симметрии матрицы и адаптивной диагональной добавкой, стандартизированные целевые переменные и поиск по сетке в логарифмическом пространстве без побочного изменения состояния объекта. Советник торгует только тогда, когда z-оценка, рассчитанная с использованием дисперсии наблюдений, достигает заданного порога или превышает его, а торговое преимущество превышает текущий спред. Калибровка проверяется в тестере стратегий.