SocketTlsSend

int  SocketTlsSend(
  int           socket,             // ソケット
  const uchar& buffer[],             // データバッファ
  uint         buffer_len           // バッファサイズ
  );

//+------------------------------------------------------------------+
//|                                                SocketTlsSend.mq5 |
//|                                  Copyright 2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link     "https://www.mql5.com
#property version     "1.00"
#property description "Add Address to the list of allowed ones in the terminal settings to let the example work"
#property script_show_inputs
 
input string Address="www.mql5.com";
input int   Port   =443;
//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数                                              |
//+------------------------------------------------------------------+
void OnStart(void)
 {
  int socket=SocketCreate();
//--- ハンドルを確認する
  if(socket!=INVALID_HANDLE)
    {
    //--- 成功したら接続する
    if(SocketConnect(socket,Address,Port,1000))
       {
        PrintFormat("Established connection to %s:%d",Address,Port);
 
        string   subject,issuer,serial,thumbprint;
        datetime expiration;
        //--- 接続が証明書で保護されている場合は、そのデータを表示する
        if(SocketTlsCertificate(socket,subject,issuer,serial,thumbprint,expiration))
          {
          Print("TLS certificate:");
          Print("   Owner:      ",subject);
          Print("   Issuer:     ",issuer);
          Print("   Number:     ",serial);
          Print("   Print:      ",thumbprint);
          Print("   Expiration: ",expiration);
          }
        //--- サーバにGETリクエストを送信する
        string request="GET / HTTP/1.1\r\nHost: www.mql5.com\r\nUser-Agent: MT5\r\n\r\n";
        char   req[];
        int   len=StringToCharArray(request,req)-1;
 
        if(len<0)
          {
          Print("StringToCharArray() failed. Error ", GetLastError());
          SocketClose(socket);
          return;
          }
        //--- if a secure TLS connection via port 443 is used
        if(SocketTlsSend(socket,req,len)==len)
          {
          Print("GET request sent");
          //--- 応答を読む
          if(!HTTPRecv(socket,1000))
              Print("Failed to get a response, error ",GetLastError());
          }
        else
          Print("Failed to send GET request, error ",GetLastError());
       }
    else
       {
        PrintFormat("Connection to %s:%d failed, error %d",Address,Port,GetLastError());
       }
    //--- 使用後はソケットを閉じる
    SocketClose(socket);
    }
  else
    Print("Failed to create a socket, error ",GetLastError());
 }
//+------------------------------------------------------------------+
//| サーバの応答を読む                                                   |
//+------------------------------------------------------------------+
bool HTTPRecv(int socket,uint timeout_ms)
 {
//--- ソケットからデータを読み出すが、タイムアウトを超えない範囲でデータを読み出す
  char   rsp[];
  string result;
  ulong timeout_check=GetTickCount64()+timeout_ms;
 
  do
    {
    uint len=SocketIsReadable(socket);
 
    if(len)
       {
        //--- read and parse the data of a secure TLS connection
        int rsp_len=SocketTlsRead(socket,rsp,len);
 
        if(rsp_len>0)
          {
          result+=CharArrayToString(rsp,0,rsp_len);
          //--- 応答ヘッダーのみを表示する
          int header_end=StringFind(result,"\r\n\r\n");
 
          if(header_end>0)
             {
              Print("HTTP answer header received:");
              Print(StringSubstr(result,0,header_end));
              return(true);
             }
            //--- 読み取りタイムアウトの有効期限を更新する
          timeout_check=GetTickCount64()+timeout_ms;
          }
       }
    }
  while(GetTickCount64()<timeout_check && !IsStopped());
 
  return(false);
 }