CopyBuffer

int  CopyBuffer(
  int      indicator_handle,    // 指標ハンドル
  int      buffer_num,          // 指標バッファ番号
  int      start_pos,            // 開始位置
  int      count,                // 複製する量
  double    buffer[]              // 受け取り側の配列
  );

int  CopyBuffer(
  int      indicator_handle,    // 指標ハンドル
  int      buffer_num,          // 指標バッファ番号
  datetime  start_time,          // 開始日と時刻
  int      count,                // 複製する量
  double    buffer[]             // 受け取り側の配列
  );

int  CopyBuffer(
  int      indicator_handle,    // 指標ハンドル
  int      buffer_num,          // 指標バッファ番号
  datetime  start_time,          // 開始日と時刻
  datetime  stop_time,            // 終了日と時刻
  double   buffer[]             // 受け取り側の配列
  );

//+------------------------------------------------------------------+
//|                                              TestCopyBuffer3.mq5 |
//|                        Copyright 2009, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "2009, MetaQuotes Software Corp."
#property link     "https://www.mql5.com"
#property version   "1.00"
 
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
//---- MA をプロットする
#property indicator_label1 "MA"
#property indicator_type1   DRAW_LINE
#property indicator_color1 clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1  1
//--- 入力パラメータ
input bool               AsSeries=true;
input int               period=15;
input ENUM_MA_METHOD     smootMode=MODE_EMA;
input ENUM_APPLIED_PRICE price=PRICE_CLOSE;
input int                shift=0;
//--- 指標バッファ
double                   MABuffer[];
int                      ma_handle;
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数                                            |
//+------------------------------------------------------------------+
int OnInit()
 {
//--- 指標バッファマッピング
  SetIndexBuffer(0,MABuffer,INDICATOR_DATA);
  Print("Parameter AsSeries = ",AsSeries);
  Print("Indicator buffer after SetIndexBuffer() is a timeseries = ",
        ArrayGetAsSeries(MABuffer));
//--- 指標短縮名を設定する
  IndicatorSetString(INDICATOR_SHORTNAME,"MA("+period+")"+AsSeries);
//--- AsSeries を設定する（入力パラメータによる）
  ArraySetAsSeries(MABuffer,AsSeries);
  Print("Indicator buffer after ArraySetAsSeries(MABuffer,true); is a timeseries = ",
        ArrayGetAsSeries(MABuffer));
//---
  ma_handle=iMA(Symbol(),0,period,shift,smootMode,price);
  return(INIT_SUCCEEDED);
 }
//+------------------------------------------------------------------+
//| カスタム指標の反復関数                                                |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
              const int prev_calculated,
              const datetime &time[],
              const double &open[],
              const double &high[],
              const double &low[],
              const double &close[],
              const long &tick_volume[],
              const long &volume[],
              const int &spread[])
 {
//--- データが全て計算されたかをチェックする
  if(BarsCalculated(ma_handle)<rates_total) return(0);
//--- 全てのデータのコピーは出来ない
  int to_copy;
  if(prev_calculated>rates_total || prev_calculated<=0) to_copy=rates_total;
  else
    {
     to_copy=rates_total-prev_calculated;
    //--- 最終値は常に複製される
     to_copy++;
    }
//--- コピーを試みる
  if(CopyBuffer(ma_handle,0,0,to_copy,MABuffer)<=0) return(0);
//--- 次の呼び出しのために prev_calculated の値を返す
  return(rates_total);
 }
//+------------------------------------------------------------------+