SocketRead

ソケットからデータを読みます。

int  SocketRead(
  int           socket,             // ソケット
  uchar&       buffer[],             // ソケットからデータを読むためのバッファ
  uint         buffer_maxlen,       // 読まれるバイト数
  uint         timeout_ms           // 読み込みのタイムアウト
  );

パラメータ

socket

[in] SocketCreate関数で返されるソケットハンドルです。 _LastErrorに無効なハンドルが渡されると、5270 (ERR_NETSOCKET_INVALIDHANDLE)がアクティブになります。

buffer

[out] データが読まれるuchar型配列への参照。動的配列サイズは、読み取られたバイト数だけ増えます。配列サイズはINT_MAX (2147483647)を超えることはできません。

buffer_maxlen

[in] buffer[]配列に読まれるバイト数。配列に収まらないデータはソケットに残り、次のSocketReadの呼び出しで受信できます。buffer_maxlenINT_MAX (2147483647)を超えることはできません。

timeout_ms

[in] ミリ秒単位の読み込みタイムアウトです。この時間内にデータが取得されない場合、試行は中止され、関数は-1を返します。

戻り値

成功の場合、読まれたバイト数。エラーの場合は -1 。

注意事項

関数の実行時にシステムソケットでエラーが発生した場合、SocketConnectによって確立された接続は中断されます。

データ読み込みエラーの場合は、エラー5273 (ERR_NETSOCKET_IO_ERROR)が _LastErrorに書かれます。

この関数は独自のスレッド内で実行されるエキスパートアドバイザーやスクリプトのみから呼び出すことが出来ます。指標から呼び出すと、GetLastError()はエラー4014「Function is not allowed for call(関数呼び出しの許可がありません)」を返します。

例:

//+------------------------------------------------------------------+
//|                                                SocketExample.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright   "Copyright 2018, MetaQuotes Software Corp."
#property link       "https://www.mql5.com"
#property version     "1.00"
#property description "Add Address to the list of allowed ones in the terminal settings to let the example work"
#property script_show_inputs
 
input string Address="www.mql5.com";
input int    Port   =80;
bool         ExtTLS =false;
//+------------------------------------------------------------------+
//| サーバにコマンドを送信                                                  |
//+------------------------------------------------------------------+
bool HTTPSend(int socket,string request)
 {
  char req[];
  int  len=StringToCharArray(request,req)-1;
  if(len<0)
    return(false);
//--- 安全なTLS接続がポート443を使用する場合
  if(ExtTLS)
    return(SocketTlsSend(socket,req,len)==len);
//--- 標準TCP接続が使用されている場合
  return(SocketSend(socket,req,len)==len);
 }
//+------------------------------------------------------------------+
//| サーバ返答を読む                                                     |
//+------------------------------------------------------------------+
bool HTTPRecv(int socket,uint timeout)
 {
  char   rsp[];
  string result;
  uint   timeout_check=GetTickCount()+timeout;
//--- ソケットからデータが存在する間タイムアウトまで読み取る
  do
    {
    uint len=SocketIsReadable(socket);
    if(len)
       {
        int rsp_len;
        //--- 接続が安全かどうかに応じたさまざまな読み取りコマンド
        if(ExtTLS)
           rsp_len=SocketTlsRead(socket,rsp,len);
        else
           rsp_len=SocketRead(socket,rsp,len,timeout);
        //--- 応答を分析する
        if(rsp_len>0)
          {
           result+=CharArrayToString(rsp,0,rsp_len);
          //--- 応答ヘッダーのみを印刷する
          int header_end=StringFind(result,"\r\n\r\n");
          if(header_end>0)
             {
              Print("HTTP answer header received:");
              Print(StringSubstr(result,0,header_end));
              return(true);
             }
          }
       }
    }
  while(GetTickCount()<timeout_check && !IsStopped());
  return(false);
 }
//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数                                              |
//+------------------------------------------------------------------+
void OnStart()
 {
  int socket=SocketCreate();
//--- ハンドルを確認する
  if(socket!=INVALID_HANDLE)
    {
    //--- すべて正常な場合は接続する
    if(SocketConnect(socket,Address,Port,1000))
       {
        Print("Established connection to ",Address,":",Port);
 
        string   subject,issuer,serial,thumbprint;
        datetime expiration;
        //--- 接続が証明書によって保護されている場合は、そのデータを表示する
        if(SocketTlsCertificate(socket,subject,issuer,serial,thumbprint,expiration))
          {
          Print("TLS certificate:");
          Print("   Owner:  ",subject);
          Print("   Issuer:  ",issuer);
          Print("   Number:     ",serial);
          Print("   Print: ",thumbprint);
          Print("   Expiration: ",expiration);
           ExtTLS=true;
          }
        //--- サーバにGET要求を送信する
        if(HTTPSend(socket,"GET / HTTP/1.1\r\nHost: www.mql5.com\r\n\r\n"))
          {
          Print("GET request sent");
          //--- 応答を読む
          if(!HTTPRecv(socket,1000))
              Print("Failed to get a response, error ",GetLastError());
          }
        else
          Print("Failed to send GET request, error ",GetLastError());
       }
    else
       {
        Print("Connection to ",Address,":",Port," failed, error ",GetLastError());
       }
    //--- 使用後にソケットを閉じる
    SocketClose(socket);
    }
  else
    Print("Failed to create a socket, error ",GetLastError());
 }
//+------------------------------------------------------------------+

参照

SocketTimeoutsMathSwap