MetaTrader 5 herunterladen

iBands

Gibt das Handle des Indikators Bollinger Bands® zurück.

int  iBands(
   string              symbol,            // Symbolname
   ENUM_TIMEFRAMES     period,            // Periode
   int                 bands_period,      // Periode für Berechnung der Mittellinie 
   int                 bands_shift,       // horizontale Verschiebung des Indikators 
   double              deviation,         //Anzahl der Standardabweichungen 
   ENUM_APPLIED_PRICE  applied_price      // Preistyp oder Handle
   );

Parameter

symbol

[in]  Symbolname des Instrumentes, dessen Daten für Berechnung des Indikators verwendet werden. NULL bedeutet das laufende Symbol.

period

[in] Wert der Periode kann einer der Enumerationswerte ENUM_TIMEFRAMES sein, 0 bedeutet das laufende Timeframe.

bands_period

[in]  Mittelungsperiode der Grundlinie des Indikators.

bands_shift

[in]  Verschiebung des Indikators in Bezug auf das Preischart.

deviation

[in] Abweichung von der Grundlinie.

applied_price

[in]  Der verwendete Preis. Kann eine der Preiskonstanten ENUM_APPLIED_PRICE oder Handle eines anderen Indikators sein.

Rückgabewert

Gibt das Handle des angegebenen technischen Indikators zurück, beim Misserfolg gibt INVALID_HANDLE zurück. Um Computerspeicher aus nicht genutzten Indikatoren zu befreien, wird die Funktion IndicatorRelease() verwendet, zu deren Indikatorhandle passiert wird.

Bemerkung

Puffernummern: 0 - BASE_LINE, 1 - UPPER_BAND, 2 - LOWER_BAND

Beispiel:

//+------------------------------------------------------------------+
//|                                                  Demo_iBands.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "Der Indikator zeigt, wie Daten erhalten werden sollen"
#property description "Indikator-Puffer für den technischen Indikator iBands."
#property description "Symbol und Zeitrahmen, in denen der Indikator berechnet wird,"
#property description "sind durch die Parameter symbol und period angegeben."
#property description "Erstellungsweise des Handles ist durch den 'type' Parameter (Typ der Funktion) angegeben."
 
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_plots   3
//--- Upper bauen
#property indicator_label1  "Upper"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrMediumSeaGreen
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- Lower bauen
#property indicator_label2  "Lower"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrMediumSeaGreen
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- Middle bauen
#property indicator_label3  "Middle"
#property indicator_type3   DRAW_LINE
#property indicator_color3  clrMediumSeaGreen
#property indicator_style3  STYLE_SOLID
#property indicator_width3  1
//+------------------------------------------------------------------+
//| Enumeration der Erstellungsweisen des Handles                     |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iBands,            // iBands verwenden
   Call_IndicatorCreate    // IndicatorCreate verwenden
  };
//--- Eingabeparameter
input Creation             type=Call_iBands;          // Funktionstyp
input int                  bands_period=20;           // MA Periode
input int                  bands_shift=0;             // Verschiebung
input double               deviation=2.0;             // Anzahl der Standardabweichungen 
input ENUM_APPLIED_PRICE   applied_price=PRICE_CLOSE// Preistyp
input string               symbol=" ";                // Symbol
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;     // Zeitrahmen
//--- Indicator-Puffer
double         UpperBuffer[];
double         LowerBuffer[];
double         MiddleBuffer[];
//--- Eine Variable um Handle des Indikators iBands zu speichern
int    handle;
//--- Variable für Speicherung
string name=symbol;
//--- Name des Indikators auf dem Chart
string short_name;
//--- die Anzahl der Werte im Indikator Bollinger Bands gespeichert wird
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Bindung von Arrays zu den Indikator-Puffern
   SetIndexBuffer(0,UpperBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,LowerBuffer,INDICATOR_DATA);
   SetIndexBuffer(2,MiddleBuffer,INDICATOR_DATA);
//--- Verschiebung jede Linie definieren
   PlotIndexSetInteger(0,PLOT_SHIFT,bands_shift);
   PlotIndexSetInteger(1,PLOT_SHIFT,bands_shift);      
   PlotIndexSetInteger(2,PLOT_SHIFT,bands_shift);      
//--- das Symbol, auf das der Indikator gebaut wird, definieren
   name=symbol;
//--- Leerzeichen aus dem linken und rechten löschen
   StringTrimRight(name);
   StringTrimLeft(name);
//--- Wenn nach diesem die Länge des String name ist Null
   if(StringLen(name)==0)
     {
      //--- das Symbol aus dem Chart, auf dem der Indikator läuft, nehmen
      name=_Symbol;
    ;}
//--- Erstellen ein Handel des Indikators
   if(type==Call_iBands)
      handle=iBands(name,period,bands_period,bands_shift,deviation,applied_price);
   else
     {
      //--- die Struktur mit Werten von Indikatorparametern ausfüllen
      MqlParam pars[4];
      //--- MA Periode
      pars[0].type=TYPE_INT;
      pars[0].integer_value=bands_period;
      //--- Verschiebung
      pars[1].type=TYPE_INT;
      pars[1].integer_value=bands_shift;
      //--- Anzahl der Standardabweichungen
      pars[2].type=TYPE_DOUBLE;
      pars[2].double_value=deviation;
      //--- Preistyp
      pars[3].type=TYPE_INT;
      pars[3].integer_value=applied_price;
      handle=IndicatorCreate(name,period,IND_BANDS,4,pars);
    ;}
//--- Wenn Handle konnte nicht erstellt werden
   if(handle==INVALID_HANDLE)
     {
      //--- darüber schreiben und Nummer des Fehlers anzeigen
      PrintFormat("Handle des Indikators iBands für das Paar %s/%s konnte nicht erstellt werden. Fehlercode ist %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- Arbeit des Indikators ist früher geendet
      return(INIT_FAILED);
    ;}
//--- Das Paar, Symbol/Zeitrahmen, auf deren Bollinger Bands berechnet war, zeigen
   short_name=StringFormat("iBands(%s/%s, %d,%d,%G,%s)",name,EnumToString(period),
                           bands_period,bands_shift,deviation,EnumToString(applied_price));
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- normale Initialisierung des Indikators  
   return(INIT_SUCCEEDED);
 ;}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- Anzahl der Werte des Indikators iBands zu kopieren
   int values_to_copy;
//--- Anzahl der berechneten Werte im Indikator finden
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() hat %d zurückgegeben, Fehlercode ist %d",calculated,GetLastError());
      return(0);
    ;}
//--- wenn dies der erste Start der Berechnung des Indikators ist oder die Anzahl der Werte im Indikator iBands geändert hat
//--- oder wenn Sie brauchen den Indikator für zwei oder mehr Balken (was bedeutet, dass etwas in der Geschichte verändert hat) zu berechnen
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- wenn die Größe der Indikatorsarrays ist größer als die Anzahl der Werte in iBands auf symbol/period ist, dann kopieren wir nicht alles 
      //--- sonst kopieren wir weniger als Größe der Indikator-Puffer
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
    ;}
   else
     {
      //--- dann ist unser Indikator nicht das erste Mal berechnet, und seit dem letzten Aufruf von OnCalculate())
      //--- nicht mehr als ein Balken für die Berechnung hinzugefügt war
      values_to_copy=(rates_total-prev_calculated)+1;
    ;}
//--- Das Array mit den Werten aus dem Indikator Bollinger Bands ausfüllen
//--- Wenn FillArraysFromBuffer false zurückgegeben hat, dann die Daten nicht bereit sind - das Werk vollenden
   if(!FillArraysFromBuffers(MiddleBuffer,UpperBuffer,LowerBuffer,bands_shift,handle,values_to_copy)) return(0);
//--- Nachricht bilden
   string comm=StringFormat("%s ==> Aktualisierte Werte im Indikator %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- Hilfsnachrichtung auf dem Chart anzeigen
   Comment(comm);
//--- die Anzahl der Werte im Indikator Bollinger Bands speichern
   bars_calculated=calculated;
//--- den Wert prev_calculated für den nächsten Anruf zurückgeben
   return(rates_total);
 ;}
//+------------------------------------------------------------------+
//| Indikator-Puffer aus dem Indikator iBands ausfüllen              |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &base_values[],     // Indikator-Puffer der Mittellinie von Bollinger Bands
                           double &upper_values[],    // Indicator-Puffer der Obergrenze
                           double &lower_values[],    // Indicator-Puffer der Untergrenze
                           int shift,                 // Verschiebung
                           int ind_handle,            // Handle von iBands
                           int amount                 // Anzahl der Werte, die kopiert werden
                           )
  {
//--- Fehlercode rücksetzen
   ResetLastError();
//--- Teil des Arrays MiddleBuffer mit Werten auf Indikator-Puffer mit Index 0 ausfüllen
   if(CopyBuffer(ind_handle,0,-shift,amount,base_values)<0)
     {
      //--- wenn die Kopie fehlschlägt, Fehlercode anzeigen
      PrintFormat("Daten konnte nicht aus dem Indikator iBands kopiert werden, Fehlercode ist %d",GetLastError());
      //--- Beenden mit Null-Ergebnis - dies bedeutet, dass der Indikator nicht berechnet wird
      return(false);
    ;}
 
//--- Teil des Arrays UpperBuffer mit Werten auf Indikator-Puffer mit Index 1 ausfüllen
   if(CopyBuffer(ind_handle,1,-shift,amount,upper_values)<0)
     {
      //--- wenn die Kopie fehlschlägt, Fehlercode anzeigen
      PrintFormat("Daten konnte nicht aus dem Indikator iBands kopiert werden, Fehlercode ist %d",GetLastError());
      //--- Beenden mit Null-Ergebnis - dies bedeutet, dass der Indikator nicht berechnet wird
      return(false);
    ;}
 
//--- Teil des Arrays LowerBuffer mit Werten auf Indikator-Puffer mit Index 2 ausfüllen
   if(CopyBuffer(ind_handle,2,-shift,amount,lower_values)<0)
     {
      //--- wenn die Kopie fehlschlägt, Fehlercode anzeigen
      PrintFormat("Daten konnte nicht aus dem Indikator iBands kopiert werden, Fehlercode ist %d",GetLastError());
      //--- Beenden mit Null-Ergebnis - dies bedeutet, dass der Indikator nicht berechnet wird
      return(false);
    ;}
//--- Alles gelang
   return(true);
 ;}
//+------------------------------------------------------------------+
//| Indicator deinitialization function                              |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- Das Chart nach der Löschung des Indikators leeren
   Comment("");
 ;}