SingleTesterCache - library for MetaTrader 5

This library allows you to read/write tst files - MT5-Tester single pass format.

Some variants of use

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // Tester's single pass data.

void OnStart()
{  
  SINGLETESTERCACHE SingleTesterCache; // Created a tester cache object.
  
  SingleTesterCache.Set(); // Put the real story of the bidding in it.
  
// ..\.\.\MQL5\Files/Test.tst.
  Print(SingleTesterCache.Save("Test.tst")); // Write it to a file that can be imported into the Tester.
}

This script corrals real account trading history into tst format. It is imported into the Tester as follows.

It turns out something like this.

DLL-solutions cannot be placed in KB, so below is the source code of another script, which is not included in KB delivery.

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // Tester's single pass data.

#include <Graphics\Graphic.mqh>
#include <fxsaber\MultiTester\MTTester.mqh> // https://www.mql5.com/en/code/26132

#define  MIN_WIDTH 10

// Creating a graph.
string GraphPlot( const double &Y1[], const double &Y2[],
                  int Width = 0, int Height = 0, const ENUM_CURVE_TYPE Type = CURVE_NONE,
                  const string CurveName1 = NULL, const string CurveName2 = NULL, string ObjName = NULL )
{
  Width = Width ? Width : (int)::ChartGetInteger(0, CHART_WIDTH_IN_PIXELS);
  Height = Height ? Height : (int)::ChartGetInteger(0, CHART_HEIGHT_IN_PIXELS);
  ObjName = (ObjName == NULL) ? __FUNCTION__ : ObjName;

  CGraphic Graphic;

  const bool Res = (::ObjectFind(0, ObjName) >= 0) ? Graphic.Attach(0, ObjName) : Graphic.Create(0, ObjName, 0, 0, 0, Width, Height);

  if (Res)
  {
    const int Size1 = ::ArraySize(Y1);
    const int Size2 = ::ArraySize(Y2);

    Graphic.CurveAdd(Y1, ((Type == CURVE_NONE) && Size1) ? ((Width / Size1 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName1);
    Graphic.CurveAdd(Y2, ((Type == CURVE_NONE) && Size2) ? ((Width / Size2 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName2);

    Graphic.CurvePlotAll();
    Graphic.Update();
  }

  return (Res ? Graphic.ChartObjectName() : NULL);
}

void OnStart()
{  
  uchar Bytes2[];
  
  if (MTTESTER::GetLastTstCache(Bytes2) != -1) // If it was possible to read the last cache record of a single run
  {
    const SINGLETESTERCACHE SingleTesterCache(Bytes2); // Drive it into the corresponding object.

    SingleTesterCache.SaveSet(NULL, true, "Created by " + __FILE__); // Save the set file with details.
    
    double Balance[];
    double Equity[];
  
    // Print the balance and equity chart.
    if (SingleTesterCache.GetBalance(Balance) && SingleTesterCache.GetEquity(Equity))
      GraphPlot(Balance, Equity, 1200, 500, CURVE_NONE, "Balance", "Equity");
      
    Print(SingleTesterCache.Header.ToString());  // Output the header of a single pass.
    Print(SingleTesterCache.Summary.ToString()); // Statistica.
    Print(SingleTesterCache.Inputs);             // Input parameters.
  }
}

This script will automatically pick up the data of the last single pass and output its data, including a balance/equity graph.

Acknowledgements.

Thanks to the developers for creating the Tester caches and helping me to unpack its formats.