Demo_FileDelete - MetaTrader 5のためのスクリプト

このスクリプトは、端末のローカルフォルダ内のすべてのテキストファイルを検索し、その作成日付が「InpFilesDate」入力パラメータ以前であるものを削除します。端末ローカルフォルダはTerminalInfoString()関数の呼び出しによって取得できます。

PrintFormat("The path to the terminal local folder: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));

コード：

//--- スクリプト起動時に入力パラメータウィンドウを表示する
#property script_show_inputs
//--- 古いファイルの日付
input datetime InpFilesDate=D'2010.01.01 00:00';
//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string   file_name;      // ファイル名を格納する変数
   string   filter="*.txt"; // ファイル検索フィルタ
   datetime create_date;    // ファイル作成日
   string   files[];        // ファイル名のリスト
   int      def_size=25;    // デフォルトの配列サイズ
   int      size=0;         // ファイル数
//--- 配列へのメモリ追加
   ArrayResize(files,def_size);
//--- ローカルフォルダのルートで検索ハンドルを受け取る
   long search_handle=FileFindFirst(filter,file_name);
//--- FileFindFirst() の実行が成功したかをチェックする
   if(search_handle!=INVALID_HANDLE)
     {
            //--- ループでファイルを検索する
      do
        {
         files[size]=file_name;
         //---配列サイズを増やす
         size++;
         if(size==def_size)
           {
            def_size+=25;
            ArrayResize(files,def_size);
           }
         //--- エラー値をリセットする
         ResetLastError();
         //--- 作成日を受け取る
         create_date=(datetime)FileGetInteger(file_name,FILE_CREATE_DATE,false);
         //--- ファイルが古いかをチェックする
         if(create_date<InpFilesDate)
           {
            PrintFormat("%s file deleted!",file_name);
            //--- 古いファイルを削除する
            FileDelete(file_name);
           }
        }
      while(FileFindNext(search_handle,file_name));
      //--- 検索ハンドルを閉じる
      FileFindClose(search_handle);
     }
   else
     {
      Print("Files not found!");
      return;
     }
//--- 何のファイルが残っているかをチェックする
   PrintFormat("Results:");
   for(int i=0;i<size;i++)
     {
      if(FileIsExist(files[i]))
         PrintFormat("%s file exists!",files[i]);
      else
         PrintFormat("%s file deleted!",files[i]);
     }
  }