SignalBaseSelect

Seleciona o sinal na base de sinais de negociação disponíveis no terminal.

bool  SignalBaseSelect(
   int     index     // índice de registro do sinal
   );

Parâmetros

index

[in]  Índice de registro do sinal na base dos sinais de negociação.

valor de retorno

Retorna true se a função for bem-sucedida ou false no caso de erro. Para obter informações sobre o erro, você deve chamar a função GetLastError ().

Exemplo:

void OnStart()
  {
// --- pedimos o número total de sinais na base de dados
   int total=SignalBaseTotal();
// --- ciclo de acordo com todos os sinais
   for(int i=0;i<total;i++)
     {
      //--- selecionamos um sinal para o trabalho futuro
      if(SignalBaseSelect(i))
        {
         //--- obtenção das propriedades do sinal
         long   id    =SignalBaseGetInteger(SIGNAL_BASE_ID);          // id do sinal
         long   pips  =SignalBaseGetInteger(SIGNAL_BASE_PIPS);        // resultado da negociaçáo em pips
         long   subscr=SignalBaseGetInteger(SIGNAL_BASE_SUBSCRIBERS); // número de assinantes
         string name  =SignalBaseGetString(SIGNAL_BASE_NAME);         // nome do sinal
         double price =SignalBaseGetDouble(SIGNAL_BASE_PRICE);        // preço de assinatura do sinal
         string curr  =SignalBaseGetString(SIGNAL_BASE_CURRENCY);     // moeda do sinal
         //--- exibimos todos os sinais rentáveis livres com zero de assinantes
         if(price==0.0 && pips>0 && subscr>0)
            PrintFormat("id=%d, name=\"%s\", currency=%s, pips=%d, subscribers=%d",id,name,curr,pips,subscr);
        }
      else PrintFormat("Erro na seleção do sinal. Código de erro=%d",GetLastError());
     }
  }