SingoloTesterCache - libreria per MetaTrader 5

Questa libreria consente di leggere/scrivere file tst - formato MT5-Tester a passaggio singolo.

Alcune varianti di utilizzo

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // Dati del tester a passaggio singolo.

void OnStart()
{  
  SINGLETESTERCACHE SingleTesterCache; // Creato un oggetto tester cache.
  
  SingleTesterCache.Set(); // Inserite la vera storia dell'offerta.
  
// ..\.\.\MQL5\Files/Test.tst.
  Print(SingleTesterCache.Save("Test.tst")); // Scrivere in un file che può essere importato nel Tester.
}

Questo script raccoglie la cronologia di trading dei conti reali in formato tst. Viene importato nel Tester come segue.

Il risultato è simile a questo.

Le soluzioni DLL non possono essere inserite nella KB, quindi di seguito è riportato il codice sorgente di un altro script, che non è incluso nella consegna della KB.

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // Dati del tester a passaggio singolo.

#include <Graphics\Graphic.mqh>
#include <fxsaber\MultiTester\MTTester.mqh> // https://www.mql5.com/it/code/26132

#define  MIN_WIDTH 10

// Creare un grafico.
string GraphPlot( const double &Y1[], const double &Y2[],
                  int Width = 0, int Height = 0, const ENUM_CURVE_TYPE Type = CURVE_NONE,
                  const string CurveName1 = NULL, const string CurveName2 = NULL, string ObjName = NULL )
{
  Width = Width ? Width : (int)::ChartGetInteger(0, CHART_WIDTH_IN_PIXELS);
  Height = Height ? Height : (int)::ChartGetInteger(0, CHART_HEIGHT_IN_PIXELS);
  ObjName = (ObjName == NULL) ? __FUNCTION__ : ObjName;

  CGraphic Graphic;

  const bool Res = (::ObjectFind(0, ObjName) >= 0) ? Graphic.Attach(0, ObjName) : Graphic.Create(0, ObjName, 0, 0, 0, Width, Height);

  if (Res)
  {
    const int Size1 = ::ArraySize(Y1);
    const int Size2 = ::ArraySize(Y2);

    Graphic.CurveAdd(Y1, ((Type == CURVE_NONE) && Size1) ? ((Width / Size1 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName1);
    Graphic.CurveAdd(Y2, ((Type == CURVE_NONE) && Size2) ? ((Width / Size2 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName2);

    Graphic.CurvePlotAll();
    Graphic.Update();
  }

  return (Res ? Graphic.ChartObjectName() : NULL);
}

void OnStart()
{  
  uchar Bytes2[];
  
  if (MTTESTER::GetLastTstCache(Bytes2) != -1) // Se fosse possibile leggere l'ultimo record della cache di una singola esecuzione
  {
    const SINGLETESTERCACHE SingleTesterCache(Bytes2); // Inserirlo nell'oggetto corrispondente.

    SingleTesterCache.SaveSet(NULL, true, "Created by " + __FILE__); // Salvare il file impostato con i dettagli.
    
    double Balance[];
    double Equity[];
  
    // Stampare il grafico del saldo e del patrimonio netto.
    if (SingleTesterCache.GetBalance(Balance) && SingleTesterCache.GetEquity(Equity))
      GraphPlot(Balance, Equity, 1200, 500, CURVE_NONE, "Balance", "Equity");
      
    Print(SingleTesterCache.Header.ToString());  // Emette l'intestazione di un singolo passaggio.
    Print(SingleTesterCache.Summary.ToString()); // Statistica.
    Print(SingleTesterCache.Inputs);             // Parametri di ingresso.
  }
}

Questo script preleverà automaticamente i dati dell'ultimo singolo passaggio e ne fornirà i dati, compreso un grafico di equilibrio/patrimonio.

Ringraziamenti.

Grazie agli sviluppatori per aver creato le cache di Tester e per avermi aiutato a decomprimere i suoi formati.