Справочник MQL5Стандартная библиотекаМатематикаНечеткая логикаФункции принадлежностиCNormalCombinationMembershipFunction

CNormalCombinationMembershipFunction

Класс для реализации двухсторонней гауссовской функции принадлежности с параметрами B1, B2, Sigma1 и Sigma2.

Описание

Двухсторонняя гауссовская функция принадлежности формируется с использованием распределения Гаусса. Она позволяет задавать асимметричные функции принадлежности. На всей области определения функция является гладкой и принимает ненулевые значения.

fuzzy_normcomb_function

Пример кода для построения этого графика приведен ниже.

Декларация

class CNormalCombinationMembershipFuncion : public IMembershipFunction

Заголовок

#include <Math\Fuzzy\membershipfunction.mqh>

Иерархия наследования

CObject

IMembershipFunction

CNormalCombinationMembershipFunction

Методы класса

Метод класса	Описание
B1	Возвращает и устанавливает значение первого центра функции принадлежности.
B2	Возвращает и устанавливает значение второго центра функции принадлежности.
Sigma1	Возвращает и устанавливает первый параметр кривизны функции принадлежности.
Sigma2	Возвращает и устанавливает второй параметр кривизны функции принадлежности.
GetValue	Рассчитывает значение функции принадлежности по указанному аргументу.

Методы унаследованные от CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Пример

//+------------------------------------------------------------------+
//|                          NormalCombinationMembershipFunction.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Create membership functions
CNormalCombinationMembershipFunction func1(1,2,3,1);
CNormalCombinationMembershipFunction func2(4,2,5,1);
CNormalCombinationMembershipFunction func3(6,2,6,1);
//--- Create wrappers for membership functions
double NormalCombinationMembershipFunction1(double x) { return(func1.GetValue(x)); }
double NormalCombinationMembershipFunction2(double x) { return(func2.GetValue(x)); }
double NormalCombinationMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"NormalCombinationMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"NormalCombinationMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("NormalCombinationMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- create curve
   graphic.CurveAdd(NormalCombinationMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[1, 2, 3, 1]");
   graphic.CurveAdd(NormalCombinationMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[4, 2, 5, 1]");
   graphic.CurveAdd(NormalCombinationMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[6, 2, 6, 1]");
//--- sets the X-axis properties
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- sets the Y-axis properties
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plot
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue