MQL5 ReferansıStandart KütüphaneMathematicsBulanık mantıkÜyelik fonksiyonlarıCNormalCombinationMembershipFunction

CNormalCombinationMembershipFunction

B1, B2, Sigma1 ve Sigma2 parametrelerine sahip çift taraflı Gaussyen üyelik fonksiyonlarıyla çalışmak için tasarlanmıştır

Açıklama

Çift taraflı Gaussyen üyelik fonksiyonu Gaussyen (normal) dağılım ile şekillendirilir Asimetrik üyelik fonksiyonlarının kullanılabilmesini sağlar. Fonksiyon düzgündür ve tüm tanım aralığı boyunca sıfırdan farklı değerler alır.

fuzzy_normcomb_function

Çizelge çizmek için oluşturulmuş bir örnek kod aşağıda verilmiştir.

Bildirim

class CNormalCombinationMembershipFuncion : public IMembershipFunction

Başlık

#include <Math\Fuzzy\membershipfunction.mqh>

Kalıtım hiyerarşisi

CObject

IMembershipFunction

CNormalCombinationMembershipFunction

Sınıf yöntemleri

Sınıf yöntemi	Açıklama
B1	İlk üyelik fonksiyonu merkezinin değerini alır/ayarlar.
B2	İkinci üyelik fonksiyonu merkezinin değerini alır/ayarlar.
Sigma1	Üyelik fonksiyonunun ilk eğrilik parametresini alır/ayarlar.
Sigma2	Üyelik fonksiyonunun ikinci eğrilik parametresini alır/ayarlar.
GetValue	Üyelik fonksiyonunun değerini belli bir argümana göre hesaplar.

Sınıftan türetilen yöntemler CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Örnek

//+------------------------------------------------------------------+
//|                          NormalCombinationMembershipFunction.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Üyelik fonksiyonlarını oluştur
CNormalCombinationMembershipFunction func1(1,2,3,1);
CNormalCombinationMembershipFunction func2(4,2,5,1);
CNormalCombinationMembershipFunction func3(6,2,6,1);
//--- üyelik fonksiyonları için örtüler oluştur
double NormalCombinationMembershipFunction1(double x) { return(func1.GetValue(x)); }
double NormalCombinationMembershipFunction2(double x) { return(func2.GetValue(x)); }
double NormalCombinationMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- grafiği oluştur
   CGraphic graphic;
   if(!graphic.Create(0,"NormalCombinationMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"NormalCombinationMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("NormalCombinationMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- eğri oluştur
   graphic.CurveAdd(NormalCombinationMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[1, 2, 3, 1]");
   graphic.CurveAdd(NormalCombinationMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[4, 2, 5, 1]");
   graphic.CurveAdd(NormalCombinationMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[6, 2, 6, 1]");
//--- X-ekseninin özelliklerini ayarla
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- Y-ekseninin özelliklerini ayarla
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- çiz
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue