싱글 테스터 캐시 - MetaTrader 5용 라이브러리

이 라이브러리를 사용하면 MT5-Tester 단일 패스 형식인 tst 파일을 읽고 쓸 수 있습니다.

다양한 사용 방법

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // 테스터의 단일 패스 데이터.

void OnStart()
{  
  SINGLETESTERCACHE SingleTesterCache; // 테스터 캐시 개체를 생성했습니다.
  
  SingleTesterCache.Set(); // 입찰의 실제 스토리를 넣으세요.
  
// ..\.\.\MQL5\Files/Test.tst.
  Print(SingleTesterCache.Save("Test.tst")); // 테스터로 가져올 수 있는 파일에 작성합니다.
}

이 스크립트는 실제 계정 거래 내역을 tst 형식으로 수집합니다. 이 스크립트는 다음과 같이 테스터로 가져옵니다.

다음과 같은 결과가 나옵니다.

DLL 솔루션은 KB에 넣을 수 없으므로 아래는 KB 제공에 포함되지 않은 다른 스크립트의 소스 코드입니다.

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // 테스터의 단일 패스 데이터.

#include <Graphics\Graphic.mqh>
#include <fxsaber\MultiTester\MTTester.mqh> // https://www.mql5.com/ko/code/26132

#define  MIN_WIDTH 10

// 그래프 만들기.
string GraphPlot( const double &Y1[], const double &Y2[],
                  int Width = 0, int Height = 0, const ENUM_CURVE_TYPE Type = CURVE_NONE,
                  const string CurveName1 = NULL, const string CurveName2 = NULL, string ObjName = NULL )
{
  Width = Width ? Width : (int)::ChartGetInteger(0, CHART_WIDTH_IN_PIXELS);
  Height = Height ? Height : (int)::ChartGetInteger(0, CHART_HEIGHT_IN_PIXELS);
  ObjName = (ObjName == NULL) ? __FUNCTION__ : ObjName;

  CGraphic Graphic;

  const bool Res = (::ObjectFind(0, ObjName) >= 0) ? Graphic.Attach(0, ObjName) : Graphic.Create(0, ObjName, 0, 0, 0, Width, Height);

  if (Res)
  {
    const int Size1 = ::ArraySize(Y1);
    const int Size2 = ::ArraySize(Y2);

    Graphic.CurveAdd(Y1, ((Type == CURVE_NONE) && Size1) ? ((Width / Size1 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName1);
    Graphic.CurveAdd(Y2, ((Type == CURVE_NONE) && Size2) ? ((Width / Size2 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName2);

    Graphic.CurvePlotAll();
    Graphic.Update();
  }

  return (Res ? Graphic.ChartObjectName() : NULL);
}

void OnStart()
{  
  uchar Bytes2[];
  
  if (MTTESTER::GetLastTstCache(Bytes2) != -1) // 단일 실행의 마지막 캐시 레코드를 읽을 수 있는 경우
  {
    const SINGLETESTERCACHE SingleTesterCache(Bytes2); // 해당 객체에 드라이브합니다.

    SingleTesterCache.SaveSet(NULL, true, "Created by " + __FILE__); // 설정된 파일을 세부 정보와 함께 저장합니다.
    
    double Balance[];
    double Equity[];
  
    // 잔액 및 주식 차트를 인쇄합니다.
    if (SingleTesterCache.GetBalance(Balance) && SingleTesterCache.GetEquity(Equity))
      GraphPlot(Balance, Equity, 1200, 500, CURVE_NONE, "Balance", "Equity");
      
    Print(SingleTesterCache.Header.ToString());  // 단일 패스의 헤더를 출력합니다.
    Print(SingleTesterCache.Summary.ToString()); // Statistica.
    Print(SingleTesterCache.Inputs);             // 매개변수 입력.
  }
}

이 스크립트는 마지막 단일 패스의 데이터를 자동으로 가져와 잔액/자산 그래프를 포함한 데이터를 출력합니다.

감사의 글

테스터 캐시를 만들고 포맷을 풀 수 있도록 도와준 개발자에게 감사드립니다.