SymbolInfoSessionQuote

bool  SymbolInfoSessionQuote(
   string            name,                // nombre del símbolo
   ENUM_DAY_OF_WEEK  day_of_week,         // día de la semana
   uint              session_index,       // número de sesión
   datetime&         from,                // hora de apertura de la sesión
   datetime&         to                   // hora de cierre de la sesión
   );

#define SYMBOL_NAME   Symbol()
#define SESSION_INDEX 0
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- imprimimos el encabezado con el símbolo y el índice de sesión SESSION_INDEX y
//--- en un ciclo por los días de la semana de lunes a viernes, imprimimos en el registro las horas de inicio y fin de la sesión de cotización
   PrintFormat("Symbol %s, Quote session %d:", SYMBOL_NAME, SESSION_INDEX);
   for(int i=MONDAY; i<SATURDAY; i++)
      SymbolInfoSessionQuotePrint(SYMBOL_NAME, (ENUM_DAY_OF_WEEK)i, SESSION_INDEX);
   /*
   resultado:
   Symbol RU000A103661, Quote session 0:
   - Monday     06:45 - 00:00
   - Tuesday    06:45 - 00:00
   - Wednesday  06:45 - 00:00
   - Thursday   06:45 - 00:00
   - Friday     06:45 - 00:00
   */
  }
//+------------------------------------------------------------------+
//| Mostramos en el registro la hora de inicio y finalización de     |
//| la sesión de cotización para los símbolos y días indicados       |
//+------------------------------------------------------------------+
void SymbolInfoSessionQuotePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
  {
//--- declaramos las variables para registrar el inicio y el final de la sesión de cotización
   datetime date_from;  // hora de inicio de la sesión
   datetime date_to;    // hora de finalización de la sesión
   
//--- obtenemos los datos de la sesión de cotización
   if(!SymbolInfoSessionQuote(symbol, day_of_week, session_index, date_from, date_to))
     {
      Print("SymbolInfoSessionQuote() failed. Error ", GetLastError());
      return;
     }
     
//--- creamos el nombre del día de la semana a partir de una constante de enumeración
   string week_day=EnumToString(day_of_week);
   if(week_day.Lower())
      week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
 
//--- mostramos en el registro los datos de la sesión de cotización
   PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
  }