IndicatorSetString

기능은 해당 지표 속성의 값을 설정. 지표 속성은 문자열 유형이어야 합니다. 기능에는 두 가지 종류가 있습니다.

속성 식별자를 지정하여 호출.

bool  IndicatorSetString(
   int     prop_id,           // 식별자
   string  prop_value         // 설정될 값
   );

속성 식별자 및 수정자를 지정하여 호출.

bool  IndicatorSetString(
   int     prop_id,           // 식별자
   int     prop_modifier,     // 수정자
   string  prop_value         // 설정될 값
   )

매개변수

prop_id

[in] 지표 속성의 식별자. 값은 ENUM_CUSTOMIND_PROPERTY_STRING 열거값 중 하나일 수 있습니다.

prop_modifier

[in] 지정된 속성의 수정자. 레벨 속성만 수정자가 필요합니다.

prop_value

[in] 속성의 값.

반환 값

실행해 성공하면 true를 반환하고, 그렇지 않으면 false를 반환합니다.

참고

속성(수정자) 번호 지정은 #property 지시문을 사용하는 경우 1부터 시작하고 함수는 0부터 번호 지정. 레벨 번호가 잘못 설정된 경우, 지표 표시가 의도한 것과 다를 수 있습니다.

예를 들어, 첫 번째 수평선에 대한 설명을 설정하려면 0 인덱스를 사용합니다:

IndicatorSetString(INDICATOR_LEVELTEXT, 0, "First Level") - 인덱스 0은 첫 번째 레벨의 텍스트 설명을 설정하는 데 사용됩니다.

예: 지표는 텍스트 레이블을 지표 수평선에 설정합니다.

IndicatorSetString() 기능 사용의 예

#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
//--- 별도의 지표 창에 3개의 수평 레벨을 표시
#property indicator_level1 30
#property indicator_level2 50
#property indicator_level3 70
//--- 수평선 색상을 설정
#property indicator_levelcolor clrRed
//--- 수평 레벨의 스타일 설정
#property indicator_levelstyle STYLE_SOLID
//+------------------------------------------------------------------+
//| 사용자 지정 지표 초기화 함수                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- 수평 레벨의 설명 설정
   IndicatorSetString(INDICATOR_LEVELTEXT,0,"First Level (index 0)");
   IndicatorSetString(INDICATOR_LEVELTEXT,1,"Second Level (index 1)");
   IndicatorSetString(INDICATOR_LEVELTEXT,2,"Third Level (index 2)");
//--- 지표를 약칭을 설정
   IndicatorSetString(INDICATOR_SHORTNAME,"IndicatorSetString() Demo");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| 사용자 지정 지표 반복 함수                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---

//--- 다음 호출을 위한 prev_calculated의 반환 값
   return(rates_total);
  }

추가 참조

사용자 지정 지표 속성, 프로그램 속성 (#property)

IndicatorSetInteger

PlotIndexSetDouble