ushort  MathSwap(
   ushort  value      // valore
   );

uint  MathSwap(
   uint   value      // valore
   );

ulong  MathSwap(
   ulong  value      // valore
   );

#property script_show_inputs
 
input ulong  InpLongValue  =  1;    // Inserisci qui qualsiasi valore ulong
input uint   InpIntValue   =  2;    // Inserisci qui qualsiasi valore uint
input ushort InpShortValue =  3;    // Inserisci qui qualsiasi valore ushort
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
 
//--- stampa nel journal i valori inseriti e convertiti da MathSwap() nella rappresentazione decimale e binaria
   Print(ValueDescription(InpLongValue));
   Print(ValueDescription(InpIntValue));
   Print(ValueDescription(InpShortValue));
   /*
  risultato:
   ulong value: 1
   ulong value: 72057594037927936 using MathSwap()
   binary ulong value: 0000000000000000000000000000000000000000000000000000000000000001
   binary ulong value: 0000000100000000000000000000000000000000000000000000000000000000 using MathSwap()
   
   uint value: 2
   uint value: 33554432 using MathSwap()
   binary uint value: 00000000000000000000000000000010
   binary uint value: 00000010000000000000000000000000 using MathSwap()
   
   ushort value: 3
   ushort value: 768 using MathSwap()
   binary ushort value: 0000000000000011
   binary ushort value: 0000001100000000 using MathSwap()
   */
  }
//+-------------------------------------------------------------------------+
//| Restituisce il testo che descrive i valori delle variabili              |
//+-------------------------------------------------------------------------+
template <typename T>
string ValueDescription(T x)
  {
   int    num_bits   = sizeof(T)*8;
   string type_name  = typename(T);
   string bin_x      = NumberToBinaryString(x);
   string bin_swap_x = NumberToBinaryString(MathSwap(x));
   return(StringFormat("%s value: %lld\n%s value: %lld using MathSwap()\nbinary %s value: %0*s\nbinary %s value: %0*s using MathSwap()\n", type_name, x, type_name, MathSwap(x), type_name, num_bits, bin_x, type_name, num_bits, bin_swap_x));
  }
//+---------------------------------------------------------------------------------------------+
//| Restituisce la rappresentazione binaria di un numero come stringa                           |
//+---------------------------------------------------------------------------------------------+
template <typename T>
string NumberToBinaryString(T x)
  {
   string res  = "";
   int    i    = -1;
   uchar  size = sizeof(T)*8-1;
   ulong  mask = (ulong)1<<size;
   while(!((x<<++i)& mask));
   for(; i <=size; i++)
      res += !((x<<i)& mask) ? "0" : "1";
   return res;
  }