MQL5参考标准程序库数学模糊逻辑Membership functionsCNormalCombinationMembershipFunction

CNormalCombinationMembershipFunction

通过B1，B2，Sigma1和Sigma2参数实施双边高斯归属函数的类。

描述

双边高斯归属函数通过高斯分布来形成。它允许设置不对称的归属函数。该函数是平滑型，根据整个定义区域行使非零值。

fuzzy_normcomb_function

绘制图表的示例代码显示如下。

声明

class CNormalCombinationMembershipFuncion : public IMembershipFunction

主题

#include <Math\Fuzzy\membershipfunction.mqh>

继承体系

CObject

IMembershipFunction

CNormalCombinationMembershipFunction

类方法

类方法	描述
B1	获取和设置第一归属函数的中心值。
B2	获取和设置第二归属函数的中心值。
Sigma1	获取和设置归属函数曲率的第一个参数。
Sigma2	获取和设置归属函数曲率的第二个参数。
GetValue	通过指定自变数计算归属函数值。

方法继承自类 CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

示例

//+------------------------------------------------------------------+
//|                          NormalCombinationMembershipFunction.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- 创建归属函数
CNormalCombinationMembershipFunction func1(1,2,3,1);
CNormalCombinationMembershipFunction func2(4,2,5,1);
CNormalCombinationMembershipFunction func3(6,2,6,1);
//--- 创建归属函数包装程序
double NormalCombinationMembershipFunction1(double x) { return(func1.GetValue(x)); }
double NormalCombinationMembershipFunction2(double x) { return(func2.GetValue(x)); }
double NormalCombinationMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| 脚本程序起始函数                                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 创建图形
   CGraphic graphic;
   if(!graphic.Create(0,"NormalCombinationMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"NormalCombinationMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("NormalCombinationMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- 创建曲线
   graphic.CurveAdd(NormalCombinationMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[1, 2, 3, 1]");
   graphic.CurveAdd(NormalCombinationMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[4, 2, 5, 1]");
   graphic.CurveAdd(NormalCombinationMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[6, 2, 6, 1]");
//--- 设置X轴属性
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- 设置Y轴属性
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- 绘图
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue