MQL5 ReferansıStandart KütüphaneMathematicsBulanık mantıkÜyelik fonksiyonlarıCS_ShapedMembershipFunction

CS_ShapedMembershipFunction

A ve B parametrelerine sahip S-şekilli üyelik fonksiyonlarıyla çalışmak için tasarlanmıştır.

Açıklama

Fonksiyon, S-şekilli iki parametreli bir üyelik fonksiyonunu ayarlar. Bu, 0 – 1 aralığında değerler alan ve azalmayan bir üyelik fonksiyonudur. Fonksiyonun parametreleri bir aralığı tanımlar. Bu aralıkta fonksiyon doğrusal olmayan şekilde 0'dan 1'e doğru artar.

Fonksiyon, çok düşük tipli bulanık kümeleri temsil eder (başka bir deyişle, azalmayan ve saturasyonlu üyelik fonksiyonlarını ayarlar).

fuzzy_s_function

Çizelge çizmek için oluşturulmuş bir örnek kod aşağıda verilmiştir.

Bildirim

class CS_ShapedMembershipFuncion : public IMembershipFunction

Başlık

#include <Math\Fuzzy\membershipfunction.mqh>

Kalıtım hiyerarşisi

CObject

IMembershipFunction

CS_ShapedMembershipFunction

Sınıf yöntemleri

Sınıf yöntemi	Açıklama
A	Artış aralığının başlangıç değerini gösteren parametreyi alır/ayarlar.
B	Bulanık küme çekirdeğinin ilk parametresini alır/ayarlar.
GetValue	Üyelik fonksiyonunun değerini belli bir argümana göre hesaplar.

Sınıftan türetilen yöntemler CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Örnek

//+------------------------------------------------------------------+
//|                                   S_ShapedMembershipFunction.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Üyelik fonksiyonlarını oluştur
CS_ShapedMembershipFunction func1(2,1);
CS_ShapedMembershipFunction func2(2,4);
CS_ShapedMembershipFunction func3(2,7);
//--- üyelik fonksiyonları için örtüler oluştur
double S_ShapedMembershipFunction1(double x) { return(func1.GetValue(x)); }
double S_ShapedMembershipFunction2(double x) { return(func2.GetValue(x)); }
double S_ShapedMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- grafiği oluştur
   CGraphic graphic;
   if(!graphic.Create(0,"S_ShapedMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"S_ShapedMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("S_ShapedMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- eğri oluştur
   graphic.CurveAdd(S_ShapedMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[2, 1]");
   graphic.CurveAdd(S_ShapedMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[2, 4]");
   graphic.CurveAdd(S_ShapedMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[2, 7]");
//--- X-ekseninin özelliklerini ayarla
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- Y-ekseninin özelliklerini ayarla
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- çiz
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue