iAlligator

A função retorna o manipulador do indicador Alligator.

int  iAlligator(
   string              symbol,            // símbolo nome
   ENUM_TIMEFRAMES     period,            // período
   int                 jaw_period,        // período para cálculo da mandíbula
   int                 jaw_shift,         // deslocamento horizontal da mandíbula
   int                 teeth_period,      // período para cálculo dos dentes
   int                 teeth_shift,       // deslocamento horizontal dos dentes
   int                 lips_period,       // período para o cálculo da boca
   int                 lips_shift,        // deslocamento horizontal da boca
   ENUM_MA_METHOD      ma_method,         // tipo de suavização
   ENUM_APPLIED_PRICE  applied_price      // tipo de preço ou manipulador
   );

Parâmetros

symbol

[in] O nome do símbolo de segurança, os dados que devem ser usados para calcular o indicador. O valor NULL significa o símbolo atual.

period

[in] O valor do período pode ser um dos valores ENUM_TIMEFRAMES, 0 (zero) significa o prazo corrente.

jaw_period

[in]  Período médio para a linha azul (mandíbula do Alligator)

jaw_shift

[in] O deslocamento da linha azul em relação à tabela de preços.

teeth_period

[in]   Período médio para a linha vermelha (dentes do Alligator).

teeth_shift

[in] O deslocamento da linha vermelha em relação para a tabela de preços.

lips_period

[in]  Período médio para a linha verde (boca de Alligator).

lips_shift

[in] O deslocamento da linha verde em relação à tabela de preços.

ma_method

[in]  O método da média. Pode ser qualquer um dos valores do ENUM_MA_METHOD.

applied_price

[in]  O preço usado. Pode ser qualquer das constantes de preços ENUM_APPLIED_PRICE ou um manipulador de outro indicador.

Valor de retorno

Retorna o manipulador de um indicador técnico especifico, em caso de falha de retorna INVALID_HANDLE. A memória do computador pode ser liberada a partir de um indicador que não é mais utilizado, usando a função IndicatorRelease(), onde o manipulador de indicador é transmitido.

Observação

Os números do buffer são os seguintes: 0 - GATORJAW_LINE, 1 - GATORTEETH_LINE, 2 - GATORLIPS_LINE.

Exemplo:

//+------------------------------------------------------------------+
//|                                              Demo_iAlligator.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                            ;https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "O indicador demonstra como obter dados"
#property description "dos buffers do indicador para o indicador técnico iAlligator."
#property description "Um símbolo e o prazo utilizado para o cálculo do indicador,"
#property description "são definidos pelos parâmetros de símbolo e período."
#property description "O método de criação do manipulador é definido através do parâmetro "type" (tipo de função)."
#property description "Todos os outros parâmetros são similares aos do padrão Alligator."
 
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_plots   3
//--- plot Jaws
#property indicator_label1  "Jaws"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot Teeth
#property indicator_label2  "Teeth"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrRed
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- plot Lips
#property indicator_label3  "Lips"
#property indicator_type3   DRAW_LINE
#property indicator_color3  clrLime
#property indicator_style3  STYLE_SOLID
#property indicator_width3  1
//+------------------------------------------------------------------+
//| Enumerador dos métodos de criação do manipulador                 |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iAlligator,        // usar iAlligator
   Call_IndicatorCreate    // usar IndicatorCreate
  };
//--- parâmetros de entrada
input Creation             type=Call_iAlligator;   // tipo de função
input string               symbol=" ";             // símbolo
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;  // timeframe
input int                  jaw_period=13;          // período da linha da mandíbula
input int                  jaw_shift=8;            // deslocamento da linha da mandíbula
input int                  teeth_period=8;         // período da linha dos dentes
input int                  teeth_shift=5;          // deslocamento da linha dos dentes
input int                  lips_period=5;          // período da linha da boca
input int                  lips_shift=3;           // deslocamento da linha da boca
input ENUM_MA_METHOD       MA_method=MODE_SMMA;    // método das linhas médias do Alligator
input ENUM_APPLIED_PRICE   applied_price=PRICE_MEDIAN;// tipo de preço utilizado para o cálculo do Alligator
//--- buffers do indicador
double         JawsBuffer[];
double         TeethBuffer[];
double         LipsBuffer[];
//--- variável para armazenar o manipulador do indicador
int    handle;
//--- variável para armazenamento
string name=symbol;
//--- nome do indicador num gráfico
string short_name;
//--- manteremos o número de valores dentro do indicador Alligator
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- atribuição de arrays para buffers do indicador
   SetIndexBuffer(0,JawsBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,TeethBuffer,INDICATOR_DATA);
   SetIndexBuffer(2,LipsBuffer,INDICATOR_DATA);
//--- definir o deslocamento de cada linha
   PlotIndexSetInteger(0,PLOT_SHIFT,jaw_shift);
   PlotIndexSetInteger(1,PLOT_SHIFT,teeth_shift);
   PlotIndexSetInteger(2,PLOT_SHIFT,lips_shift);
//--- determinar o símbolo do indicador, é desenhado para
   name=symbol;
//--- excluir os espaços à direita e à esquerda
   StringTrimRight(name);
   StringTrimLeft(name);
//--- se resulta em comprimento zero da string do 'name'
   if(StringLen(name)==0)
     {
      //--- tomar o símbolo do gráfico, o indicador está anexado para
      name=_Symbol;
     }
//--- criar manipulador do indicador
   if(type==Call_iAlligator)
      handle=iAlligator(name,period,jaw_period,jaw_shift,teeth_period,
                        teeth_shift,lips_period,lips_shift,MA_method,applied_price);
   else
     {
      //--- preencher a estrutura com os parâmetros do indicador
      MqlParam pars[8];
     //--- períodos e deslocamentos das linhas do Alligator
      pars[0].type=TYPE_INT;
      pars[0].integer_value=jaw_period;
      pars[1].type=TYPE_INT;
      pars[1].integer_value=jaw_shift;
      pars[2].type=TYPE_INT;
      pars[2].integer_value=teeth_period;
      pars[3].type=TYPE_INT;
      pars[3].integer_value=teeth_shift;
      pars[4].type=TYPE_INT;
      pars[4].integer_value=lips_period;
      pars[5].type=TYPE_INT;
      pars[5].integer_value=lips_shift;
//--- tipo de suavização
      pars[6].type=TYPE_INT;
      pars[6].integer_value=MA_method;
//--- tipo de preço
      pars[7].type=TYPE_INT;
      pars[7].integer_value=applied_price;
//--- criar manipulador
      handle=IndicatorCreate(name,period,IND_ALLIGATOR,8,pars);
     }
//--- se o manipulador não é criado
   if(handle==INVALID_HANDLE)
     {
      //--- mensagem sobre a falha e a saída do código de erro
      PrintFormat("Falha ao criar o manipulador do indicador iAlligator para o símbolo %s/%s, código de erro %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- o indicador é interrompido precocemente
      return(INIT_FAILED);
     }
//--- mostrar o símbolo/prazo do indicador Alligator calculado para
   short_name=StringFormat("iAlligator(%s/%s, %d,%d,%d,%d,%d,%d)",name,EnumToString(period),
                           jaw_period,jaw_shift,teeth_period,teeth_shift,lips_period,lips_shift);
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inicialização normal do indicador    
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- número de valores copiados a partir do indicador iAlligator
   int values_to_copy;
//--- determinar o número de valores calculados no indicador
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() retornando %d, código de erro %d",calculated,GetLastError());
      return(0);
     }
//--- se for o primeiro arranque do cálculo do indicador, ou se o número de valores que mudou o indicador iAlligator
//--- ou se é necessário cálculo do indicador para duas ou mais barras (isso significa que algo mudou no histórico do preço)
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- Se o array JawsBuffer é maior do que o número dos valores do indicador iAlligator para símbolo/período, então não copiamos tudo
      //--- caso contrário, copiamos menor do que o tamanho dos buffers do indicador
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
     }
   else
     {
      //--- isso significa que não é a primeira vez do cálculo do indicador, é desde a última chamada de OnCalculate())
      //--- para o cálculo não mais do que uma barra é adicionada
      values_to_copy=(rates_total-prev_calculated)+1;
     }
//--- preencher os arrays com os valores do indicador de Alligator
//--- se FillArraysFromBuffer retorna falso, isto significa que a informação ainda não está pronta, sair da operação
   if(!FillArraysFromBuffers(JawsBuffer,jaw_shift,TeethBuffer,teeth_shift,LipsBuffer,lips_shift,handle,values_to_copy)) return(0);
//--- formar a mensagem
   string comm=StringFormat("%s ==>  Valor atualizado no indicador %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- exibir a mensagem de serviço no gráfico
   Comment(comm);
//--- memorizar o número de valores dentro do indicador Alligator
   bars_calculated=calculated;
//--- retorna o valor prev_calculated para a próxima chamada
   return(rates_total);
  }  
//+------------------------------------------------------------------+
//| Preencher buffers do indicador a partir do indicador iAlligator  |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &jaws_buffer[],  // buffer do indicador para a linha da mandíbula
                           int j_shift,            // deslocamento da linha da mandíbula
                           double &teeth_buffer[], // buffer do indicador para a linha de dentes
                           int t_shift,            // deslocamento da linha dos dentes
                           double &lips_buffer[],  // buffer do indicador para a linha da boca
                           int l_shift,            // deslocamento da linha da boca
                           int ind_handle,         // manipulador do indicator iAlligator 
                           int amount              // número de valores copiados
                           )
  {
//--- redefinir o código de erro
   ResetLastError();
//--- preencher uma parte do array JawsBuffer com valores a partir do buffer do indicador que tem índice 0
   if(CopyBuffer(ind_handle,0,-j_shift,amount,jaws_buffer)<0)
     {
      //--- Se a cópia falhar, informe o código de erro
      PrintFormat("Falha para copiar dados a partir do indicador iAlligator, código de erro %d",GetLastError());
      //--- parar com resultado zero - significa que indicador é considerado como não calculado
      return(false);
     }
 
//--- preencher uma parte do array TeethBuffer com valores a partir do buffer do indicador que tem índice 1
   if(CopyBuffer(ind_handle,1,-t_shift,amount,teeth_buffer)<0)
     {
      //--- Se a cópia falhar, informe o código de erro
      PrintFormat("Falha para copiar dados a partir do indicador iAlligator, código de erro %d",GetLastError());
      //--- parar com resultado zero - significa que indicador é considerado como não calculado
      return(false);
     }
 
//--- preencher uma parte do array LipsBuffer com valores a partir do buffer do indicador que tem o índice 2
   if(CopyBuffer(ind_handle,2,-l_shift,amount,lips_buffer)<0)
     {
      //--- Se a cópia falhar, informe o código de erro
      PrintFormat("Falha para copiar dados a partir do indicador iAlligator, código de erro %d",GetLastError());
      //--- parar com resultado zero - significa que indicador é considerado como não calculado
      return(false);
     }
//--- está tudo bem
   return(true);
  }  
//+------------------------------------------------------------------+
//| Função de desinicialização do indicador                          |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- limpar o gráfico após excluir o indicador
   Comment("");
  }