シングルテスター・キャッシュ - MetaTrader 5のためのライブラリ

このライブラリを使用すると、tstファイル（MT5-Testerシングルパス・フォーマット）を読み書きできます。

いくつかの使用方法

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // テスターのシングルパスデータ。

void OnStart()
{  
  SINGLETESTERCACHE SingleTesterCache; // テスターキャッシュオブジェクトを作成しました。
  
  SingleTesterCache.Set(); // 入札の本当のストーリーを入れよう。
  
// .. \MQL5Files/Test.tst.
  Print(SingleTesterCache.Save("Test.tst")); // テスターにインポートできるファイルに書き込む。
}

このスクリプトは、リアル口座の取引履歴をtst形式に整理します。このスクリプトは以下のようにTesterにインポートされる。

このようになる。

DLL-ソリューションはKBに入れることができないので、以下はKB配信には含まれない別のスクリプトのソースコードです。

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // テスターのシングルパスデータ。

#include <Graphics\Graphic.mqh>
#include <fxsaber\MultiTester\MTTester.mqh> //https://www.mql5.com/ja/code/26132

#define  MIN_WIDTH 10

// グラフを作成する。
string GraphPlot( const double &Y1[], const double &Y2[],
                  int Width = 0, int Height = 0, const ENUM_CURVE_TYPE Type = CURVE_NONE,
                  const string CurveName1 = NULL, const string CurveName2 = NULL, string ObjName = NULL )
{
  Width = Width ? Width : (int)::ChartGetInteger(0, CHART_WIDTH_IN_PIXELS);
  Height = Height ? Height : (int)::ChartGetInteger(0, CHART_HEIGHT_IN_PIXELS);
  ObjName = (ObjName == NULL) ? __FUNCTION__ : ObjName;

  CGraphic Graphic;

  const bool Res = (::ObjectFind(0, ObjName) >= 0) ? Graphic.Attach(0, ObjName) : Graphic.Create(0, ObjName, 0, 0, 0, Width, Height);

  if (Res)
  {
    const int Size1 = ::ArraySize(Y1);
    const int Size2 = ::ArraySize(Y2);

    Graphic.CurveAdd(Y1, ((Type == CURVE_NONE) && Size1) ? ((Width / Size1 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName1);
    Graphic.CurveAdd(Y2, ((Type == CURVE_NONE) && Size2) ? ((Width / Size2 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName2);

    Graphic.CurvePlotAll();
    Graphic.Update();
  }

  return (Res ? Graphic.ChartObjectName() : NULL);
}

void OnStart()
{  
  uchar Bytes2[];
  
  if (MTTESTER::GetLastTstCache(Bytes2) != -1) // 1回の実行の最後のキャッシュ・レコードを読むことができる場合
  {
    const SINGLETESTERCACHE SingleTesterCache(Bytes2); // それを対応するオブジェクトに打ち込む。

    SingleTesterCache.SaveSet(NULL, true, "Created by " + __FILE__); // セットファイルを詳細とともに保存する。
    
    double Balance[];
    double Equity[];
  
    // バランス・チャートとエクイティ・チャートを印刷する。
    if (SingleTesterCache.GetBalance(Balance) && SingleTesterCache.GetEquity(Equity))
      GraphPlot(Balance, Equity, 1200, 500, CURVE_NONE, "Balance", "Equity");
      
    Print(SingleTesterCache.Header.ToString());  // シングルパスのヘッダーを出力する。
    Print(SingleTesterCache.Summary.ToString()); // Statistica.
    Print(SingleTesterCache.Inputs);             // 入力パラメータ。
  }
}

このスクリプトは、最後のシングルパスのデータを自動的にピックアップし、バランス/エクイティグラフを含むそのデータを出力します。

謝辞

テスター・キャッシュを作成し、そのフォーマットの解凍を手伝ってくれた開発者に感謝する。