Demo_FileFind - MetaTrader 5のためのスクリプト

このスクリプトは、ファイルとディレクトリの検索と操作のための関数を使用する簡単な例です。

このスクリプトは端末の「Experts」ローカルフォルダに配置されているすべてのファイルとディレクトリの名前を表示します。端末ローカルフォルダはTerminalInfoString()関数の呼び出しによって取得できます。

PrintFormat("The path to the terminal local folder: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));

このスクリプトはディレクトリの検索に有用なFileIsExist() 関数のプロパティを使います。関数のパラメータの現在のディレクトリの名前が指定されている場合は、関数は「false」を戻し_LastError 変数はエラー 5018 - 「This is not a file, this is a directory」（これはファイルではなくディレクトリです）を記載します。

FileFindFirst()、FileFindNext()及びFileFindClose() 関数の説明はヘルプで参照できます。

コード：

void OnStart()
  {
   string file_name;
   int    i=1;
//--- ローカルフォルダのルートで検索ハンドルを受け取る
   long search_handle=FileFindFirst(InpFilter,file_name);
//--- FileFindFirst() の実行が成功したかをチェックする
   if(search_handle!=INVALID_HANDLE)
     {
      //--- 渡された文字列がファイル名かディレクトリ名かをループでチェックする
      do
        {
         ResetLastError();
         //--- ファイルであれば trueを返し、ディレクトリであればエラーを生成する
         FileIsExist(file_name);
         PrintFormat("%d : %s name = %s",i,GetLastError()==5018 ?"Directory" : "File",file_name);
         i++;
        }
      while(FileFindNext(search_handle,file_name));
      //--- 検索ハンドルを閉じる
      FileFindClose(search_handle);
     }
   else
      Print("Files not found!");
  }