ДокументацияРазделы
Справочник MQL5Глобальные переменные терминалаGlobalVariableSet 

GlobalVariableSet

Устанавливает новое значение глобальной переменной. Если переменная не существует, то система создает новую глобальную переменную.

datetime  GlobalVariableSet(
   string  name,      // имя
   double  value      // устанавлимое значение
   );

Параметры

name

[in]  Имя глобальной переменной.

value

[in]  Новое числовое значение.

Возвращаемое значение

При успешном выполнении функция возвращает время последнего доступа, иначе 0. Чтобы получить информацию об ошибке, необходимо вызвать функцию GetLastError().

Примечание

Имя глобальной переменной не должно превышать 63 символа. Глобальные переменные существуют в клиентском терминале 4 недели с момента последнего обращения, после этого автоматически уничтожаются.

Пример:

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#define   GV_NAME    "TestGlobalVariableSet"
#define   GV_VALUE   1.23456
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- устанавливаем новое значение GV_VALUE в глобальную переменную клиентского терминала с именем GV_NAME
//--- если переменной ещё нет, то она будет создана
   if(GlobalVariableSet(GV_NAME, GV_VALUE)==0)
     {
      Print("GlobalVariableSet() failed. Error ", GetLastError());
      return;
     }
//--- проверим результат и распечатаем его в журнале
   double value=0;
   if(GlobalVariableGet(GV_NAME, value))
     {
      PrintFormat("The global variable of the client terminal named \"%s\" is set to %.5f", GV_NAME, value);
     }
   /*
   результат:
   The global variable of the client terminal named "TestGlobalVariableSet" is set to 1.23456
   */
  }