datetime ExtBarTimeOpen;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- règle le compteur sur 1 seconde
EventSetTimer(1);
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
Comment("");
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- récupère l'heure d'ouverture de la barre courante
ExtBarTimeOpen=time[rates_total-1];
//--- retourne la valeur de prev_calculated pour le prochain appel
return(rates_total);
}
//+------------------------------------------------------------------+
//| Timer function |
//+------------------------------------------------------------------+
void OnTimer()
{
//--- définit l'heure d'ouverture de la barre précédente
static datetime bar_open_time=ExtBarTimeOpen;
//--- compte le nombre de secondes écoulées depuis l'ouverture de la barre
static int seconds=int(TimeCurrent()-ExtBarTimeOpen);
//--- si l'heure d'ouverture précédente n'est pas égale à l'heure actuelle, alors c'est une nouvelle barre
//--- écrit la nouvelle heure d'ouverture comme la précédente et met les secondes à zéro
if(bar_open_time!=ExtBarTimeOpen)
{
bar_open_time=ExtBarTimeOpen;
seconds=0;
}
//--- augmente et ajuste le nombre de secondes écoulées depuis l'ouverture de la barre
seconds++;
if(seconds>PeriodSeconds(PERIOD_CURRENT))
seconds=0;
//--- heure d'ouverture de la barre au format yyyy.mm.dd hh:mi
string bar_time_open=TimeToString(ExtBarTimeOpen);
//--- heure actuelle au format yyyy.mm.dd hh:mi:ss
string time_current=TimeToString(TimeCurrent(),TIME_DATE|TIME_MINUTES|TIME_SECONDS);
//--- nombre de secondes restantes avant l'ouverture d'une nouvelle barre
int sec_left=PeriodSeconds(PERIOD_CURRENT)-seconds;
//--- temps restant jusqu'à ce que la barre actuelle se ferme, sous la forme hh:mm:ss
string time_left=TimeToString(sec_left,TIME_MINUTES|TIME_SECONDS);
//--- crée la chaîne de sortie
string txt=StringFormat("Opening time of the current bar: %s\n"+
"Time Current: %s\n"+
"Seconds have passed since the bar opened: %d\n"+
"Approximately seconds left before bar closes: %d\n"+
"Time remaining until bar closes: %s",bar_time_open,time_current,seconds,sec_left,time_left);
//--- affiche l'heure d'ouverture de la barre et l'heure actuelle,
//--- le nombre de secondes écoulées depuis l'ouverture de la barre actuelle et restant jusqu'à sa fermeture et
//--- le temps restant jusqu'à la fermeture de la barre actuelle dans le commentaire
Comment(txt);
/*
result on M1:
Opening time of the current bar: 2024.02.22 18:06
Time Current: 2024.02.22 18:06:24
Seconds have passed since the bar opened: 25
Approximately seconds left before bar closes: 35
Time remaining until bar closes: 00:00:35
result on M5:
Opening time of the current bar: 2024.02.22 18:05
Time Current: 2024.02.22 18:07:28
Seconds have passed since the bar opened: 149
Approximately seconds left before bar closes: 151
Time remaining until bar closes: 00:02:31
result on H1:
Opening time of the current bar: 2024.02.22 18:00
Time Current: 2024.02.22 18:08:13
Seconds have passed since the bar opened: 494
Approximately seconds left before bar closes: 3106
Time remaining until bar closes: 00:51:46
result on D1:
Opening time of the current bar: 2024.02.22 00:00
Time Current: 2024.02.22 18:11:01
Seconds have passed since the bar opened: 65462
Approximately seconds left before bar closes: 20938
Time remaining until bar closes: 05:48:58
*/
}
|