iMomentum

A função retorna o manipulador do indicador Momentum. Tem apenas um buffer.

int  iMomentum(
   string               symbol,            // símbolo nome
   ENUM_TIMEFRAMES      period,            // período
   int                  mom_period,        // período médio
   ENUM_APPLIED_PRICE   applied_price      // tipo de preço ou de manipulador
   );

Parâmetros

symbol

[in] O nome do símbolo de segurança, os dados que devem ser usados para calcular o indicador. O valor NULL significa o símbolo atual.

period

[in] O valor do período pode ser um dos valores ENUM_TIMEFRAMES, 0 (zero) significa o prazo corrente.

mom_period

[in]  Período médio(barras contadas) para o cálculo de modificação do preço.

applied_price

[in]  O preço usado. Pode ser qualquer das constantes de preços ENUM_APPLIED_PRICE ou um manipulador de outro indicador.

Valor de retorno

Retorna o manipulador de um indicador técnico especifico, em caso de falha de retorna INVALID_HANDLE. A memória do computador pode ser liberada a partir de um indicador que não é mais utilizado, usando a função IndicatorRelease(), onde o manipulador de indicador é transmitido.

Exemplo:

//+------------------------------------------------------------------+
//|                                               Demo_iMomentum.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                            ;https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "O indicador demonstra como obter dados"
#property description "de buffers do indicador para o indicador técnico iMomentum."
#property description "Um símbolo e o prazo utilizado para o cálculo do indicador,"
#property description "são definidos pelos parâmetros de símbolo e período."
#property description "O método de criação do manipulador é definido através do parâmetro "type" (tipo de função)."
#property description "Todos os outros parâmetros são similares ao padrão Momentum."
 
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
//--- plotar iMomentum
#property indicator_label1  "iMomentum"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrDodgerBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//+------------------------------------------------------------------+
//| Enumerador dos métodos de criação do manipulador                 |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iMomentum,         // usar iMomentum
   Call_IndicatorCreate    // usar IndicatorCreate
  };
//--- parâmetros de entrada
input Creation             type=Call_iMomentum;       // tipo de função
input int                  mom_period=14;             // período do indicador Momentum
input ENUM_APPLIED_PRICE   applied_price=PRICE_CLOSE// tipo de preço
input string               symbol=" ";                // símbolo
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;     // timeframe
//--- buffer do indicador
double         iMomentumBuffer[];
//--- variável para armazenar o manipulador do indicator iMomentum
int    handle;
//--- variável para armazenamento
string name=symbol;
//--- nome do indicador num gráfico
string short_name;
//--- manteremos o número de valores no indicador Momentum
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- atribuição de array para buffer do indicador
   SetIndexBuffer(0,iMomentumBuffer,INDICATOR_DATA);
//--- determinar o símbolo do indicador, é desenhado para
   name=symbol;
//--- excluir os espaços à direita e à esquerda
   StringTrimRight(name);
   StringTrimLeft(name);
//--- se resulta em comprimento zero da string do 'name'
   if(StringLen(name)==0)
     {
      //--- tomar o símbolo do gráfico, o indicador está anexado para
      name=_Symbol;
     }
//--- criar manipulador do indicador
   if(type==Call_iMomentum)
      handle=iMomentum(name,period,mom_period,applied_price);
   else
     {
      //--- preencher a estrutura com os parâmetros do indicador
      MqlParam pars[2];
      //--- período
      pars[0].type=TYPE_INT;
      pars[0].integer_value=mom_period;
      //--- tipo de preço
      pars[1].type=TYPE_INT;
      pars[1].integer_value=applied_price;
      handle=IndicatorCreate(name,period,IND_MOMENTUM,2,pars);
     }
//--- se o manipulador não é criado
   if(handle==INVALID_HANDLE)
     {
      //--- mensagem sobre a falha e a saída do código de erro
      PrintFormat("Falha ao criar o manipulador do indicador iMomentum para o símbolo %s/%s, código de erro %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- o indicador é interrompido precocemente
      return(INIT_FAILED);
     }
//--- mostra que o símbolo/prazo do indicador Momentum é calculado para
   short_name=StringFormat("iMomentum(%s/%s, %d, %s)",name,EnumToString(period),
                           mom_period, EnumToString(applied_price));
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inicialização normal do indicador  
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- número de valores copiados a partir do indicador iMomentum
   int values_to_copy;
//--- determinar o número de valores calculados no indicador
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() retornando %d, código de erro %d",calculated,GetLastError());
      return(0);
     }
//--- se for o princípio do cálculo do indicador, ou se o número de valores é modificado no indicador iMomentum
//--- ou se é necessário cálculo do indicador para duas ou mais barras (isso significa que algo mudou no histórico do preço)
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- se o array iMomentumBuffer é maior do que o número de valores no indicador iMomentum para o símbolo/período, então não copiamos tudo
      //--- caso contrário, copiamos menor do que o tamanho dos buffers do indicador
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
     }
   else
     {
      //--- isso significa que não é a primeira vez do cálculo do indicador, é desde a última chamada de OnCalculate())
      //--- para o cálculo não mais do que uma barra é adicionada
      values_to_copy=(rates_total-prev_calculated)+1;
     }
//--- preencher o array iMomentumBuffer com valores do indicador Momentum
//--- se FillArrayFromBuffer retorna falso, significa que a informação não está pronta ainda, sair da operação
   if(!FillArrayFromBuffer(iMomentumBuffer,handle,values_to_copy)) return(0);
//--- formar a mensagem
   string comm=StringFormat("%s ==>  Valor atualizado no indicador %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- exibir a mensagem de serviço no gráfico
   Comment(comm);
//--- memorizar o número de valores no indicador Momentum
   bars_calculated=calculated;
//--- retorna o valor prev_calculated para a próxima chamada
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Preencher buffers do indicador a partir do indicador iMomentum   |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &values[],  // buffer do indicator para valores do Momentum
                         int ind_handle,    // manipulador do indicador iMomentum
                         int amount         // número de valores copiados
                         )
  {
//--- redefinir o código de erro
   ResetLastError();
//--- preencher uma parte do array iMomentumBuffer com valores do buffer do indicador que tem índice 0 (zero)
   if(CopyBuffer(ind_handle,0,0,amount,values)<0)
     {
      //--- Se a cópia falhar, informe o código de erro
      PrintFormat("Falha ao copiar dados do indicador iMomentum, código de erro %d",GetLastError());
      //--- parar com resultado zero - significa que indicador é considerado como não calculado
      return(false);
     }
//--- está tudo bem
   return(true);
  }
//+------------------------------------------------------------------+
//| Função de desinicialização do indicador                          |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- limpar o gráfico após excluir o indicador
   Comment("");
  }