单测试器缓存 - MetaTrader 5程序库

该库允许您读/写 tst 文件 - MT5-Tester 单程格式。

使用的一些变体

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // 测试人员的单程数据。

void OnStart()
{  
  SINGLETESTERCACHE SingleTesterCache; // 创建一个测试器缓存对象。
  
  SingleTesterCache.Set(); // 把竞标的真实情况写进去。
  
// .\.\.MQL5\Files/Test.tst.
  Print(SingleTesterCache.Save("Test.tst")); // 将其写入可导入测试器的文件。
}

该脚本将真实账户的交易历史记录整理成 tst 格式。导入测试器的方式如下。

结果是这样的

DLL 解决方案不能放在 KB 中，因此下面是另一个脚本的源代码，它不包含在 KB 中。

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // 测试人员的单程数据。

#include <Graphics\Graphic.mqh>
#include <fxsaber\MultiTester\MTTester.mqh> //https://www.mql5.com/zh/code/26132

#define  MIN_WIDTH 10

// 创建图形。
string GraphPlot( const double &Y1[], const double &Y2[],
                  int Width = 0, int Height = 0, const ENUM_CURVE_TYPE Type = CURVE_NONE,
                  const string CurveName1 = NULL, const string CurveName2 = NULL, string ObjName = NULL )
{
  Width = Width ? Width : (int)::ChartGetInteger(0, CHART_WIDTH_IN_PIXELS);
  Height = Height ? Height : (int)::ChartGetInteger(0, CHART_HEIGHT_IN_PIXELS);
  ObjName = (ObjName == NULL) ? __FUNCTION__ : ObjName;

  CGraphic Graphic;

  const bool Res = (::ObjectFind(0, ObjName) >= 0) ? Graphic.Attach(0, ObjName) : Graphic.Create(0, ObjName, 0, 0, 0, Width, Height);

  if (Res)
  {
    const int Size1 = ::ArraySize(Y1);
    const int Size2 = ::ArraySize(Y2);

    Graphic.CurveAdd(Y1, ((Type == CURVE_NONE) && Size1) ? ((Width / Size1 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName1);
    Graphic.CurveAdd(Y2, ((Type == CURVE_NONE) && Size2) ? ((Width / Size2 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName2);

    Graphic.CurvePlotAll();
    Graphic.Update();
  }

  return (Res ? Graphic.ChartObjectName() : NULL);
}

void OnStart()
{  
  uchar Bytes2[];
  
  if (MTTESTER::GetLastTstCache(Bytes2) != -1) // 如果可以读取单次运行的最后一条缓存记录
  {
    const SINGLETESTERCACHE SingleTesterCache(Bytes2); // 将其驱动到相应的对象中。

    SingleTesterCache.SaveSet(NULL, true, "Created by " + __FILE__); // 保存包含详细信息的设置文件。
    
    double Balance[];
    double Equity[];
  
    // 打印余额和权益图表。
    if (SingleTesterCache.GetBalance(Balance) && SingleTesterCache.GetEquity(Equity))
      GraphPlot(Balance, Equity, 1200, 500, CURVE_NONE, "Balance", "Equity");
      
    Print(SingleTesterCache.Header.ToString());  // 输出单次传递的页眉。
    Print(SingleTesterCache.Summary.ToString()); // Statistica.
    Print(SingleTesterCache.Inputs);             // 输入参数。
  }
}

该脚本将自动获取最后一次单程的数据并输出其数据，包括平衡/权益图。

鸣谢。

感谢开发人员创建 Tester 缓存并帮助我解压其格式。