//+------------------------------------------------------------------+
//| Demo_iAlligator.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Индикатор демонстрирует как нужно получать данные"
#property description "индикаторных буферов для технического индикатора iAlligator."
#property description "Символ и таймфрейм, на котором рассчитывается индикатор,"
#property description "задаются параметрами symbol и period."
#property description "Способ создания хэндла задается параметром 'type' (тип функции)."
#property description "Все остальные параметры как в стандартном Аллигаторе."
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_plots 3
//--- plot Jaws
#property indicator_label1 "Jaws"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrBlue
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- plot Teeth
#property indicator_label2 "Teeth"
#property indicator_type2 DRAW_LINE
#property indicator_color2 clrRed
#property indicator_style2 STYLE_SOLID
#property indicator_width2 1
//--- plot Lips
#property indicator_label3 "Lips"
#property indicator_type3 DRAW_LINE
#property indicator_color3 clrLime
#property indicator_style3 STYLE_SOLID
#property indicator_width3 1
//+------------------------------------------------------------------+
//| Перечисление способов создания хэндла |
//+------------------------------------------------------------------+
enum Creation
{
Call_iAlligator, // использовать iAlligator
Call_IndicatorCreate // использовать IndicatorCreate
};
//--- входные параметры
input Creation type=Call_iAlligator; // тип функции
input string symbol=" "; // символ
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // таймфрейм
input int jaw_period=13; // период для линии Челюстей
input int jaw_shift=8; // смещение линии Челюстей
input int teeth_period=8; // период для линии Зубов
input int teeth_shift=5; // смещение линии Челюстей
input int lips_period=5; // период для линии Губ
input int lips_shift=3; // смещение линии Губ
input ENUM_MA_METHOD MA_method=MODE_SMMA; // метод усреднения линий Аллигатора
input ENUM_APPLIED_PRICE applied_price=PRICE_MEDIAN;// тип цены, от которой строится Аллигатор
//--- индикаторные буферы
double JawsBuffer[];
double TeethBuffer[];
double LipsBuffer[];
//--- переменная для хранения хэндла индикатора iAlligator
int handle;
//--- переменная для хранения
string name=symbol;
//--- имя индикатора на графике
string short_name;
//--- будем хранить количество значений в индикаторе Alligator
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- привязка массивов к индикаторномым буферам
SetIndexBuffer(0,JawsBuffer,INDICATOR_DATA);
SetIndexBuffer(1,TeethBuffer,INDICATOR_DATA);
SetIndexBuffer(2,LipsBuffer,INDICATOR_DATA);
//--- зададим смещение для каждой линии
PlotIndexSetInteger(0,PLOT_SHIFT,jaw_shift);
PlotIndexSetInteger(1,PLOT_SHIFT,teeth_shift);
PlotIndexSetInteger(2,PLOT_SHIFT,lips_shift);
//--- определимся с символом, на котором строится индикатор
name=symbol;
//--- удалим пробелы слева и справа
StringTrimRight(name);
StringTrimLeft(name);
//--- если после этого длина строки name нулевая
if(StringLen(name)==0)
{
//--- возьмем символ с графика, на котором запущен индикатор
name=_Symbol;
}
//--- создадим хэндл индикатора
if(type==Call_iAlligator)
handle=iAlligator(name,period,jaw_period,jaw_shift,teeth_period,
teeth_shift,lips_period,lips_shift,MA_method,applied_price);
else
{
//--- заполним структуру значениями параметров индикатора
MqlParam pars[8];
//--- периоды и смещения линий Аллигатора
pars[0].type=TYPE_INT;
pars[0].integer_value=jaw_period;
pars[1].type=TYPE_INT;
pars[1].integer_value=jaw_shift;
pars[2].type=TYPE_INT;
pars[2].integer_value=teeth_period;
pars[3].type=TYPE_INT;
pars[3].integer_value=teeth_shift;
pars[4].type=TYPE_INT;
pars[4].integer_value=lips_period;
pars[5].type=TYPE_INT;
pars[5].integer_value=lips_shift;
//--- тип сглаживания
pars[6].type=TYPE_INT;
pars[6].integer_value=MA_method;
//--- тип цены
pars[7].type=TYPE_INT;
pars[7].integer_value=applied_price;
//--- создадим хэндл
handle=IndicatorCreate(name,period,IND_ALLIGATOR,8,pars);
}
//--- если не удалось создать хэндл
if(handle==INVALID_HANDLE)
{
//--- сообщим о неудаче и выведем номер ошибки
PrintFormat("Не удалось создать хэндл индикатора iAlligator для пары %s/%s, код ошибки %d",
name,
EnumToString(period),
GetLastError());
//--- работа индикатора завершается досрочно
return(INIT_FAILED);
}
//--- покажем на какой паре символ/таймфрейм рассчитан индикатор Alligator
short_name=StringFormat("iAlligator(%s/%s, %d,%d,%d,%d,%d,%d)",name,EnumToString(period),
jaw_period,jaw_shift,teeth_period,teeth_shift,lips_period,lips_shift);
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- нормальное выполнение инициализации индикатора
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- количество копируемых значений из индикатора iAlligator
int values_to_copy;
//--- узнаем количество рассчитанных значений в индикаторе
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() вернул %d, код ошибки %d",calculated,GetLastError());
return(0);
}
//--- если это первый запуск вычислений нашего индикатора или изменилось количество значений в индикаторе iAlligator
//--- или если необходимо рассчитать индикатор для двух или более баров (значит что-то изменилось в истории)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- если массив JawsBuffer больше, чем значений в индикаторе iAlligator на паре symbol/period, то копируем не все
//--- в противном случае копировать будем меньше, чем размер индикаторных буферов
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- значит наш индикатор рассчитывается не в первый раз и с момента последнего вызова OnCalculate())
//--- для расчета добавилось не более одного бара
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- заполняем массивы значениями из индикатора Alligator
//--- если FillArraysFromBuffer вернула false, значит данные не готовы - завершаем работу
if(!FillArraysFromBuffers(JawsBuffer,jaw_shift,TeethBuffer,teeth_shift,LipsBuffer,lips_shift,handle,values_to_copy)) return(0);
//--- сформируем сообщение
string comm=StringFormat("%s ==> Обновлено значений в индикаторе %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- выведем на график служебное сообщение
Comment(comm);
//--- запомним количество значений в индикаторе Alligator
bars_calculated=calculated;
//--- вернем значение prev_calculated для следующего вызова
return(rates_total);
}
//+------------------------------------------------------------------+
//| Заполняем индикаторные буферы из индикатора iAlligator |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &jaws_buffer[], // индикаторный буфер для линии Челюстей
int j_shift, // смещение линии Челюстей
double &teeth_buffer[], // индикаторный буфер для линии Зубов
int t_shift, // смещение линии Зубов
double &lips_buffer[], // индикаторный буфер для линии Губ
int l_shift, // смещение линии Губ
int ind_handle, // хэндл индикатора iAlligator
int amount // количество копируемых значений
)
{
//--- сбросим код ошибки
ResetLastError();
//--- заполняем часть массива JawsBuffer значениями из индикаторного буфера под индексом 0
if(CopyBuffer(ind_handle,0,-j_shift,amount,jaws_buffer)<0)
{
//--- если копирование не удалось, сообщим код ошибки
PrintFormat("Не удалось скопировать данные из индикатора iAlligator, код ошибки %d",GetLastError());
//--- завершим с нулевым результатом - это означает, что индикатор будет считаться нерассчитанным
return(false);
}
//--- заполняем часть массива TeethBuffer значениями из индикаторного буфера под индексом 1
if(CopyBuffer(ind_handle,1,-t_shift,amount,teeth_buffer)<0)
{
//--- если копирование не удалось, сообщим код ошибки
PrintFormat("Не удалось скопировать данные из индикатора iAlligator, код ошибки %d",GetLastError());
//--- завершим с нулевым результатом - это означает, что индикатор будет считаться нерассчитанным
return(false);
}
//--- заполняем часть массива LipsBuffer значениями из индикаторного буфера под индексом 2
if(CopyBuffer(ind_handle,2,-l_shift,amount,lips_buffer)<0)
{
//--- если копирование не удалось, сообщим код ошибки
PrintFormat("Не удалось скопировать данные из индикатора iAlligator, код ошибки %d",GetLastError());
//--- завершим с нулевым результатом - это означает, что индикатор будет считаться нерассчитанным
return(false);
}
//--- все получилось
return(true);
}
//+------------------------------------------------------------------+
//| Indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- почистим график при удалении индикатора
Comment("");
}
|