Скачать MetaTrader 5

iFractals

Возвращает хэндл индикатора Fractals.

int  iFractals(
   string           symbol,     // имя символа
   ENUM_TIMEFRAMES  period      // период
   );

Параметры

symbol

[in]  Символьное имя инструмента, на данных которого будет вычисляться индикатор. NULL означает текущий символ.

period

[in]  Значение периода может быть одним из значений перечисления ENUM_TIMEFRAMES, 0 означает текущий таймфрейм.

Возвращаемое значение

Возвращает хэндл указанного технического индикатора, в случае неудачи возвращает INVALID_HANDLE. Для освобождения памяти компьютера от неиспользуемого больше индикатора служит функция IndicatorRelease(), которой передается хэндл этого индикатора.

Примечание

Номера буферов: 0 - UPPER_LINE, 1 - LOWER_LINE.

Пример:

//+------------------------------------------------------------------+
//|                                               Demo_iFractals.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "Индикатор демонстрирует как нужно получать данные"
#property description "индикаторных буферов для технического индикатора iFractals."
#property description "Символ и таймфрейм, на котором рассчитывается индикатор,"
#property description "задаются параметрами symbol и period."
#property description "Способ создания хэндла задается параметром 'type' (тип функции)."
 
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//--- построение FractalUp
#property indicator_label1  "FractalUp"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrBlue
//--- построение FractalDown
#property indicator_label2  "FractalDown"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrRed
//+------------------------------------------------------------------+
//| Перечисление способов создания хэндла                            |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iFractals,         // использовать iFractals
   Call_IndicatorCreate    // использовать IndicatorCreate
  };
//--- входные параметры
input Creation             type=Call_iFractals;          // тип функции 
input string               symbol=" ";                   // символ 
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;        // таймфрейм
//--- индикаторные буферы
double         FractalUpBuffer[];
double         FractalDownBuffer[];
//--- переменная для хранения хэндла индикатора iFractals
int    handle;
//--- переменная для хранения 
string name=symbol;
//--- имя индикатора на графике
string short_name;
//--- будем хранить количество значений в индикаторе Fractals
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- привязка массивов к индикаторным буферам
   SetIndexBuffer(0,FractalUpBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,FractalDownBuffer,INDICATOR_DATA);
//--- зададим коды символом из набора Wingdings для свойств PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,217); // стрелка вверх
   PlotIndexSetInteger(1,PLOT_ARROW,218); // стрелка вниз
//--- определимся с символом, на котором строится индикатор
   name=symbol;
//--- удалим пробелы слева и справа
   StringTrimRight(name);
   StringTrimLeft(name);
//--- если после этого длина строки name нулевая
   if(StringLen(name)==0)
     {
      //--- возьмем символ с графика, на котором запущен индикатор
      name=_Symbol;
     }
//--- создадим хэндл индикатора
   if(type==Call_iFractals)
      handle=iFractals(name,period);
   else
      handle=IndicatorCreate(name,period,IND_FRACTALS);
//--- если не удалось создать хэндл
   if(handle==INVALID_HANDLE)
     {
      //--- сообщим о неудаче и выведем номер ошибки
      PrintFormat("Не удалось создать хэндл индикатора iFractals для пары %s/%s, код ошибки %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- работа индикатора завершается досрочно
      return(INIT_FAILED);
     }
//--- покажем на какой паре символ/таймфрейм рассчитан индикатор Fractals
   short_name=StringFormat("iFractals(%s/%s)",name,EnumToString(period));
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- нормальное выполнение инициализации индикатора 
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- количество копируемых значений из индикатора iFractals
   int values_to_copy;
//--- узнаем количество рассчитанных значений в индикаторе
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() вернул %d, код ошибки %d",calculated,GetLastError());
      return(0);
     }
//--- если это первый запуск вычислений нашего индикатора или изменилось количество значений в индикаторе iFractals
//--- или если необходимо рассчитать индикатор для двух или более баров (значит что-то изменилось в истории)
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- если массив FractalUpBuffer больше, чем значений в индикаторе iFractals на паре symbol/period, то копируем не все 
      //--- в противном случае копировать будем меньше, чем размер индикаторных буферов
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
     }
   else
     {
      //--- значит наш индикатор рассчитывается не в первый раз и с момента последнего вызова OnCalculate())
      //--- для расчета добавилось не более одного бара
      values_to_copy=(rates_total-prev_calculated)+1;
     }
//--- заполняем массивы FractalUpBuffer и FractalDownBuffer значениями из индикатора Fractals
//--- если FillArrayFromBuffer вернула false, значит данные не готовы - завершаем работу
   if(!FillArraysFromBuffers(FractalUpBuffer,FractalDownBuffer,handle,values_to_copy)) return(0);
//--- сформируем сообщение
   string comm=StringFormat("%s ==>  Обновлено значений в индикаторе %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- выведем на график служебное сообщение
   Comment(comm);
//--- запомним количество значений в индикаторе Fractals
   bars_calculated=calculated;
//--- вернем значение prev_calculated для следующего вызова
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Заполняем индикаторные буферы из индикатора iFractals            |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &up_arrows[],        // индикаторный буфер стрелок вверх
                           double &down_arrows[],      // индикаторный буфер стрелок вниз
                           int ind_handle,             // хэндл индикатора iFractals
                           int amount                  // количество копируемых значений
                           )
  {
//--- сбросим код ошибки
   ResetLastError();
//--- заполняем часть массива FractalUpBuffer значениями из индикаторного буфера под индексом 0
   if(CopyBuffer(ind_handle,0,0,amount,up_arrows)<0)
     {
      //--- если копирование не удалось, сообщим код ошибки
      PrintFormat("Не удалось скопировать данные из индикатора iFractals в массив FractalUpBuffer, код ошибки %d",
                  GetLastError());
      //--- завершим с нулевым результатом - это означает, что индикатор будет считаться нерассчитанным
      return(false);
     }
//--- заполняем часть массива FractalDownBuffer значениями из индикаторного буфера под индексом 1
   if(CopyBuffer(ind_handle,1,0,amount,down_arrows)<0)
     {
      //--- если копирование не удалось, сообщим код ошибки
      PrintFormat("Не удалось скопировать данные из индикатора iFractals в массив FractalDownBuffer, код ошибки %d",
                  GetLastError());
      //--- завершим с нулевым результатом - это означает, что индикатор будет считаться нерассчитанным
      return(false);
     }
//--- все получилось
   return(true);
  }
//+------------------------------------------------------------------+
//| Indicator deinitialization function                              |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- почистим график при удалении индикатора
   Comment("");
  }


Обновлено: 2015.12.03