English
preview
Разработка собственного торгового советника (Часть 2): Управление рисками и динамический расчет объема позиции

Разработка собственного торгового советника (Часть 2): Управление рисками и динамический расчет объема позиции

MetaTrader 5 — Трейдинг |
12 0
Solomon Anietie Sunday
Solomon Anietie Sunday

Содержание

  1. Введение
  2. Что было упущено в части 1: проблема фиксированного объема в лотах
  3. Решение 1: расчет объема позиции с учетом риска
  4. Решение 2: учет ограничений брокера
  5. Решение 3: адаптивное управление риском при просадках
  6. Заключение


Введение

В части 1 вы уже усовершенствовали базовый советник на основе пересечения скользящих средних, превратив его в технически корректный каркас: он обрабатывает сигналы один раз на бар, выделяет свои позиции по магическому номеру, устанавливает стоп-лоссы на основе ATR и обрабатывает основные ошибки. Для алгоритмических трейдеров и разработчиков советников остается одна серьезная проблема: советник по-прежнему использует фиксированный объем в лотах, заданный параметром LotSize. Одно это решение нарушает контроль риска: денежный риск на сделку меняется с изменением волатильности (при росте ATR), не масштабируется в зависимости от баланса счета и никак не реагирует на просадки; кроме того, брокеры могут отклонять в остальном корректные ордера из-за несоблюдения минимального расстояния до стоп-лосса или требований к объему в лотах.

В этой статье мы устраняем этот недостаток: привязываем объем позиции к выбранному проценту от средств счета, используя расстояние до стоп-лосса на основе ATR в качестве входного параметра для расчета объема позиции, проверяем стоп-уровни и объемы на соответствие ограничениям брокера SYMBOL_* и добавляем дополнительный механизм адаптивного управления риском, который снижает подверженность риску при просадках. В результате получается модуль расчета объема позиции для MetaTrader 5, пригодный для повторного использования: он делает риск в долларах предсказуемым и позволяет соблюдать его при исполнении сделок без изменения логики стратегии.

Предмет данной статьи

К концу этой части мы:

  • Заменим фиксированный входной параметр LotSize расчетом объема позиции с учетом риска.
  • Рассчитаем объем в лотах на основе баланса счета, процента риска и расстояния до стоп-лосса, определяемого по ATR.
  • Добавим проверку соблюдения установленных брокером требований к минимальному расстоянию до стоп-лосса и ограничений по объему.
  • Добавим адаптивный механизм управления рисками, который автоматически снижает подверженность риску во время просадок.

Описанные здесь методы не относятся исключительно к стратегии пересечения скользящих средних. Та же логика расчета объема позиции применима к большинству торговых советников, которые рассчитывают стоп-лосс перед отправкой ордера.


Что было упущено в части 1: проблема фиксированного объема в лотах

Именно так наш советник в настоящее время открывает сделки. Объем в лотах — это фиксированный входной параметр, который задается один раз и используется для каждой сделки независимо от условий:

input double LotSize = 0.1;        // Fixed lot size

А вот где входной параметр объема в лотах используется напрямую — как при покупке, так и при продаже:

if(canOpenTrade)
  {
   double sl = NormalizeDouble(ask - stopDistance, digits);
   double tp = NormalizeDouble(ask + (stopDistance * TPRatio), digits);

// Execute Buy trade and check result
   if(!trade.Buy(LotSize, _Symbol, 0.0, sl, tp, "Fixed EA Buy"))
     {
      PrintFormat("Buy failed. Retcode: %u (%s)",
                  trade.ResultRetcode(),
                  trade.ResultRetcodeDescription());
     }
  }
if(canOpenTrade)
  {
   double sl = NormalizeDouble(bid + stopDistance, digits);
   double tp = NormalizeDouble(bid - (stopDistance * TPRatio), digits);

// Execute Sell trade and check result
   if(!trade.Sell(LotSize, _Symbol, 0.0, sl, tp, "Fixed EA Sell"))
     {
      PrintFormat("Sell failed. Retcode: %u (%s)",
                  trade.ResultRetcode(),
                  trade.ResultRetcodeDescription());
     }
  }

На первый взгляд все выглядит нормально: LotSize — это просто еще один настраиваемый входной параметр, подобно FastMA или ATRMultiplier. Разница заключается в том, что объем в лотах определяет подверженность риску. Если подверженность риску остается неизменной при изменении состояния счета, то фактически ею вообще не управляют.

Проблема 1: объем в лотах не связан с балансом счета

Трейдер, использующий LotSize = 0.1 на счете с 1 000 долларов, и другой трейдер, применяющий ту же настройку на счете с 50 000 долларов, явно принимают на себя разный риск. Первый может рисковать значительной долей средств счета в каждой сделке, тогда как второй рискует лишь малой долей. Поскольку советник никогда не корректирует объем в лотах автоматически, трейдерам приходится самостоятельно пересчитывать и обновлять его при каждом значительном изменении баланса счета — и, честно говоря, большинство из них этого не делает.

Проблема 2: объем в лотах не связан с расстоянием до стоп-лосса

Эта проблема менее очевидна, поскольку она частично сводит на нет то, чего мы добились с помощью стоп-лоссов на основе ATR в части 1. Напомним, что расстояние до стоп-лосса рассчитывается на основе текущего значения ATR:

double stopDistance = atrValue * ATRMultiplier;

По мере изменения волатильности расстояние до стоп-лосса соответственно увеличивается или уменьшается. Именно такого поведения мы и хотим добиться. Проблема заключается в том, что LotSize остается фиксированным. Большее расстояние до стоп-лосса при том же объеме в лотах означает больший денежный риск, хотя запланированный трейдером риск не изменился.

Проблема 3: Отсутствие реакции на просадку

Торговый советник также не учитывает результаты собственной работы. Он использует один и тот же объем в лотах независимо от того, достигают ли средства счета новых максимумов или счет восстанавливается после серии убыточных сделок. Система, ориентированная на защиту капитала, автоматически снижала бы подверженность риску во время просадок, не полагаясь на ручное вмешательство. Эту логику мы оставим опциональной, поскольку не все трейдеры стремятся к консервативному подходу.

В следующем разделе мы решим эту проблему, рассчитывая объем в лотах на основе выбранного процента риска и текущего расстояния до стоп-лосса, а не используя фиксированный входной параметр.


Решение 1: Расчет объема позиции с учетом риска

Мы выявили два недостатка использования фиксированного объема в лотах: такой подход не учитывает ни баланс счета, ни расстояние до стоп-лосса, рассчитанное на основе ATR. У обеих проблем одна первопричина: объем в лотах изначально не был привязан к риску. Решение заключается в том, чтобы рассчитывать объем в лотах исходя из суммы, которой мы готовы рискнуть в каждой сделке.

Вместо вопроса «Сколькими лотами мне торговать?» задайте себе вопрос: «Какую сумму я готов потерять, если в этой сделке сработает стоп-лосс?» Эта сумма определяется как процент от баланса счета. Расстояние до стоп-лосса позволяет определить убыток при объеме позиции в один лот и рассчитать объем в лотах, при котором денежный риск остается постоянным. Эффективная система управления рисками следует принципу: сумма риска остается фиксированной, а объем позиции корректируется так, чтобы сохранять эту сумму неизменной.

Замена фиксированного входного параметра

Фиксированное значение входного параметра LotSize заменяется фиксированным процентным значением:

input double RiskPercent = 1.0;    // Risk per trade [%]

Процент риска, равный 1.0, означает, что объем каждой сделки рассчитывается так, чтобы при срабатывании стоп-лосса убыток составлял примерно 1 % от текущего баланса счета независимо от расстояния до стоп-лосса.

Преобразование расстояния до стоп-лосса в денежный риск

Чтобы рассчитать объем в лотах, сначала нужно определить убыток по позиции объемом в один лот при срабатывании стоп-лосса. Мы получаем два свойства торгового инструмента:

double tickSize  = SymbolInfoDouble(_Symbol, SYMBOL_TRADE_TICK_SIZE);
double tickValue = SymbolInfoDouble(_Symbol, SYMBOL_TRADE_TICK_VALUE);

SYMBOL_TRADE_TICK_SIZE — это минимальное изменение цены торгового инструмента, а SYMBOL_TRADE_TICK_VALUE — денежная стоимость этого изменения в валюте счета для одного лота. Зная расстояние до стоп-лосса, легко рассчитать денежный убыток на один лот:

double monetaryRiskPerLot = (stopDistance / tickSize) * tickValue;

Примечание: стоимость тика и размер контракта

Некоторые торговые советники рассчитывают денежный риск вручную на основе размера контракта и стоимости одного пункта. Проблема в том, что такой расчет корректен лишь для стандартных валютных пар. SYMBOL_TRADE_TICK_VALUE уже учитывает размер контракта и, при необходимости, конвертацию валюты, поэтому эта формула дает правильный результат для индексов, металлов или любых торговых инструментов с нестандартными спецификациями контрактов. Прямое использование SYMBOL_TRADE_TICK_VALUE позволяет избежать целого ряда незаметных ошибок в расчетах, которые выявляются только при запуске советника на незнакомом торговом инструменте.

Создание функции расчета объема в лотах

Имея значение денежного риска на один лот, мы можем объединить этот расчет в функцию, которую можно использовать повторно:

//+------------------------------------------------------------------+
//| Calculate lot size from account risk and stop distance           |
//+------------------------------------------------------------------+
double CalculateLotSize(double stopDistance)
  {
   double balance = AccountInfoDouble(ACCOUNT_BALANCE);
   double riskAmount = balance * (RiskPercent / 100.0);

   double tickSize  = SymbolInfoDouble(_Symbol, SYMBOL_TRADE_TICK_SIZE);
   double tickValue = SymbolInfoDouble(_Symbol, SYMBOL_TRADE_TICK_VALUE);

   if(tickSize <= 0 || tickValue <= 0)
     {
      Print("Invalid tick size or tick value. Cannot calculate lot size.");
      return 0.0;
     }

   double monetaryRiskPerLot = (stopDistance / tickSize) * tickValue;
   if(monetaryRiskPerLot <= 0)
     {
      Print("Monetary risk per lot is zero. Cannot calculate lot size.");
      return 0.0;
     }

   return NormalizeDouble(riskAmount / monetaryRiskPerLot, 2);
  }

Проверки корректности данных обязательны, а не факультативны. Функция SymbolInfoDouble() вполне может возвращать ноль во время синхронизации торгового инструмента или при недоступности его свойств. Возврат значения 0.0 позволяет советнику безопасно пропустить сделку, вместо того чтобы сформировать недопустимый ордер или вызвать ошибку деления на ноль.

Интеграция в функцию OnTick()

Приведенная выше функция вызывается сразу после расчета расстояния до стоп-лосса на основе ATR:

//--- Calculate the dynamic stop distance
   double stopDistance = atrValue * ATRMultiplier;
   int digits = (int)SymbolInfoInteger(_Symbol, SYMBOL_DIGITS);
   double lotSize = CalculateLotSize(stopDistance);

Если рассчитанный объем в лотах недопустим, мы просто пропускаем сделку:

   if(lotSize <= 0)
     {
      Print("Calculated lot size is invalid. Trade skipped.");
      return;
     }

Наконец, в коде выполнения сделок мы заменяем все вхождения входного параметра LotSize на lotSize. Для покупки:

if(!trade.Buy(lotSize, _Symbol, 0.0, sl, tp, "Fixed EA Buy"))
  {
   PrintFormat("Buy failed. Retcode: %u (%s)",
               trade.ResultRetcode(),
               trade.ResultRetcodeDescription());
  }

А для продажи:

if(!trade.Sell(lotSize, _Symbol, 0.0, sl, tp, "Fixed EA Sell"))
  {
   PrintFormat("Sell failed. Retcode: %u (%s)",
               trade.ResultRetcode(),
               trade.ResultRetcodeDescription());
  }

С учетом этих изменений рассмотрим один и тот же торговый сигнал в двух рыночных условиях:

  • При низком ATR расстояние до стоп-лосса меньше, поэтому денежный риск на один лот ниже. Советник компенсирует это увеличением объема в лотах.
  • При высоком значении ATR расстояние до стоп-лосса больше, поэтому при объеме в один лот под риском оказывается большая сумма денег. Советник соответственно уменьшает объем в лотах.

В обеих ситуациях максимальный убыток по-прежнему определяется выбранным процентом RiskPercent от текущего баланса счета. Теперь советник автоматически адаптирует свою подверженность риску как к волатильности рынка, так и к росту или снижению баланса счета, чего невозможно достичь при фиксированном объеме в лотах. Но это еще не все. Значение lotSize необходимо проверить на соответствие ограничениям брокера по минимальному и максимальному объему и шагу объема, а значение stopDistance — на соответствие минимальному расстоянию до стоп-лосса, установленному брокером. Если хотя бы одно из этих значений выходит за допустимые пределы, ордер будет отклонен. Это мы исправим на следующем шаге.


Решение 2: Учет ограничений брокера

Расчет объема позиции с учетом риска позволяет получить математически корректный объем в лотах. Это не означает, что брокер примет такой объем. Для каждого торгового инструмента установлены ограничения: минимальное расстояние до стоп-лосса, минимальный и максимальный объем сделки, а также шаг объема. Если проигнорировать любое из этих ограничений, торговый сервер может отклонить ордер даже при корректном расчете риска.

Проблема 1: Минимальное расстояние до стоп-лосса

В части 1 мы отметили это как меру безопасности, которую стоит добавить позже, и теперь пришло время ее реализовать. Брокеры устанавливают минимальное расстояние между ценой входа и стоп-лоссом с помощью параметра SYMBOL_TRADE_STOPS_LEVEL. Если при торговле инструментами с низкой волатильностью или на младших таймфреймах расстояние до стоп-лосса, рассчитанное на основе ATR, оказывается меньше этого предела, то рассчитанный нами стоп-лосс находится слишком близко к цене, и ордер будет отклонен.

Решение: Проверка и корректировка

Прежде чем окончательно установить стоп-лосс, мы сравниваем расстояние от цены до него с минимумом, установленным брокером, и при необходимости отодвигаем стоп-лосс дальше от цены:

//--- Validate minimum stop distance
   double minStopDistance = SymbolInfoInteger(_Symbol, SYMBOL_TRADE_STOPS_LEVEL) * _Point;
   if(stopDistance < minStopDistance)
     {
      Print("Stop distance too tight. Adjusting from ", stopDistance, " to ", minStopDistance);
      stopDistance = minStopDistance;
     }

Значение SYMBOL_TRADE_STOPS_LEVEL возвращается в пунктах, поэтому перед сравнением со stopDistance, уже выраженным в ценовых единицах, его необходимо преобразовать в ценовое расстояние с помощью _Point.

Примечание о порядке действий

Эта проверка должна быть выполнена до вызова функции CalculateLotSize(). Если расстояние до стоп-лосса увеличивается, то увеличивается и денежный риск для одного лота. Если сначала рассчитать объем в лотах, а затем скорректировать стоп-лосс, эти два параметра окажутся несогласованными, что сведет на нет точность, достигнутую в решении 1.

Таким образом, правильная последовательность выглядит следующим образом:

  1. Рассчитать расстояние до стоп-лосса.
  2. Проверить, что оно не меньше минимального расстояния, установленного брокером.
  3. Рассчитать объем в лотах.

Проблема 2: Объем в лотах также должен быть допустимым

Брокеры также устанавливают ограничения на объем сделки. Для каждого торгового инструмента заданы минимальный и максимальный объем в лотах, а также допустимый шаг объема. Рассчитанное значение, например 0.133 лота или значение ниже минимального, будет отклонено независимо от точности расчета риска.

Решение: Ограничение и округление

Это выполняется внутри функции CalculateLotSize(), непосредственно перед возвратом результата:

//--- Confine and round to the broker's volume rules
   double minLot  = SymbolInfoDouble(_Symbol, SYMBOL_VOLUME_MIN);
   double maxLot  = SymbolInfoDouble(_Symbol, SYMBOL_VOLUME_MAX);
   double lotStep = SymbolInfoDouble(_Symbol, SYMBOL_VOLUME_STEP);

   double lotSize = riskAmount / monetaryRiskPerLot;
   lotSize = MathMax(minLot, MathMin(lotSize, maxLot));
   lotSize = NormalizeDouble(lotSize / lotStep, 0) * lotStep;

   return lotSize;

Сначала функции MathMax() и MathMin() удерживают рассчитанный объем в лотах в пределах диапазона, разрешенного брокером. Затем округление до ближайшего значения, кратного lotStep, обеспечивает соответствие допустимому шагу объема. Это заменяет следующую строку из решения 1:

return NormalizeDouble(riskAmount / monetaryRiskPerLot, 2);

Округление до двух знаков после запятой предполагает, что для каждого торгового инструмента шаг объема составляет 0.01 лота, однако это не всегда так.

Включение обеих проверок в OnTick()

После внедрения обеих проверок соответствующий фрагмент кода в функции OnTick() принимает следующий вид:

//--- Calculate the dynamic stop distance
   double stopDistance = atrValue * ATRMultiplier;

//--- Validate minimum stop distance
   double minStopDistance = SymbolInfoInteger(_Symbol, SYMBOL_TRADE_STOPS_LEVEL) * _Point;
   if(stopDistance < minStopDistance)
     {
      Print("Stop distance too tight. Adjusting from ", stopDistance, " to ", minStopDistance);
      stopDistance = minStopDistance;
     }

   double lotSize = CalculateLotSize(stopDistance);

   if(lotSize <= 0)
     {
      Print("Calculated lot size is invalid. Trade skipped.");
      return;
     }

Все остальное, например расчеты стоп-лосса и тейк-профита, а также вызовы функций trade.Buy() и trade.Sell(), остается практически без изменений. Разница заключается в том, что расстояние до стоп-лосса и объем в лотах прошли проверку, поэтому каждый ордер, отправляемый брокеру, соответствует его торговым правилам.

Решение 1 обеспечило точность расчета объема в лотах. Решение 2 делает этот объем допустимым для торговли, то есть приемлемым для брокера. Расчет риска может быть математически верным, но при этом нарушать правила брокера. В таком случае сделка не будет исполнена, поэтому система управления рисками фактически окажется бесполезной. После внесения обоих решений советник рассчитывает объем позиций с учетом риска, соблюдая ограничения брокера на исполнение ордеров.

Тестирование расчета объема позиции с учетом риска

После внедрения расчета объема позиции с учетом риска необходимо проверить в тестере стратегий, работает ли он должным образом. Это важная проверка: ошибка в расчете может привести к тому, что советник будет рисковать гораздо большими суммами, чем предполагалось, и вызвать потери на реальном счете еще до обнаружения проблемы. Чтобы проверить это, мы настраиваем желаемый процент риска, стоп-лосс и тейк-профит. В данном примере в каждой сделке мы рискуем 1 % от суммы на счете, составляющей 10 000 долларов. Это означает, что срабатывание стоп-лосса должно привести к убытку примерно в 100 долларов, а при соотношении прибыли к риску 2:1 ожидаемая прибыль должна составить около 200 долларов.

Тестирование расчета объема позиции с учетом риска_входные параметры

Результаты приведены ниже:

Тестирование расчета объема позиции с учетом риска_результаты

По итогам десяти завершенных сделок средний результат убыточной сделки составляет примерно −103.16 доллара, а прибыльной — примерно 196.90 доллара. Эти значения очень близки к ожидаемым −100 и +200 долларам, что подтверждает корректную работу расчета объема позиции. Незначительные расхождения являются ожидаемыми и не обусловлены самим расчетом риска. Они обусловлены обычными торговыми издержками и факторами исполнения, такими как спреды, проскальзывание и комиссии.

Еще одно направление совершенствования связано с тем, что объем каждой сделки по-прежнему рассчитывается одним и тем же способом независимо от последних результатов торговли. Независимо от того, достигнут ли новый максимум средств счета или счет восстанавливается после просадки, советник использует один и тот же процент риска. Именно этот адаптивный механизм мы и реализуем далее.


Решение 3: Адаптивное управление риском при просадках

Теперь советник правильно рассчитывает объем сделок и соблюдает правила брокера, но по-прежнему подходит ко всем сделкам одинаково, независимо от результатов торговли на счете. Независимо от того, достигнут ли только что новый максимум средств счета или счет уже находится в просадке после нескольких убыточных сделок, RiskPercent остается неизменным. Более консервативный подход заключается в автоматическом снижении риска во время просадок, вместо того чтобы полагаться на ручное вмешательство трейдера.

Идея: риск, изменяющийся в зависимости от просадки

Мы будем использовать следующий механизм: отслеживать максимум средств счета, определять, насколько текущие средства счета снизились относительно этого максимума, и снижать процент риска, как только просадка превысит заданный порог. По мере восстановления счета восстанавливается обычный уровень риска. На приведенной ниже иллюстрации эта идея представлена наглядно:

Иллюстрация адаптивного управления риском при просадке

Добавьте входные параметры

Эта функция управляется тремя новыми входными параметрами: переключателем, уровнем просадки, при котором она активируется, и степенью снижения риска.

input bool   EnableAdaptiveRisk  = false; // Reduce risk during drawdowns
input double DDLevel             = 3.0;   // Drawdown % that triggers reduced risk
input double RiskReductionFactor = 0.5;   // Adaptive risk multiplier when triggered [0.5 = half risk]

Эту функцию можно не использовать; если оставить ее отключенной (false), советник будет вести себя точно так же, как и после решения 2.

Отслеживайте максимум средств счета

Для расчета просадки советник должен запоминать максимум средств счета. Поскольку это значение должно сохраняться между тиками, мы сохраняем его в качестве глобальной переменной. Она будет добавлена ниже других глобальных переменных:

//--- Global Variables
CTrade trade;
int fastHandle, slowHandle;
int atrHandle;
double g_PeakEquity = 0.0;

Создайте функцию адаптивного управления риском

//+------------------------------------------------------------------+
//| Return the risk percent to use, adjusted for drawdown            |
//+------------------------------------------------------------------+
double GetAdaptiveRiskPercent()
  {
   if(!EnableAdaptiveRisk)
      return RiskPercent;

   double equity = AccountInfoDouble(ACCOUNT_EQUITY);

//--- Initialize or update the peak
   if(g_PeakEquity == 0.0 || equity > g_PeakEquity)
      g_PeakEquity = equity;

//--- Calculate current drawdown from peak
   double drawdownPercent = 0.0;
   if(g_PeakEquity > 0.0)
      drawdownPercent = (g_PeakEquity - equity) / g_PeakEquity * 100.0;

   PrintFormat("Adaptive Risk | Drawdown: %.2f%% | Risk Used: %.2f%%",
               drawdownPercent,
               (drawdownPercent >= DDLevel) ? RiskPercent * RiskReductionFactor : RiskPercent);

   if(drawdownPercent >= DDLevel)
      return RiskPercent * RiskReductionFactor;

   return RiskPercent;
  }

Когда адаптивное управление риском отключено, функция просто возвращает значение RiskPercent, что позволяет функции CalculateLotSize() вызывать ее без дополнительной проверки того, включено ли адаптивное управление риском. Вызов PrintFormat() необязателен, но полезен при тестировании. Он фиксирует как текущую просадку, так и применяемый процент риска, что позволяет легко убедиться, что эта функция работает ожидаемым образом в тестере стратегий или при реальной торговле.

Примечание о различии между средствами счета и балансом счета:

Просадка рассчитывается относительно ACCOUNT_EQUITY, а не ACCOUNT_BALANCE. Баланс изменяется только при закрытии сделки, поэтому значительный плавающий убыток по открытой позиции останется полностью незамеченным. Средства счета отражают нереализованные убытки по мере их возникновения, а именно на них нам и нужно реагировать.

Внедрение в функцию CalculateLotSize()

Изменить нужно только участок кода, в котором рассчитывается сумма риска. Вместо RiskPercent будет использоваться вызов новой функции. Было:

double balance = AccountInfoDouble(ACCOUNT_BALANCE);
double riskAmount = balance * (RiskPercent / 100.0);

Стало:

double balance = AccountInfoDouble(ACCOUNT_BALANCE);
double riskAmount = balance * (GetAdaptiveRiskPercent() / 100.0);

Все остальное, включая расчет денежного риска, проверку объема и проверки ограничений брокера, добавленные в предыдущих решениях, остается без изменений. Механизм адаптации лишь изменяет процент риска, используемый в существующем расчете.

Пояснение

Поскольку g_PeakEquity только увеличивается, просадка всегда измеряется относительно зафиксированного максимума средств счета. Как только просадка достигает DDLevel, для каждой новой сделки применяется процент риска RiskPercent × RiskReductionFactor, пока просадка не уменьшится до значения ниже порогового. Вместо того чтобы рисковать одной и той же суммой на протяжении серии убыточных сделок, советник автоматически снижает риск при ухудшении результатов.

В данной реализации используется один порог просадки. На практике некоторые советники предусматривают небольшой буфер восстановления перед возвратом к полному уровню риска. Без такого буфера уровень риска может переключаться туда и обратно, если средства счета колеблются вблизи порогового значения. Хотя это усовершенствование делает поведение системы более плавным, представленная здесь версия уже обеспечивает основное преимущество адаптивного расчета объема позиции.

После внесения решений 1–3 торговый советник рассчитывает объем позиций исходя из риска для счета, проверяет каждый ордер на соответствие торговым правилам брокера и автоматически снижает подверженность риску во время просадок.

Упорядочивание функции OnTick()

Большая часть функции OnTick(), в том числе определение появления нового бара, проверки готовности индикаторов, копирование данных скользящих средних и ATR, а также проверка спреда, остается без изменений. Повторять это было бы излишне. Вместо этого мы сосредоточимся на решениях 1–3. Эти изменения дублируют одну и ту же логику в двух ветвях: «покупка» и «продажа». Несколько дублирующихся строк кода теперь отвечают за учет открытых позиций, адаптивное управление риском, проверку стоп-уровней и расчет объема позиции. В программной инженерии нет необходимости поддерживать два практически идентичных блока кода. Более лаконичным решением будет перенести все в одну функцию, учитывающую направление.

Выделенная функция исполнения торговых операций

//+------------------------------------------------------------------+
//| Validate, size, and open a trade in the given direction          |
//| direction: 1 = Buy, -1 = Sell                                    |
//+------------------------------------------------------------------+
void OpenPosition(int direction, double price, double stopDistance, int digits)
  {
//--- Position awareness check
   bool canOpenTrade = false;
   if(AllowHedging)
      canOpenTrade = (CountOpenPositionsByDirection(direction) == 0);
   else
      canOpenTrade = (CountOpenPositions() == 0);

   if(!canOpenTrade)
      return;

//--- Lot size from the validated stop distance
   double lotSize = CalculateLotSize(stopDistance);
   if(lotSize <= 0)
     {
      Print("Calculated lot size is invalid. Trade skipped.");
      return;
     }

//--- SL/TP and execution, direction-specific
   double sl, tp;
   if(direction == 1)
     {
      sl = NormalizeDouble(price - stopDistance, digits);
      tp = NormalizeDouble(price + (stopDistance * TPRatio), digits);
      if(!trade.Buy(lotSize, _Symbol, 0.0, sl, tp, "Fixed EA Buy"))
         PrintFormat("Buy failed. Retcode: %u (%s)", trade.ResultRetcode(),
                     trade.ResultRetcodeDescription());
     }
   else
     {
      sl = NormalizeDouble(price + stopDistance, digits);
      tp = NormalizeDouble(price - (stopDistance * TPRatio), digits);
      if(!trade.Sell(lotSize, _Symbol, 0.0, sl, tp, "Fixed EA Sell"))
         PrintFormat("Sell failed. Retcode: %u (%s)", trade.ResultRetcode(),
                     trade.ResultRetcodeDescription());
     }
  }

Весь код, предшествующий проверке спреда и проверке расстояния до стоп-лосса, остается точно таким же, как после решения 2. Меняется только логика пересечения скользящих средних: теперь она передает исполнение торговых операций новой функции:

//--- Check crossover on the latest closed bar (index 1) and execute trade
   if(fast[1] > slow[1] && fast[2] <= slow[2])
      OpenPosition(1, ask, stopDistance, digits);
   else
      if(fast[1] < slow[1] && fast[2] >= slow[2])
         OpenPosition(-1, bid, stopDistance, digits);
  }
Теперь функция OnTick() определяет лишь наличие сигнала. После подтверждения сигнала функция OpenPosition() отвечает за исполнение торговой операции: проверку возможности открытия позиции с учетом уже открытых позиций, расчет объема позиции, расчет уровней SL/TP и отправку ордера. Любые будущие улучшения расчета объема позиции, проверки соответствия требованиям брокера или исполнения торговых операций потребуется вносить только в одном месте, а не в двух. Кроме того, это гарантирует, что ордера на покупку и продажу всегда будут следовать одним и тем же правилам, что исключает риск постепенного расхождения этих двух ветвей по мере развития советника.



Распространенные ошибки и способы их устранения

Здесь мы кратко рассмотрим некоторые типичные ошибки, которые эта статья помогает устранить трейдерам при создании собственных советников.

Ошибка Решение
Ручной расчет денежного риска на основе размера контракта и стоимости пункта. Используйте SYMBOL_TRADE_TICK_VALUE и SYMBOL_TRADE_TICK_SIZE, которые автоматически учитывают различные характеристики контрактов.
Расчет объема в лотах до проверки расстояния до стоп-лосса.
Сначала проверьте расстояние до стоп-лосса на соответствие SYMBOL_TRADE_STOPS_LEVEL, а затем рассчитайте объем в лотах на основе окончательного значения расстояния.
Округление объема в лотах до фиксированного числа знаков после запятой. Ограничьте рассчитанный объем в лотах пределами SYMBOL_VOLUME_MIN/MAX и округлите его с учетом SYMBOL_VOLUME_STEP, поскольку не для каждого торгового инструмента допустим шаг объема в 0.01 лота.



Еще предстоит обсудить

Используемая в данной статье модель риска исходит из того, что стоп-лосс определяет максимально допустимый уровень риска. Это подходит для многих трендовых стратегий, например стратегии на основе пересечения скользящих средних, но это не единственный способ управления позициями.

Системы на основе возврата к среднему могут рассчитывать объем сделок с учетом целевой прибыли и ожидаемого расстояния возврата к среднему. В таком случае стоп-лосс служит защитным элементом системы, а не входным параметром для расчета объема позиции. В некоторых стратегиях традиционный стоп-лосс вообще не используется. Вместо этого в них задают максимально допустимую просадку по счету (например, 3–5 %) и управляют позицией до достижения целевой прибыли или до того момента, когда плавающий убыток достигнет установленного для счета предела. В этих системах лимит риска на уровне счета заменяет стоп-лосс на уровне сделки в качестве основного показателя риска. Расширение этой системы для поддержки альтернативных подходов — естественный следующий шаг, заслуживающий отдельной статьи. Однако реализация этих подходов выходит за рамки данной статьи.


Заключение

Использование фиксированного объема в лотах было последним оставшимся недостатком торгового советника из части 1: при таком подходе риск в долларах не был привязан к балансу счета, волатильности и результатам торговли на счете. В этой статье мы заменили статический параметр LotSize практической системой расчета объема позиции, которую можно протестировать и которая:

  • Рассчитывает объем в лотах на основе выбранного процента риска RiskPercent от средств счета и расстояния до стоп-лосса, определяемого по ATR (с использованием SYMBOL TRADE TICK SIZE и SYMBOL TRADE TICK VALUE для преобразования ценового расстояния в денежный риск);
  • Перед расчетом объема позиции проверяет расстояние до стоп-лосса на соответствие SYMBOL TRADE STOPS_LEVEL и при необходимости корректирует его;
  • Ограничивает и округляет рассчитанный объем в лотах в соответствии с параметрами SYMBOL VOLUME MIN/MAX/STEP, чтобы брокер принимал ордера;
  • Добавляет необязательный адаптивный механизм (выявление просадки относительно максимума средств счета) для автоматического снижения риска во время серий убыточных сделок;
  • Централизует выполнение в рамках единой функции, учитывающей направление операции, благодаря чему ветви покупки и продажи всегда следуют одним и тем же правилам.

В совокупности эти изменения обеспечивают предсказуемый риск в долларах на одну сделку, который изменяется в зависимости от баланса счета и волатильности рынка, позволяют избежать отклонения ордеров сервером и могут быть внедрены в другие советники без изменения их торговой логики. Перед переходом к реальной торговле следует использовать тестер стратегий, чтобы подтвердить ожидаемый убыток в долларах при срабатывании стоп-лосса и проверить корректность округления и соблюдения ограничений. Исходный код, использованный в данной статье, предоставляется для непосредственного использования и сравнения с исходной реализацией.

Перевод с английского произведен MetaQuotes Ltd.
Оригинальная статья: https://www.mql5.com/en/articles/23638

Прикрепленные файлы |
Особенности написания Пользовательских Индикаторов Особенности написания Пользовательских Индикаторов
Написание пользовательских индикаторов в торговой системе MetaTrader 4
Метаразметка классических стратегий (Часть 3): Фильтрация и определение размера позиций при торговле по полосам Боллинджера Метаразметка классических стратегий (Часть 3): Фильтрация и определение размера позиций при торговле по полосам Боллинджера
Эффективность стратегии возврата к среднему на основе полос Боллинджера снижается в трендовых рыночных режимах, когда ADX высок, а ширина полос увеличивается. Мы отделяем выбор направления сделки от отбора сделок с помощью двухэтапного конвейера метаразметки: вторичный классификатор на основе градиентного бустинга, обученный с использованием PurgedKFold на признаках, характеризующих полосы Боллинджера (BBP, BBB, режим ширины полос), выдает вероятности действий, на основе которых выполняется определение размера позиции. Реализация на MQL5 загружает модель ONNX и определяет размер позиции в рамках архитектуры с двумя торговыми советниками, чтобы отфильтровывать касания полос, дающие сигналы низкого качества.
Особенности написания экспертов Особенности написания экспертов
Написание и тестирование экспертов в торговой системе MetaTrader 4.
Паттерн "Репозиторий" в MQL5: Абстрагирование доступа к торговой истории для обеспечения тестируемости логики советника Паттерн "Репозиторий" в MQL5: Абстрагирование доступа к торговой истории для обеспечения тестируемости логики советника
Прямые вызовы API торговой истории MQL5 внутри аналитических компонентов создают скрытые зависимости от терминала, из-за которых изолированное тестирование невозможно на уровне архитектуры. В данной статье создается слой абстракции ITradeRepository с реализациями CLiveTradeRepository и CMockTradeRepository, позволяющий одному и тому же аналитическому модулю и панели кривой средств одинаково работать как с текущими данными торгового счета, так и с детерминированным набором данных в памяти. Внедрение репозитория устраняет прямую связанность с API, позволяет проводить проверку в автономном режиме и при смене источника данных ограничивает необходимые изменения одним классом реализации.