#define GRAPH_WIDTH 750
#define GRAPH_HEIGHT 350
#include <Graphics\Graphic.mqh>
CGraphic ExtGraph;
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
vector delta=vector::Full(101,2*M_PI/100);
delta[0]=0;
//--- ottenere 101 valori da 0 a 2 pi greco con passo delta
vector X=delta.CumSum();
//-- calcolare il valore del coseno iperbolico per ogni valore del vettore X
vector Y=MathCosh(X);
//-- trasferire i valori calcolati dai vettori agli array
double x_array[],y_array[];
X.Swap(x_array);
Y.Swap(y_array);
//--- traccia un grafico dei valori vettoriali calcolati
CurvePlot(x_array,y_array,clrDodgerBlue);
//--- attendere di aver premuto i tasti Escape o PgDn per eliminare il grafico (prendere uno screenshot) ed uscire
while(!IsStopped())
{
if(StopKeyPressed())
break;
Sleep(16);
}
//--- pulire
ExtGraph.Destroy();
}
//+-----------------------------------------------------------------------------------------------------------+
//| Quando si preme ESC, restituire 'true' |
//| Quando si preme PgDn, prendere uno screenshot del grafico e restituire 'true' |
//| Altrimenti restituire 'false' |
//+-----------------------------------------------------------------------------------------------------------+
bool StopKeyPressed()
{
//--- se viene premuto ESC, restituisce 'true'
if(TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)!=0)
return(true);
//--- se PgDn viene premuto e uno screenshot del grafico viene preso correttamente, restituisce 'true'
if(TerminalInfoInteger(TERMINAL_KEYSTATE_PAGEDOWN)!=0 && MakeAndSaveScreenshot(MQLInfoString(MQL_PROGRAM_NAME)+"_Screenshot"))
return(true);
//--- restituisce 'false'
return(false);
}
//+------------------------------------------------------------------+
//| Crea un oggetto grafico e disegna una curva |
//+------------------------------------------------------------------+
void CurvePlot(double &x_array[], double &y_array[], const color colour)
{
ExtGraph.Create(ChartID(), "Graphic", 0, 0, 0, GRAPH_WIDTH, GRAPH_HEIGHT);
ExtGraph.CurveAdd(x_array, y_array, ColorToARGB(colour), CURVE_LINES);
ExtGraph.IndentUp(30);
ExtGraph.CurvePlotAll();
string text1="Press ESC to delete the graph and stop the script, or";
string text2="Press PgDn to create a screen, delete the graph and stop the script";
ExtGraph.TextAdd(54, 9, text1, ColorToARGB(clrBlack));
ExtGraph.TextAdd(54,21, text2, ColorToARGB(clrBlack));
ExtGraph.Update();
}
//+------------------------------------------------------------------+
//| Fa uno screenshot e salva l'immagine in un file |
//+------------------------------------------------------------------+
bool MakeAndSaveScreenshot(const string file_name)
{
string file_names[];
ResetLastError();
int selected=FileSelectDialog("Save Picture", NULL, "All files (*.*)|*.*", FSD_WRITE_FILE, file_names, file_name+".png");
if(selected<1)
{
if(selected<0)
PrintFormat("%s: FileSelectDialog() function returned error %d", __FUNCTION__, GetLastError());
return false;
}
bool res=false;
if(ChartSetInteger(0,CHART_SHOW,false))
res=ChartScreenShot(0, file_names[0], GRAPH_WIDTH, GRAPH_HEIGHT);
ChartSetInteger(0,CHART_SHOW,true);
return(res);
}
|
