iBands

A função retorna o manipulador do indicador Bollinger Bands®.

int  iBands(
   string              symbol,            // símbolo nome
   ENUM_TIMEFRAMES     period,            // período
   int                 bands_period,      // período para o cálculo da média da linha
   int                 bands_shift,       // deslocamento horizontal do indicador
   double              deviation,         // número de desvios padrão
   ENUM_APPLIED_PRICE  applied_price      // tipo de preço ou manipulador
   );

Parâmetros

symbol

[in] O nome do símbolo de segurança, os dados que devem ser usados para calcular o indicador. O valor NULL significa o símbolo atual.

period

[in] O valor do período pode ser um dos valores ENUM_TIMEFRAMES, 0 (zero) significa o prazo corrente.

bands_period

[in]  O período médio da linha principal do indicador.

bands_shift

[in] O deslocamento do indicador em relação ao gráfico de preço.

deviation

[in]  Desvio a partir da linha principal.

applied_price

[in]  O preço usado. Pode ser qualquer das constantes de preços ENUM_APPLIED_PRICE ou um manipulador de outro indicador.

Valor de retorno

Retorna o manipulador de um indicador técnico especifico, em caso de falha de retorna INVALID_HANDLE. A memória do computador pode ser liberada a partir de um indicador que não é mais utilizado, usando a função IndicatorRelease(), onde o manipulador de indicador é transmitido.

Observação

Os números de buffer são os seguintes: 0 - BASE_LINE, 1 - UPPER_BAND, 2 - LOWER_BAND

Exemplo:

//+------------------------------------------------------------------+
//|                                                  Demo_iBands.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                            ;https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "O indicador demonstra como obter dados"
#property description "buffers do indicador para o indicador técnico iBands."
#property description "Um símbolo e o prazo utilizado para o cálculo do indicador,"
#property description "são definidos pelos parâmetros de símbolo e período."
#property description "O método de criação do manipulador é definido através do parâmetro "type" (tipo de função)."
 
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_plots   3
//--- plotar linha superior
#property indicator_label1  "Upper"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrMediumSeaGreen
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plotar linha inferior
#property indicator_label2  "Lower"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrMediumSeaGreen
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- plotar linha média
#property indicator_label3  "Middle"
#property indicator_type3   DRAW_LINE
#property indicator_color3  clrMediumSeaGreen
#property indicator_style3  STYLE_SOLID
#property indicator_width3  1
//+------------------------------------------------------------------+
//| Enumerador dos métodos de criação do manipulador                 |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iBands,            // usar iBands
   Call_IndicatorCreate    // usar IndicatorCreate
  };
//--- parâmetros de entrada
input Creation             type=Call_iBands;          // tipo da função
input int                  bands_period=20;           // período da média móvel
input int                  bands_shift=0;             // deslocamento
input double               deviation=2.0;             // número de desvios padrão
input ENUM_APPLIED_PRICE   applied_price=PRICE_CLOSE// tipo de preço
input string               symbol=" ";                // símbolo
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;     // timeframe
//--- buffers do indicador
double         UpperBuffer[];
double         LowerBuffer[];
double         MiddleBuffer[];
//--- variável para armazenar o manipulador do indicador iBands
int    handle;
//--- variável para armazenamento
string name=symbol;
//--- nome do indicador num gráfico
string short_name;
//--- manteremos o número de valores no indicador Bollinger Bands
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- atribuição de arrays para buffers do indicador
   SetIndexBuffer(0,UpperBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,LowerBuffer,INDICATOR_DATA);
   SetIndexBuffer(2,MiddleBuffer,INDICATOR_DATA);
//--- definir o deslocamento de cada linha
   PlotIndexSetInteger(0,PLOT_SHIFT,bands_shift);
   PlotIndexSetInteger(1,PLOT_SHIFT,bands_shift);      
   PlotIndexSetInteger(2,PLOT_SHIFT,bands_shift);      
//--- determinar o símbolo do indicador, é desenhado para
   name=symbol;
//--- excluir os espaços à direita e à esquerda
   StringTrimRight(name);
   StringTrimLeft(name);
//--- se resulta em comprimento zero da string do 'name'
   if(StringLen(name)==0)
     {
      //--- tomar o símbolo do gráfico, o indicador está anexado para
      name=_Symbol;
     }
//--- criar manipulador do indicador
   if(type==Call_iBands)
      handle=iBands(name,period,bands_period,bands_shift,deviation,applied_price);
   else
     {
      //--- preencher a estrutura com os parâmetros do indicador
      MqlParam pars[4];
      //--- período da média móvel
      pars[0].type=TYPE_INT;
      pars[0].integer_value=bands_period;
      //--- deslocamento
      pars[1].type=TYPE_INT;
      pars[1].integer_value=bands_shift;
      //--- número do desvio padrão
      pars[2].type=TYPE_DOUBLE;
      pars[2].double_value=deviation;
      //--- tipo de preço
      pars[3].type=TYPE_INT;
      pars[3].integer_value=applied_price;
      handle=IndicatorCreate(name,period,IND_BANDS,4,pars);
     }
//--- se o manipulador não é criado
   if(handle==INVALID_HANDLE)
     {
      //--- mensagem sobre a falha e a saída do código de erro
      PrintFormat("Falha ao criar o manipulador do indicador iBands para o símbolo %s/%s, código de erro %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- o indicador é interrompido precocemente
      return(INIT_FAILED);
     }
//--- mostra que o símbolo/prazo do indicador Bollinger Bands é calculado para
   short_name=StringFormat("iBands(%s/%s, %d,%d,%G,%s)",name,EnumToString(period),
                           bands_period,bands_shift,deviation,EnumToString(applied_price));
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inicialização normal do indicador  
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- número de valores copiados a partir do indicador iBands
   int values_to_copy;
//--- determinar o número de valores calculados no indicador
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() retornando %d, código de erro %d",calculated,GetLastError());
      return(0);
     }
//--- se for o princípio do cálculo do indicador, ou se o número de valores é modificado no indicador iBands
//--- ou se é necessário cálculo do indicador para duas ou mais barras (isso significa que algo mudou no histórico do preço)
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- se o tamanho buffers do indicador é maior do que o número de valores no indicador iBands para símbolo/período, então não copiamos tudo 
      //--- caso contrário, copiamos menor do que o tamanho dos buffers do indicador
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
     }
   else
     {
      //--- isso significa que não é a primeira vez do cálculo do indicador, é desde a última chamada de OnCalculate())
      //--- para o cálculo não mais do que uma barra é adicionada
      values_to_copy=(rates_total-prev_calculated)+1;
     }
//--- preencher o array com valores do indicador Bollinger Bands
//--- se FillArraysFromBuffer retorna falso, isto significa que a informação ainda não está pronta, sair da operação
   if(!FillArraysFromBuffers(MiddleBuffer,UpperBuffer,LowerBuffer,bands_shift,handle,values_to_copy)) return(0);
//--- formar a mensagem
   string comm=StringFormat("%s ==>  Valor atualizado no indicador %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- exibir a mensagem de serviço no gráfico
   Comment(comm);
//--- memorizar o número de valores no indicador Bollinger Bands
   bars_calculated=calculated;
//--- retorna o valor prev_calculated para a próxima chamada
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Preencher buffers do indicador a partir do indicador iBands      |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &base_values[],     // buffer do indicador da linha média do Bollinger Bands
                           double &upper_values[],    // buffer do indicador da borda superior
                           double &lower_values[],    // buffer do indicador da borda inferior
                           int shift,                 // deslocamento
                           int ind_handle,            // manipulador do indicador iBands
                           int amount                 // número dos valores copiados
                           )
  {
//--- redefinir o código de erro
   ResetLastError();
//--- preencher uma parte do array MiddleBuffer com valores do buffer do indicador que tem índice 0 (zero)
   if(CopyBuffer(ind_handle,0,-shift,amount,base_values)<0)
     {
      //--- Se a cópia falhar, informe o código de erro
      PrintFormat("Falha ao copiar dados do indicador iBands, código de erro %d",GetLastError());
      //--- parar com resultado zero - significa que indicador é considerado como não calculado
      return(false);
     }
 
//--- preencher uma parte do array UpperBuffer com valores do buffer do indicador que tem índice 1
   if(CopyBuffer(ind_handle,1,-shift,amount,upper_values)<0)
     {
      //--- Se a cópia falhar, informe o código de erro
      PrintFormat("Falha ao copiar dados do indicador iBands, código de erro %d",GetLastError());
      //--- parar com resultado zero - significa que indicador é considerado como não calculado
      return(false);
     }
 
//--- preencher uma parte do array LowerBuffer com valores do buffer do indicador que tem o índice 2
   if(CopyBuffer(ind_handle,2,-shift,amount,lower_values)<0)
     {
      //--- Se a cópia falhar, informe o código de erro
      PrintFormat("Falha ao copiar dados do indicador iBands, código de erro %d",GetLastError());
      //--- parar com resultado zero - significa que indicador é considerado como não calculado
      return(false);
     }
//--- está tudo bem
   return(true);
  }
//+------------------------------------------------------------------+
//| Função de desinicialização do indicador                          |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   if(handle!=INVALID_HANDLE)
      IndicatorRelease(handle);
//--- limpar o gráfico após excluir o indicador
   Comment("");
  }