English
preview
Создание автоматических ежедневных отчетов о торговых операциях с помощью функции SendMail

Создание автоматических ежедневных отчетов о торговых операциях с помощью функции SendMail

MetaTrader 5 — Эксперты |
30 1
ALGOYIN LTD
Israel Pelumi Abioye

Введение

Трейдерам часто бывает сложно отслеживать свои результаты по итогам каждого торгового дня, поскольку ручной анализ сделок в MetaTrader 5 может занимать много времени, а важные детали легко упустить. Однако MetaTrader 5 не предоставляет встроенной системы для автоматического формирования структурированных ежедневных отчетов о торговых операциях и их отправки по электронной почте в отформатированном виде.

В этой статье мы создадим систему, которая автоматизирует формирование ежедневных торговых отчетов непосредственно в MetaTrader 5. Вы узнаете, как получать исторические данные о сделках за указанный период, рассчитывать ключевые показатели эффективности, а также динамически формировать тему и текст письма на основе активности на счете. Наконец, мы автоматизируем этот процесс, настроив отправку отчета один раз в день с помощью функции SendMail(). Так вы получите торговый дневник, который ведется автоматически и регулярно доставляется прямо в ваш почтовый ящик.


Обзор проекта и план реализации

Перед тем как приступить к программированию, крайне важно полностью понять, что мы собираемся сделать и как это будет реализовано на языке MQL5. В этой главе представлен структурированный обзор проекта и описан последовательный процесс, которому мы будем следовать для достижения желаемого результата.

Что мы создаем

В рамках этого проекта мы разработаем советник на языке MQL5, который будет автоматически формировать структурированный ежедневный отчет о торговых операциях на основе истории сделок по счёту и отправлять его напрямую на электронную почту пользователя с помощью функции SendMail(). Система предназначена для использования в качестве личного торгового дневника, работающего без ручного вмешательства. В конце каждого торгового дня советник будет получать данные обо всех закрытых сделках, совершённых в заданном временном интервале, обычно за период предыдущей дневной свечи. На основе этих данных система будет извлекать и систематизировать ключевую торговую информацию, такую как общая прибыль, количество прибыльных и убыточных сделок, а также общее количество сделок.

Советник оформит эту информацию в виде отчета для отправки по электронной почте. Он будет динамически формировать тему письма и текст сообщения с учетом торговой активности за этот день. После подготовки отчета он будет автоматически отправляться один раз в день, что обеспечит постоянный мониторинг эффективности торговли и поможет вам оценивать свои результаты без необходимости вручную просматривать историю терминала.

Рисунок 1. Что мы создаем

План реализации

В этом разделе мы пошагово рассмотрим процесс реализации системы автоматизированной ежедневной торговой отчётности на MQL5.

Настройка параметров SMTP:

Перед отправкой писем через MetaTrader 5 необходимо настроить SMTP. Почтовые серверы и программные приложения могут обмениваться данными через Интернет с использованием протокола SMTP (Simple Mail Transfer Protocol). Эти настройки используются функцией SendMail() языка MQL5 для установления соединения с почтовым сервером и отправки электронного письма указанному получателю.

Рисунок 2. Настройка параметров SMTP

Для установления этого соединения необходимо указать несколько параметров. Сначала укажите SMTP-сервер — это почтовый сервер, отвечающий за отправку сообщения. Кроме того, нам потребуется логин SMTP, которым, как правило, является адрес электронной почты, привязанный к учетной записи, с которой отправляются письма. Для аутентификации соединения также требуется пароль SMTP. Процесс генерации этого пароля будет рассмотрен, когда мы приступим к этапу реализации. В заключение укажите адрес электронной почты отправителя (обычно он совпадает с логином SMTP) и адрес электронной почты получателя. Эти параметры лежат в основе системы доставки электронной почты, и их необходимо правильно настроить, прежде чем система автоматической отчётности сможет работать.

Получение и обработка исторических данных о сделках:

На этом втором этапе мы сосредоточимся на разработке основной логики, которая преобразует необработанные данные торговой истории в значимые показатели эффективности для ежедневного отчета. Первым этапом этого процесса является указание точного временного интервала, соответствующего последнему завершившемуся торговому дню. Это предотвращает пересечение с текущей торговой сессией, гарантируя, что в анализ будут включены только сделки, завершённые в пределах указанного периода.

После определения временного диапазона мы извлечём все записи о сделках, попадающих в него. Из этого полного набора данных мы тщательно отберём только завершённые сделки, исключив открытые позиции, неполные данные и нерелевантные записи. Это позволяет нам работать исключительно с окончательными результатами торговых операций, которые точно отражают эффективность торговли. После отбора подходящих сделок мы обработаем каждую из них, чтобы определить, была ли она прибыльной, и зафиксировать сумму прибыли или убытка. По мере обработки данных мы будем накапливать общую статистику: суммарную прибыль, общее количество совершённых сделок, количество прибыльных и убыточных сделок.

Создание темы письма и текста сообщения:

На этом этапе мы сосредоточимся на подготовке итогового содержимого отчёта, который будет отправлен на электронную почту трейдера. Для этого ранее рассчитанные торговые данные необходимо систематизировать таким образом, чтобы их можно было легко понять с первого взгляда. Чтобы каждое письмо однозначно соотносилось с конкретным торговым днём, мы сначала формируем информативную тему письма, соответствующую отчётному периоду. Это упрощает отслеживание и оценку эффективности в динамике.

Далее мы получаем основные сведения о торговом счёте: имя счёта, номер счёта и валюту. Эти сведения дают представление о контексте и помогают определить источник отчета о торговых операциях, особенно при управлении несколькими счетами. В заключение мы объединяем всю собранную информацию, включая общее количество сделок, суммарную прибыль по прибыльным сделкам, суммарный убыток по убыточным сделкам и общий финансовый результат. В результате формируется полная торговая сводка, готовая к отправке в виде итогового отчёта по электронной почте; сведения о счёте и показатели эффективности представлены в ней в наглядном и удобном для чтения формате.

Отправка отчета по электронной почте один раз в день:

На заключительном этапе мы реализуем логику, которая определяет время отправки торгового отчёта и гарантирует, что он отправляется только один раз в день. Чтобы определить начало нового торгового дня, система непрерывно отслеживает смену дневных свечей. При обнаружении начала нового дня ранее созданная тема и текст сообщения используются для запуска процесса отправки электронного письма.

Чтобы избежать дублирования писем, мы сохраняем временную метку последнего отправленного отчета и сравниваем её с текущим дневным периодом. Если обнаруживается начало нового торгового дня, а отчет за этот период еще не отправлен, электронное письмо отправляется немедленно. После отправки система обновляет соответствующую запись, чтобы предотвратить многократную отправку одного и того же отчета в течение одного дня. Это гарантирует надёжную автоматическую доставку торгового дневника без повторной отправки и ручного вмешательства.

 

Реализация на языке MQL5

Теперь, когда мы определили требования к проекту и план его реализации, можем приступить к непосредственной разработке системы на языке MQL5. В этом разделе мы реализуем каждый этап плана в коде: начнём с настройки параметров электронной почты, затем перейдём к получению и обработке исторических данных о сделках, формированию содержимого письма и автоматизации его ежедневной отправки.

Настройка параметров SMTP

Первым делом необходимо настроить MetaTrader 5 так, чтобы он мог отправлять электронные письма через вашего почтового провайдера. Для этого откройте MetaTrader 5 и нажмите Ctrl + O, чтобы открыть окно настроек платформы. Затем перейдите на вкладку "Почта" (Email). На вкладке "Почта" установите флажок "Разрешить", чтобы включить отправку уведомлений по электронной почте. Это указывает MetaTrader 5, что разрешена отправка уведомлений по электронной почте с использованием настроенного SMTP-сервера.

Далее введите необходимые параметры SMTP. В поле "SMTP-сервер" введите:

smtp.gmail.com:465

Чтобы настроить доставку торговых отчётов, сначала введите свой адрес Gmail в поле "SMTP-логин". Затем в поле "Пароль SMTP" (SMTP password:) введите специальный пароль, созданный для SMTP-аутентификации; подробнее об этом будет рассказано далее. Поскольку адрес электронной почты, используемый в качестве SMTP-логина, определяет отправителя, его также следует указать в поле "От кого" (From:). Затем в поле "Кому" (To:) укажите адрес электронной почты получателя, который в зависимости от ваших настроек может отличаться от адреса отправителя.

Рисунок 3. Настройки SMTP

Кроме того, перед созданием пароля SMTP важно включить двухэтапную аутентификацию в аккаунте Google, поскольку Google требует выполнения этого дополнительного шага безопасности перед выдачей паролей приложений для таких программ, как MetaTrader 5.

Для начала перейдите по адресу:

myaccount.google.com

Затем перейдите в раздел "Безопасность" (Security) и войдите в свою учетную запись Google, если появится соответствующий запрос:

Рисунок 4. Безопасность и вход в систему

Как только загрузится страница "Безопасность", найдите пункт "Двухэтапная аутентификация" (2-Step Verification) и нажмите на него:

Рисунок 5. Двухэтапная аутентификация

Откроется страница настройки двухфакторной аутентификации Google. Затем выберите "Включить двухэтапную аутентификацию" и следуйте инструкциям на экране, чтобы продолжить. В зависимости от настроек вашей учетной записи Google может потребовать подтверждения личности с помощью номера телефона, приложения для аутентификации или других разрешенных способов.

После успешного включения двухэтапной аутентификации перейдите на следующую страницу:

myaccount.google.com/apppasswords

На этой странице можно создать пароли приложений для использования в таких программах, как MetaTrader 5. Как только страница загрузится, введите название приложения, например "MetaTrader 5", и нажмите "Создать" (Create):

Рисунок 6. Пароль SMTP

Затем Google сгенерирует уникальный пароль специально для MetaTrader 5:

Рисунок 7. Пароль

Этот сгенерированный пароль — ваш пароль SMTP. Скопируйте пароль и вернитесь в окно настроек электронной почты MetaTrader 5. Вставьте сгенерированный пароль в поле  "Пароль SMTP", которое мы ранее оставили пустым.

Рисунок 8. Ввод пароля

Чтобы убедиться, что MetaTrader 5 правильно подключён к почтовому серверу, нажмите кнопку "Тест" (Test) в окне настроек электронной почты. Платформа отправит тестовое письмо с использованием ваших настроек SMTP. Если настройки верны, тестовое сообщение будет отправлено на адрес электронной почты получателя, указанный в поле "Кому".

Получение и обработка исторических данных о сделках

Как было указано в плане реализации, на втором этапе проекта мы сосредоточимся на сборе и анализе истории сделок за заданный торговый период. Первое, что нам нужно сделать на этом этапе, — это определить точный временной интервал, который мы хотим проанализировать и который соответствует завершившемуся торговому дню.

Пример:

datetime start_time;          // Start time of the reporting period
datetime end_time;            // End time of the reporting period
bool is_time;                 // Indicates whether the history was selected successfully
ulong ticket;                 // Current deal ticket being processed
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
//--- Get the start and end times of the previous trading day
   start_time = iTime(_Symbol,PERIOD_D1,1);
   end_time = iTime(_Symbol,PERIOD_D1,0);

//--- Select trade history within the specified period
   is_time = HistorySelect(start_time, end_time);

//--- Process historical deals if history selection is successful
   if(is_time)
     {
      //--- Iterate through all deals in the selected history
      for(int i = 0; i < HistoryDealsTotal(); i++)
        {
         // Get the deal ticket
         ticket = HistoryDealGetTicket(i);
        }
     }

  }

Пояснение:

В этой части мы определяем точные временные границы предыдущего торгового дня, чтобы получить историю сделок именно за этот период. Сначала мы получаем время открытия предыдущей дневной свечи — начало периода, который хотим проанализировать. Во второй строке извлекается время открытия текущей дневной свечи, которое используется в качестве конечной границы предыдущего торгового периода. Важно понимать, что в MetaTrader 5 данные временных рядов индексируются начиная с самого последнего бара. Индекс 0 обозначает текущую формирующуюся свечу, индекс 1 — последнюю завершившуюся свечу, индекс 2 — предыдущую и так далее. Благодаря такой структуре индекс 1 позволяет определить точное начало предыдущего завершённого дня, а индекс 0 — начало текущего дня.

Однако, хотя время окончания периода соответствует текущей свече, сама эта свеча ещё не закрыта: текущая дневная свеча продолжает формироваться. Поэтому время открытия текущей свечи используется как конечная граница анализируемого периода, хотя сама свеча ещё формируется. В совокупности эти два значения позволяют нам точно задать временной диапазон для анализа только завершённых торговых операций предыдущего дня. Далее мы используем функцию HistorySelect() для выбора временного диапазона, за который нужно получить историю торговли для анализа. Этот этап гарантирует, что в наш отчёт попадут только сделки, завершённые в течение указанного периода. Задавая время начала и окончания, мы обеспечиваем, чтобы система игнорировала все сделки за пределами этого интервала и отбирала для анализа только относящиеся к нему исторические данные.

Результатом этой операции является подтверждение того, что история сделок за данный период была успешно выбрана и готова к обработке. После выбора истории мы можем перейти к обработке данных в цикле и расчёту показателей эффективности, таких как прибыль, убытки и общее количество сделок. После этого мы проверяем, удалось ли выбрать историю сделок. Это гарантирует, что до начала любой обработки будут доступны достоверные данные за указанный период времени. Если история успешно выбрана, мы переходим к следующему этапу. Затем мы в цикле перебираем все записи о сделках, доступные в выбранной истории. Это позволяет нам проанализировать каждую сделку по отдельности, чтобы в наш анализ были включены все сделки, завершенные в течение данного периода.

Для каждой сделки в цикле мы извлекаем уникальный идентификатор, который обозначает именно эту сделку. Этот идентификатор позволяет нам получать доступ к подробной информации о каждой сделке и работать с ней на последующих этапах обработки. Теперь мы можем получить исторические данные за выбранный период, который соответствует завершившейся торговой сессии.

Примечание: По мере изложения мы будем выделять фрагменты кода, относящиеся к каждому этапу реализации, чтобы каждую часть можно было понять отдельно, не смешивая её с ранее рассмотренными фрагментами.

Пример:

//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
//--- Get the start and end times of the previous trading day
   start_time = iTime(_Symbol,PERIOD_D1,1);
   end_time = iTime(_Symbol,PERIOD_D1,0);

//--- Select trade history within the specified period
   is_time = HistorySelect(start_time, end_time);

//--- Variables for storing trading statistics
   double total_profit = 0;
   double total_wins = 0;
   double total_loss = 0;
   int total_trades = 0;

//--- Process historical deals if history selection is successful
   if(is_time)
     {
      //--- Iterate through all deals in the selected history
      for(int i = 0; i < HistoryDealsTotal(); i++)
        {
         // Get the deal ticket
         ticket = HistoryDealGetTicket(i);

         // Process only closing deals
         if(HistoryDealGetInteger(ticket, DEAL_ENTRY) == DEAL_ENTRY_OUT)
           {
            // Add deal profit to total profit
            total_profit += HistoryDealGetDouble(ticket, DEAL_PROFIT);

            // Increment total trade count
            total_trades++;

            // Add profitable deals to total wins
            if(HistoryDealGetDouble(ticket, DEAL_PROFIT) >= 0)
              {
               total_wins += HistoryDealGetDouble(ticket, DEAL_PROFIT);
              }

            // Add losing deals to total loss
            if(HistoryDealGetDouble(ticket, DEAL_PROFIT) < 0)
              {
               total_loss += HistoryDealGetDouble(ticket, DEAL_PROFIT);
              }
           }
        }
     }

  }
//+------------------------------------------------------------------+

Пояснение:

Сначала мы убеждаемся, что работаем только с завершёнными сделками. Для этого мы проверяем свойство DEAL_ENTRY и отбираем сделки со значением DEAL_ENTRY_OUT — сделки выхода из позиции. Этот шаг важен, поскольку только закрытые сделки содержат окончательные значения прибыли или убытка, которые можно использовать для отчетности. Обнаружив закрывающую сделку, мы приступаем к извлечению и обработке её данных. Далее мы добавляем сумму прибыли или убытка по этой сделке к общей сумме прибыли. Это позволяет получить текущую сводку результатов торговли на счёте по всем закрытым сделкам за выбранный период. При этом мы увеличиваем общее количество сделок на единицу для каждой подходящей закрывающей сделки, что позволяет отслеживать общее число совершённых сделок.

Мы также оцениваем прибыльность сделки. Мы считаем сделку успешной и добавляем её результат к общей сумме прибыли по успешным сделкам, если этот результат больше или равен нулю. Это позволяет нам выделить и оценить положительные показатели отдельно от общей прибыли. Наконец, мы проверяем, привела ли сделка к убытку. Если прибыль по сделке меньше нуля, мы относим её к убыточным сделкам и добавляем её результат к общей сумме убытков. Это позволяет нам чётко выделить отрицательные результаты и проанализировать просадки в течение торгового периода.

Создание темы письма и текста сообщения

На следующем этапе реализации мы готовим окончательное содержание ежедневного торгового отчёта, который будет отправлен по электронной почте.

Пример:
datetime start_time;          // Start time of the reporting period
datetime end_time;            // End time of the reporting period
bool is_time;                 // Indicates whether the history was selected successfully
ulong ticket;                 // Current deal ticket being processed

long account_login;           // Trading account login number
string account_name;          // Trading account holder name
string email_subject;         // Subject line of the email report
string email_body;            // Body content of the email report
string account_currency;      // Account deposit currency
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
//--- Get the start and end times of the previous trading day
   start_time = iTime(_Symbol,PERIOD_D1,1);
   end_time = iTime(_Symbol,PERIOD_D1,0);

//--- Select trade history within the specified period
   is_time = HistorySelect(start_time, end_time);

//--- Variables for storing trading statistics
   double total_profit = 0;
   double total_wins = 0;
   double total_loss = 0;
   int total_trades = 0;

//--- Process historical deals if history selection is successful
   if(is_time)
     {
      //--- Iterate through all deals in the selected history
      for(int i = 0; i < HistoryDealsTotal(); i++)
        {
         // Get the deal ticket
         ticket = HistoryDealGetTicket(i);

         // Process only closing deals
         if(HistoryDealGetInteger(ticket, DEAL_ENTRY) == DEAL_ENTRY_OUT)
           {
            // Add deal profit to total profit
            total_profit += HistoryDealGetDouble(ticket, DEAL_PROFIT);

            // Increment total trade count
            total_trades++;

            // Add profitable deals to total wins
            if(HistoryDealGetDouble(ticket, DEAL_PROFIT) >= 0)
              {
               total_wins += HistoryDealGetDouble(ticket, DEAL_PROFIT);
              }

            // Add losing deals to total loss
            if(HistoryDealGetDouble(ticket, DEAL_PROFIT) < 0)
              {
               total_loss += HistoryDealGetDouble(ticket, DEAL_PROFIT);
              }
           }

        }
     }

//--- Create the email subject containing the report period
   email_subject = "Daily Trading Report | " + TimeToString(start_time) +
                   " - " + TimeToString(end_time);
//--- Retrieve account information
   account_name = AccountInfoString(ACCOUNT_NAME);
   account_login = AccountInfoInteger(ACCOUNT_LOGIN);
   account_currency = AccountInfoString(ACCOUNT_CURRENCY);

//--- Build the email body containing account and trading statistics
   email_body = "Account Name: " + account_name +
                "\nAccount Login: " + IntegerToString(account_login) +
                "\nTotal Trades: " + IntegerToString(total_trades) +
                "\nTotal Wins: " + DoubleToString(total_wins,2) + " " + account_currency +
                "\nTotal Loss: " + DoubleToString(total_loss,2) + " " + account_currency +
                "\nTotal Profit: " + DoubleToString(total_profit,2) + " " + account_currency;

  }
//+------------------------------------------------------------------+

Пояснение:

Daily Trading Report (ежедневный торговый отчёт) — это неизменный текст в начале темы письма, который сразу поясняет его назначение. Затем динамически добавляется временной диапазон отчёта с использованием времени начала и окончания выбранной торговой сессии. Время начала и время окончания преобразуются в удобный для чтения формат даты и времени с помощью функции TimeToString(start_time). Затем эти два значения соединяются дефисом, чтобы наглядно обозначить период, охватываемый отчётом. В результате тема каждого письма становится уникальной и содержит указание на конкретную дату, что позволяет легко определить точный торговый день, к которому относится отчет, при просмотре нескольких писем.

Затем мы получаем имя счёта, которое соответствует зарегистрированному имени владельца торгового счёта. Это помогает определить, кому принадлежит отчет, особенно когда его просматривают за пределами торговой платформы. Далее извлекается номер счёта. Это уникальный числовой идентификатор, присваиваемый брокером каждому торговому счёту. Он используется, чтобы отличать один счёт от другого, особенно при управлении несколькими счетами или их мониторинге.

Также извлекается валюта счёта — базовая валюта, в которой рассчитываются прибыль, убытки и баланс счёта. Включение этой информации гарантирует, что все финансовые показатели в отчете, присланном по электронной почте, будут понятны и правильно интерпретированы. Последний блок отвечает за составление всего текста электронного письма, которое будет отправлено в качестве ежедневного отчета о торговых операциях. Он формирует единое структурированное сообщение, содержащее как данные о счёте, так и показатели эффективности торговли. Сначала текст письма инициализируется строкой, содержащей подпись для имени счёта и само имя счёта. В верхней части сообщения указывается, кому принадлежит отчет. Затем добавляется номер счёта. Поскольку номер счёта является числовым значением, его преобразуют в текстовый формат для корректного включения в строку.

Это гарантирует, что номер счёта будет отображаться правильно в тексте письма. Затем добавляется общее количество сделок, завершённых за выбранный период. Это краткая сводка торговой активности за день. Затем добавляется общая сумма прибыли по прибыльным сделкам. Этот показатель, представленный в виде десятичного числа с двумя знаками после запятой, отражает общую сумму прибыли по всем прибыльным сделкам.

Валюта счета указывается для уточнения суммы прибыли. Затем в том же формате добавляется общая сумма убытков. Это общая сумма убытков по всем убыточным сделкам; для наглядности она представлена с указанием соответствующей валюты и в нужном формате. Наконец, добавляется общая прибыль. Этот показатель отражает чистый финансовый результат за торговый период и также выводится с двумя знаками после запятой и указанием валюты счёта. Для соединения всех этих чисел используются символы переноса строки, благодаря чему каждый элемент данных отображается в отдельной строке. В результате электронное письмо имеет четкий и удобный для чтения формат, который подходит для ежедневной отчетности о результатах торговли.

Отправка отчета по электронной почте один раз в день

Отчет о торговых операциях автоматически отправляется по электронной почте на заключительном этапе внедрения. Вся необходимая информация уже собрана и отформатирована, включая торговую статистику, сведения о счёте и текст электронного письма.

Пример:
datetime last_email_sent;     // Time when the last email report was sent
//--- Create the email subject containing the report period
email_subject = "Daily Trading Report | " + TimeToString(start_time) +
                " - " + TimeToString(end_time);
//--- Retrieve account information
account_name = AccountInfoString(ACCOUNT_NAME);
account_login = AccountInfoInteger(ACCOUNT_LOGIN);
account_currency = AccountInfoString(ACCOUNT_CURRENCY);

//--- Build the email body containing account and trading statistics
email_body = "Account Name: " + account_name +
             "\nAccount Login: " + IntegerToString(account_login) +
             "\nTotal Trades: " + IntegerToString(total_trades) +
             "\nTotal Wins: " + DoubleToString(total_wins,2) + " " + account_currency +
             "\nTotal Loss: " + DoubleToString(total_loss,2) + " " + account_currency +
             "\nTotal Profit: " + DoubleToString(total_profit,2) + " " + account_currency;

//--- Get the current daily bar opening time
datetime current_email_time = iTime(_Symbol,PERIOD_D1,0);

//--- Send the report only once per daily candle
if(current_email_time != last_email_sent)
  {
//--- Send the email report
   SendMail(email_subject,email_body);

//--- Store the daily candle time to prevent duplicate emails
   last_email_sent = current_email_time;
  }

Пояснение:

Логика этого раздела обеспечивает отправку отчета только один раз в торговый день и определяет время его отправки. Сначала система получает время открытия текущей дневной свечи: это значение точно указывает начало текущего торгового дня, поскольку в MetaTrader 5 каждый день начинается новая свеча на таймфрейме D1. Время открытия каждой новой дневной свечи служит уникальной временной меткой. Затем ранее сохраненное время отправки электронного письма сравнивается с этим значением времени. Цель — проверить, было ли уже отправлено письмо для текущей дневной свечи. Если значения различаются, значит, начался новый день и отчет за этот день еще не отправлен.

При выполнении этого условия система отправляет электронное письмо с подготовленными темой и текстом сообщения. Это гарантирует отправку торговых данных сразу после обнаружения начала новой дневной сессии. После отправки электронного письма система сохраняет время открытия текущей дневной свечи как новое значение времени. Это значение служит флагом, предотвращающим повторную отправку того же отчета в течение того же торгового дня. Такая логика предотвращает появление дубликатов писем и гарантирует, что отчет формируется один раз в день, благодаря чему система работает полностью в автоматическом режиме и отличается высокой надежностью.


Заключение

Следуя шагам, описанным в этой статье, мы создали на MQL5 полноценную автоматизированную систему ежедневной торговой отчетности, которая получает историю сделок, обрабатывает данные о результатах торговли и отправляет структурированный отчет по электронной почте с помощью функции SendMail(). Система:

  • извлекает исторические данные о сделках за заданный дневной период;
  • фильтрует и обрабатывает только закрытые сделки для получения точных результатов;
  • рассчитывает общую прибыль, количество прибыльных и убыточных сделок, а также общее количество сделок;
  • извлекает информацию о торговом счёте, такую как имя счёта, номер счёта и валюта;
  • создает структурированную тему письма, содержащую информацию об отчетном периоде;
  • формирует понятный текст письма с торговой статистикой и данными счёта;
  • автоматизирует отправку электронных писем один раз в день, отслеживая появление новой дневной свечи;
  • предотвращает дублирование писем, отслеживая ранее отправленные отчеты.

В результате получается полностью автоматизированный торговый дневник, который работает в фоновом режиме и предоставляет достоверные данные о ежедневных результатах торговли без необходимости ручного вмешательства.

Перевод с английского произведен MetaQuotes Ltd.
Оригинальная статья: https://www.mql5.com/en/articles/23093

Прикрепленные файлы |
MT5_TO_EMAIL.mq5 (4.79 KB)
Последние комментарии | Перейти к обсуждению на форуме трейдеров (1)
Nikita.PMC
Nikita.PMC | 18 нояб. 2026 в 16:42

В такой отчет я бы добавил еще минимум средств за день. Пример: день закрыт в +200, но днем открытая позиция уходила в минус 1 800 по средствам. По закрытым сделкам этого не видно, а для дневного лимита просадки на проп-счете важна как раз эта цифра. Я пишу AccountInfoDouble(ACCOUNT_EQUITY) в OnTick, держу минимум в глобальной переменной терминала и обнуляю его на новой дневной свече. Начало дня тоже лучше брать по времени сервера через iTime(_Symbol, PERIOD_D1, 0), иначе у брокера на GMT+2 отчет съедет на пару часов.

Особенности написания Пользовательских Индикаторов Особенности написания Пользовательских Индикаторов
Написание пользовательских индикаторов в торговой системе MetaTrader 4
Нейросети в трейдинге: AlphaGen — поиск торговых факторов (нейросетевые политики) Нейросети в трейдинге: AlphaGen — поиск торговых факторов (нейросетевые политики)
Продолжаем адаптацию AlphaGen и рассматриваем поисковую и торговую нейросетевые политики, построенные на общем базовом классе. Разбираем выбор токенов с учётом префикса и маски, формирование нормированных параметров торгового действия, архитектуры сетей, распределения, рекуррентную память и обратное распространение градиентов в MQL5 и OpenCL. Прослеживаем путь данных через каждую политику, чтобы определить её назначение и понять, почему вместо одного универсального объекта используются две специализированные сети.
Особенности написания экспертов Особенности написания экспертов
Написание и тестирование экспертов в торговой системе MetaTrader 4.
Полиномиальная регрессия в реальном времени: Реализация каузального фильтра Савицкого — Голея на MQL5 Полиномиальная регрессия в реальном времени: Реализация каузального фильтра Савицкого — Голея на MQL5
Мы адаптируем фильтр Савицкого — Голея для MQL5, придавая ему строго каузальную форму для работы в реальном времени, и выводим фиксированные коэффициенты для вычисления в конечной точке. В статье представлены полноценный индикатор и советник, объясняется чувствительность к шуму при вычислении на краю окна и реализуется защитный механизм подтверждения на нескольких барах. Приведены результаты тестирования на исторических данных по нескольким торговым инструментам без выборочного отбора удачных результатов. Вы получаете готовый к компиляции код, рекомендации по настройке параметров и альтернативу скользящим средним с меньшим запаздыванием.