MQL5 RiferimentoLibreria StandardMatematicheLogica fuzzyMembership functionsCNormalCombinationMembershipFunction

CNormalCombinationMembershipFunction

Classe per implementare una funzione di appartenenza gaussiana a due facce con i parametri B1, B2, Sigma1 e Sigma2.

Descrizione

La funzione di appartenenza gaussiana a due facce (lati) è formata utilizzando la distribuzione gaussiana. Essa consente di impostare funzioni di appartenenza asimmetriche. La funzione è smussata ed assume valori diversi da zero lungo tutta l'area di definizione.

fuzzy_normcomb_function

Un codice di esempio per tracciare un grafico viene visualizzato qui di seguito.

Dichiarazione

class CNormalCombinationMembershipFuncion : public IMembershipFunction

Titolo

#include <Math\Fuzzy\membershipfunction.mqh>

Gerarchia di ereditarietà

CObject

IMembershipFunction

CNormalCombinationMembershipFunction

I metodi della classe

I metodi della classe	Descrizione
B1	Ottiene ed imposta il valore del primo centro di funzione di appartenenza.
B2	Ottiene ed imposta il valore del secondo centro di funzione di appartenenza.
Sigma1	Ottiene ed imposta il primo parametro della curvatura della funzione di appartenenza.
Sigma2	Ottiene ed imposta il secondo parametro della curvatura della funzione di appartenenza.
GetValue	Calcola il valore della funzione di appartenenza da un argomento specificato.

Metodi ereditati dalla classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Esempio

//+------------------------------------------------------------------+
//|                          NormalCombinationMembershipFunction.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Crea funzioni di appartenenza
CNormalCombinationMembershipFunction func1(1,2,3,1);
CNormalCombinationMembershipFunction func2(4,2,5,1);
CNormalCombinationMembershipFunction func3(6,2,6,1);
//--- Crea wrapper per funzioni di appartenenza
double NormalCombinationMembershipFunction1(double x) { return(func1.GetValue(x)); }
double NormalCombinationMembershipFunction2(double x) { return(func2.GetValue(x)); }
double NormalCombinationMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Funzione di start del programma Script                           |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- crea grafica
   CGraphic graphic;
   if(!graphic.Create(0,"NormalCombinationMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"NormalCombinationMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("NormalCombinationMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- crea curva
   graphic.CurveAdd(NormalCombinationMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[1, 2, 3, 1]");
   graphic.CurveAdd(NormalCombinationMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[4, 2, 5, 1]");
   graphic.CurveAdd(NormalCombinationMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[6, 2, 6, 1]");
//--- imposta le proprietà dell'asse X
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- imposta le proprietà asse Y
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plotta
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue