SocketClose

Fecha o soquete.

bool  SocketClose(
   const int  socket      // identificador do soquete
   );

Parâmetros

socket

[in]  Identificador do soquete que deve ser fechado. O identificador é retornado pela função SocketCreate. Ao passar um identificador inválido para _LastError é registrado o erro 5270 (ERR_NETSOCKET_INVALIDHANDLE).

Valor retornado

Retorna true em caso de sucesso, caso contrário, false.

Observação

Se, para o soquete, anteriormente foi criada uma conexão SocketConnect, ela será interrompida.

A função só pode ser chamada por EAs e scripts, pois eles trabalham em seu próprio fluxo de execução. Quando chamado do indicador GetLastError() retorna o erro 4014 — "Função do sistema não permitida para chamada".

Exemplo:

//+------------------------------------------------------------------+
//|                                                SocketExample.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright   "Copyright 2018, MetaQuotes Software Corp."
#property link        "https://www.mql5.com"
#property version     "1.00"
#property description "Para o exemplo funcionar, adicione Address à lista de permitidos nas configurações do terminal"
#property script_show_inputs
 
input string Address="www.mql5.com";
input int    Port   =80;
bool         ExtTLS =false;
//+------------------------------------------------------------------+
//| Enviando comandos para o servidor                                |
//+------------------------------------------------------------------+
bool HTTPSend(int socket,string request)
  {
   char req[];
   int  len=StringToCharArray(request,req)-1;
   if(len<0)
      return(false);
//--- se for usada uma conexão TLS segura pela porta 443
   if(ExtTLS)
      return(SocketTlsSend(socket,req,len)==len);
//--- se for usada uma conexão TCP normal
   return(SocketSend(socket,req,len)==len);
  }
//+------------------------------------------------------------------+
//| Lendo a resposta do servidor                                     |
//+------------------------------------------------------------------+
bool HTTPRecv(int socket,uint timeout)
  {
   char   rsp[];
   string result;
   uint   timeout_check=GetTickCount()+timeout;
//--- lê dados do soquete enquanto eles existem, mas não mais tempo do que o timeout
   do
     {
      uint len=SocketIsReadable(socket);
      if(len)
        {
         int rsp_len;
         //--- diferentes comandos de leitura dependendo de se a conexão é segura ou não
         if(ExtTLS)
            rsp_len=SocketTlsRead(socket,rsp,len);
         else
            rsp_len=SocketRead(socket,rsp,len,timeout);
         //--- analisa a resposta
         if(rsp_len>0)
           {
            result+=CharArrayToString(rsp,0,rsp_len);
            //--- imprime apenas o cabeçalho da resposta
            int header_end=StringFind(result,"\r\n\r\n");
            if(header_end>0)
              {
               Print("Cabeçalho HTTP de resposta recebido:");
               Print(StringSubstr(result,0,header_end));
               return(true);
              }
           }
        }
     }
   while(GetTickCount()<timeout_check && !IsStopped());
   return(false);
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   int socket=SocketCreate();
//--- verifica o identificador
   if(socket!=INVALID_HANDLE)
     {
      //--- se tudo estiver em ordem, conecte-se
      if(SocketConnect(socket,Address,Port,1000))
        {
         Print("Conectado a ",Address,":",Port);
 
         string   subject,issuer,serial,thumbprint;
         datetime expiration;
         //--- se a conexão estiver protegida por um certificado, exibe seus dados
         if(SocketTlsCertificate(socket,subject,issuer,serial,thumbprint,expiration))
           {
            Print("Certificado TLS:");
            Print("   Proprietário:  ",subject);
            Print("   Emissor:  ",issuer);
            Print("   Número:     ",serial);
            Print("   Impressão digital: ",thumbprint);
            Print("   Expiração: ",expiration);
            ExtTLS=true;
           }
         //--- envia um pedido GET ao servidor
         if(HTTPSend(socket,"GET / HTTP/1.1\r\nHost: www.mql5.com\r\n\r\n"))
           {
            Print("Solicitação GET enviada");
            //--- leia a resposta
            if(!HTTPRecv(socket,1000))
               Print("Falha ao obter resposta, erro ",GetLastError());
           }
         else
            Print("Falha ao enviar solicitação GET, erro ",GetLastError());
        }
      else
        {
         Print("Falhou conexão a ",Address,":",Port,", erro ",GetLastError());
        }
      //--- fecha o soquete após ser usado
      SocketClose(socket);
     }
   else
      Print("Não foi possível criar o soquete, erro ",GetLastError());
  }
//+------------------------------------------------------------------+