//+------------------------------------------------------------------+
//| Demo_iSAR.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| ;https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "O indicador demonstra como obter dados"
#property description "de buffers do indicador para o indicador técnico iSAR."
#property description "Um símbolo e o prazo utilizado para o cálculo do indicador,"
#property description "são definidos pelos parâmetros de símbolo e período."
#property description "O método de criação do manipulador é definido através do parâmetro "type" (tipo de função)."
#property description "Todos os outros parâmetros são similares ao padrão Parabolic Stop and Reverse."
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots 1
//--- desenhando iSAR
#property indicator_label1 "iSAR"
#property indicator_type1 DRAW_ARROW
#property indicator_color1 clrBlue
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//+------------------------------------------------------------------+
//| Enumerador dos métodos de criação do manipulador |
//+------------------------------------------------------------------+
enum Creation
{
Call_iSAR, // usar iSAR
Call_IndicatorCreate // usar IndicatorCreate
};
//--- parâmetros de entrada
input Creation type=Call_iSAR; // tipo de função
input double step=0.02; // passo - o fator de aceleração para arrastar as paradas
input double maximum=0.2; // máximo valor do passo
input string symbol=" "; // símbolo
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // timeframe
//--- buffers do indicador
double iSARBuffer[];
//--- variável para armazenar o manipulador do indicator iSAR
int handle;
//--- variável para armazenamento
string name=symbol;
//--- nome do indicador num gráfico
string short_name;
//--- manteremos o número de valores no indicador Parabolic SAR
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado |
//+------------------------------------------------------------------+
int OnInit()
{
//--- atribuição de array para buffer do indicador
SetIndexBuffer(0,iSARBuffer,INDICATOR_DATA);
//--- definir um código de símbolo do conjunto de caracteres Wingdings para a propriedade PLOT_ARROW para exibir num gráfico
PlotIndexSetInteger(0,PLOT_ARROW,159);
//--- determinar o símbolo do indicador, é desenhado para
name=symbol;
//--- excluir os espaços à direita e à esquerda
StringTrimRight(name);
StringTrimLeft(name);
//--- se resulta em comprimento zero da string do 'name'
if(StringLen(name)==0)
{
//--- tomar o símbolo do gráfico, o indicador está anexado para
name=_Symbol;
}
//--- criar manipulador do indicador
if(type==Call_iSAR)
handle=iSAR(name,period,step,maximum);
else
{
//--- preencher a estrutura com os parâmetros do indicador
MqlParam pars[2];
//--- valor do passo
pars[0].type=TYPE_DOUBLE;
pars[0].double_value=step;
//--- limite do valor do passo que pode ser usado para os cálculos
pars[1].type=TYPE_DOUBLE;
pars[1].double_value=maximum;
handle=IndicatorCreate(name,period,IND_SAR,2,pars);
}
//--- se o manipulador não é criado
if(handle==INVALID_HANDLE)
{
//--- mensagem sobre a falha e a saída do código de erro
PrintFormat("Falha ao criar o manipulador do indicador iSAR para o símbolo %s/%s, código de erro %d",
name,
EnumToString(period),
GetLastError());
//--- o indicador é interrompido precocemente
return(INIT_FAILED);
}
//--- mostra que o símbolo/prazo do indicador Parabolic SAR é calculado para
short_name=StringFormat("iSAR(%s/%s, %G, %G)",name,EnumToString(period),
step,maximum);
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inicialização normal do indicador
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- número de valores copiados a partir do indicador iSAR
int values_to_copy;
//--- determinar o número de valores calculados no indicador
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() retornando %d, código de erro %d",calculated,GetLastError());
return(0);
}
//--- se for o princípio do cálculo do indicador, ou se o número de valores é modificado no indicador iSAR
//--- ou se é necessário cálculo do indicador para duas ou mais barras (isso significa que algo mudou no histórico do preço)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- se o array iSARBuffer é maior do que o número de valores no indicador iSAR para o símbolo/período, então não copiamos tudo
//--- caso contrário, copiamos menor do que o tamanho dos buffers do indicador
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- isso significa que não é a primeira vez do cálculo do indicador, é desde a última chamada de OnCalculate())
//--- para o cálculo não mais do que uma barra é adicionada
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- preencher os arrays com valores do indicador iSAR
//--- se FillArrayFromBuffer retorna falso, significa que a informação não está pronta ainda, sair da operação
if(!FillArrayFromBuffer(iSARBuffer,handle,values_to_copy)) return(0);
//--- formar a mensagem
string comm=StringFormat("%s ==> Valor atualizado no indicador %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- exibir a mensagem de serviço no gráfico
Comment(comm);
//--- memorizar o número de valores no indicador SAR
bars_calculated=calculated;
//--- retorna o valor prev_calculated para a próxima chamada
return(rates_total);
}
//+------------------------------------------------------------------+
//| Preencher buffers do indicador a partir do indicador iSAR |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &sar_buffer[], // buffer do indicator para valores do Parabolic SAR
int ind_handle, // manipulador do indicador iSAR
int amount // número de valores copiados
)
{
//--- redefinir o código de erro
ResetLastError();
//--- preencher uma parte do array iSARBuffer com valores do buffer do indicador que tem índice 0 (zero)
if(CopyBuffer(ind_handle,0,0,amount,sar_buffer)<0)
{
//--- Se a cópia falhar, informe o código de erro
PrintFormat("Falha ao copiar dados do indicador iSAR, código de erro %d",GetLastError());
//--- parar com resultado zero - significa que indicador é considerado como não calculado
return(false);
}
//--- está tudo bem
return(true);
}
//+------------------------------------------------------------------+
//| Função de desinicialização do indicador |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- limpar o gráfico após excluir o indicador
Comment("");
}
|