DocumentaciónSecciones
Manual de referencia de MQL5Indicadores personalizadosIndicatorSetString 

IndicatorSetString

Establece el valor de la propiedad correspondiente del indicador. La propiedad del indicador tiene que ser del tipo string. Existen 2 variantes de la función.

Llamada con especificación del identificador de la propiedad.

bool  IndicatorSetString(
   int     prop_id,           // identificador
   string  prop_value         // valor que se establece
   );

Llamada con especificación del identificador y modificador de la propiedad.

bool  IndicatorSetString(
   int     prop_id,           // identificador
   int     prop_modifier,     // modificador 
   string  prop_value         // valor que se establece
   )

Parámetros

prop_id

[in]  Identificador de la propiedad del indicador. Su valor puede ser uno de los valores de la enumeración ENUM_CUSTOMIND_PROPERTY_STRING.

prop_modifier

[in]  Modificador de la propiedad especificada. Sólo las propiedades de niveles requieren un modificador.

prop_value

[in]  Valor de la propiedad.

Valor devuelto

En caso de éxito devuelve true, de lo contrario devuelve false.

Nota

Cuando se utiliza la directiva #property la numeración de las propiedades (modificadores) se empieza desde 1 (un uno). Mientras que la función utiliza la numeración desde 0 (cero). Si el número del nivel no se establece de forma correcta, la visualización del indicador puede ser diferente de lo que está previsto.

Por ejemplo, para establecer la descripción del primer nivel horizontal utilice el índice cero:

  • IndicatorSetString(INDICATOR_LEVELTEXT, 0, "First Level") - utilice el índice 0 para establecer la descripción de texto del primer nivel.

Ejemplo: indicador que establece el texto para los niveles horizontales del indicador.

Ejemplo del uso de la función IndicatorSetString()

#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
//--- establecemos la muestra de tres niveles horizontales en la ventana separada del indicador
#property indicator_level1 30
#property indicator_level2 50
#property indicator_level3 70
//--- establecemos el color de niveles horizontales
#property indicator_levelcolor clrRed
//--- establecemos el estilo de niveles horizontales
#property indicator_levelstyle STYLE_SOLID
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- establecemos las descripciones de niveles horizontales
   IndicatorSetString(INDICATOR_LEVELTEXT,0,"First Level (index 0)");
   IndicatorSetString(INDICATOR_LEVELTEXT,1,"Second Level (index 1)");
   IndicatorSetString(INDICATOR_LEVELTEXT,2,"Third Level (index 2)");
//--- ponemos el nombre breve al indicador
   IndicatorSetString(INDICATOR_SHORTNAME,"IndicatorSetString() Demo");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   
//--- return value of prev_calculated for next call
   return(rates_total);
  }

Véase también

Propiedades de indicadores personalizados, Propiedades de programas (#property)