iGator

この関数は Gator (ゲーター)指標のハンドルを返します。 オシレーターは、アリゲーターの青線と赤線の差(上ヒストグラム)と、赤線と緑線の差(下ヒストグラム)を示します。

int  iGator(
  string              symbol,            // 銘柄名
  ENUM_TIMEFRAMES    period,            // 期間
  int                jaw_period,        // 顎の計算期間
  int                jaw_shift,        // 顎の水平シフト
  int                teeth_period,      // 歯の計算期間
  int                teeth_shift,      // 歯の水平シフト
  int                lips_period,      // 口の計算期間
  int                lips_shift,        // 口の水平シフト
  ENUM_MA_METHOD      ma_method,        // 平滑化の種類
  ENUM_APPLIED_PRICE  applied_price      // 価格の種類かハンドル
  );

パラメータ

symbol

[in] データが指標計算に使用される有価証券の銘柄名(NULL は現在のシンボル)

period

[in] 期間の値は ENUM_TIMEFRAMES 列挙の値の 1 つで、0 は現在の時間軸の意味です。

jaw_period

[in]  青線の平均期間(アリゲーターの顎)

jaw_shift

[in] 価格チャートに相対した青線のシフト(指標ヒストグラムの視覚的なズレとは直接関係しません)。

teeth_period

[in]  赤線の平均期間(アリゲーターの歯)

teeth_shift

[in] 価格チャートに相対した赤線のシフト(指標ヒストグラムの視覚的なズレとは直接関係しません)。

lips_period

[in]  緑線の平均期間(アリゲーターの口)

lips_shift

[in] 価格チャートに相対した緑線のシフト(指標ヒストグラムの視覚的なズレとは直接関係しません)。

ma_method

[in]  平滑化の種類ENUM_MA_METHOD のいずれかの値

applied_price

[in]  使用される価格。ENUM_APPLIED_PRICE 価格定数のいずれか、または別の指標ハンドル。

戻り値

指定されたテクニカル指標ハンドル。失敗の場合 INVALID_HANDLEIndicatorRelease() 関数に指標ハンドルを渡すことによって 、コンピュータメモリを利用されていない指標から解放することが出来ます。

注意事項

バッファ番号は 0 - UPPER_HISTOGRAM, 1 - 上ヒストグラムの色バッファ 2 - LOWER_HISTOGRAM, 3 - 下ヒストグラムの色バッファ です。

例:

//+------------------------------------------------------------------+
//|                                                  Demo_iGator.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link     "https://www.mql5.com"
#property version   "1.00"
#property description "The indicator demonstrates how to obtain data"
#property description "of indicator buffers for the iGator technical indicator."
#property description "A symbol and timeframe used for calculation of the indicator,"
#property description "are set by the symbol and period parameters."
#property description "The method of creation of the handle is set through the 'type' parameter (function type)."
#property description "All other parameters are as in a standard Gator Oscillator."
 
#property indicator_separate_window
#property indicator_buffers 4
#property indicator_plots   2
//--- GatorUp の描画
#property indicator_label1 "GatorUp"
#property indicator_type1   DRAW_COLOR_HISTOGRAM
#property indicator_color1  clrGreen, clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1  1
//--- GatorDown の描画
#property indicator_label2 "GatorDown"
#property indicator_type2   DRAW_COLOR_HISTOGRAM
#property indicator_color2  clrGreen, clrRed
#property indicator_style2 STYLE_SOLID
#property indicator_width2  1
//+------------------------------------------------------------------+
//| 作成を処理する方法の列挙                                              |
//+------------------------------------------------------------------+
enum Creation
 {
  Call_iGator,           // iGator を使用する
  Call_IndicatorCreate   // IndicatorCreateを使用する
 };
//--- 入力パラメータ
input Creation             type=Call_iGator;       // 関数の種類
input string               symbol=" ";             // シンボル
input ENUM_TIMEFRAMES     period=PERIOD_CURRENT; // 時間軸
input int                  jaw_period=13;         // 顎線の期間
input int                  jaw_shift=8;           // 顎線のシフト
input int                  teeth_period=8;         // 歯線の期間
input int                  teeth_shift=5;         // 歯線のシフト
input int                  lips_period=5;         // 口線の期間
input int                  lips_shift=3;           // 口線のシフト
input ENUM_MA_METHOD       MA_method=MODE_SMMA;   // アリゲーター線の平均化の方法
input ENUM_APPLIED_PRICE   applied_price=PRICE_MEDIAN;// アリゲーター計算に使用される価格の種類
//--- 指標バッファ
double         GatorUpBuffer[];
double         GatorUpColors[];
double         GatorDownBuffer[];
double         GatorDownColors[];
//--- iGator 指標ハンドルを格納する変数
int    handle;
//--- 格納に使用される変数
string name=symbol;
//--- チャートでの指標名
string short_name;
//--- 上下ヒストグラムのシフト値
int shift;
//--- ゲーターオシレーター指標に値の数を保存
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数                                            |
//+------------------------------------------------------------------+
int OnInit()
 {
//--- 配列の指標バッファへの割り当て
  SetIndexBuffer(0,GatorUpBuffer,INDICATOR_DATA);
  SetIndexBuffer(1,GatorUpColors,INDICATOR_COLOR_INDEX);
  SetIndexBuffer(2,GatorDownBuffer,INDICATOR_DATA);
  SetIndexBuffer(3,GatorDownColors,INDICATOR_COLOR_INDEX);
/*
  パラメータで指定された全てのシフトは、ゲーターオシレーターが描画されているアリゲーター指標を参照します。
  これが、ゲーター指標自体は動数にアリゲーター線を動かし、
  ゲーターオシレーター値の計算に使用される理由です。
*/
//--- 顎線と歯線との差に等しい上下のヒストグラムのシフトを計算してみる
  shift=MathMin(jaw_shift,teeth_shift);
  PlotIndexSetInteger(0,PLOT_SHIFT,shift);
//--- 指標の 2 つのヒストグラムに同じシフトを使用されるのが iGator 指標の実装の仕方
  PlotIndexSetInteger(1,PLOT_SHIFT,shift);
 
//--- 指標が描画するシンボルを決める
  name=symbol;
//--- 左右のスペースを削する
  StringTrimRight(name);
  StringTrimLeft(name);
//---「name」文字列の長さがゼロになった場合
  if(StringLen(name)==0)
    {
    //--- 指標が接続されているチャートのシンボルを取る
     name=_Symbol;
    }
//--- 指標ハンドルを作成する
  if(type==Call_iGator)
     handle=iGator(name,period,jaw_period,jaw_shift,teeth_period,teeth_shift,
                   lips_period,lips_shift,MA_method,applied_price);
  else
    {
    //--- 構造体を指標のパラメータで記入
     MqlParam pars[8];
    //--- アリゲーター線の期間とシフト
     pars[0].type=TYPE_INT;
     pars[0].integer_value=jaw_period;
     pars[1].type=TYPE_INT;
     pars[1].integer_value=jaw_shift;
     pars[2].type=TYPE_INT;
     pars[2].integer_value=teeth_period;
     pars[3].type=TYPE_INT;
     pars[3].integer_value=teeth_shift;
     pars[4].type=TYPE_INT;
     pars[4].integer_value=lips_period;
     pars[5].type=TYPE_INT;
     pars[5].integer_value=lips_shift;
    //--- 平滑化の種類
     pars[6].type=TYPE_INT;
     pars[6].integer_value=MA_method;
    //--- 価格の種類
     pars[7].type=TYPE_INT;
     pars[7].integer_value=applied_price;
    //--- ハンドルを作成
     handle=IndicatorCreate(name,period,IND_GATOR,8,pars);
    }
//--- ハンドルが作成されなかった場合
  if(handle==INVALID_HANDLE)
    {
    //--- 失敗した事実とエラーコードを出力する
    PrintFormat("Failed to create handle of the iGator indicator for the symbol %s/%s, error code %d",
                 name,
                EnumToString(period),
                GetLastError());
    //--- 指標が早期に中止された
    return(INIT_FAILED);
    }
//--- ゲーターオシレーターが計算された銘柄/時間軸を表示
  short_name=StringFormat("iGator(%s/%s, %d, %d ,%d, %d, %d, %d)",name,EnumToString(period),
                          jaw_period,jaw_shift,teeth_period,teeth_shift,lips_period,lips_shift);
  IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- 通常の指標の初期化  
  return(INIT_SUCCEEDED);
 }
//+------------------------------------------------------------------+
//| カスタム指標の反復関数                                                |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
              const int prev_calculated,
              const datetime &time[],
              const double &open[],
              const double &high[],
              const double &low[],
              const double &close[],
              const long &tick_volume[],
              const long &volume[],
              const int &spread[])
 {
//--- iGator 指標から複製された値の数
  int values_to_copy;
//--- 指標で計算された値の数を決める
  int calculated=BarsCalculated(handle);
  if(calculated<=0)
    {
    PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());
    return(0);
    }
//--- これが指標計算の初めであるか iGator 指標の値の数が変更した
//---または、2 つ以上のバーの指標の計算が必要である場合(価格履歴で何かが変更された)
  if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
    {
    //--- もし GatorUpBuffer 配列が銘柄/期間で iGator 指標の値の数より大きい場合、全体のコピーはしない
    //--- 他の場合、指標バッファサイズより少ない量をコピーをする
    if(calculated>rates_total) values_to_copy=rates_total;
    else                       values_to_copy=calculated;
    }
  else
    {
    //--- これは初回の計算ではなく、
    //--- 前回の OnCalculate() から、一以上のバーが加えられてない。
     values_to_copy=(rates_total-prev_calculated)+1;
    }
//--- 配列をゲーターオシレーター指標の値で記入
//--- FillArraysFromBuffer が false を返した場合、情報の準備が終わっていないので操作を終了する
  if(!FillArraysFromBuffers(GatorUpBuffer,GatorUpColors,GatorDownBuffer,GatorDownColors,
     shift,handle,values_to_copy)) return(0);
//--- メッセージを形成する
  string comm=StringFormat("%s ==>  Updated value in the indicator %s: %d",
                          TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                           short_name,
                           values_to_copy);
//--- チャートにサービスメッセージを表示する
  Comment(comm);
//--- ゲーターオシレーター指標の値の数を覚える
  bars_calculated=calculated;
//--- prev_calculated 値を次の関数呼び出しのために返す
  return(rates_total);
 }
//+------------------------------------------------------------------+
//| iGator 指標から指標バッファを記入する                                     |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &ups_buffer[],         // 上ヒストグラムの指標バッファ
                          double &up_color_buffer[],   // 上ヒストグラムの価格インデックスの指標バッファ
                          double &downs_buffer[],       // 下ヒストグラムの指標バッファ
                          double &downs_color_buffer[], // 下ヒストグラムの価格インデックスの指標バッファ
                          int u_shift,                 // 上下ヒストグラムのシフト
                          int ind_handle,               // iGator 指標ハンドル
                          int amount                   // 複製された値の数
                          )
 {
//--- エラーコードをリセットする
  ResetLastError();
//--- インデックス0 を持つ指標バッファの値で GatorUpBuffer 配列の一部を記入する
  if(CopyBuffer(ind_handle,0,-u_shift,amount,ups_buffer)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy data from the iGator indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
 
//--- インデックス 1 を持つ指標バッファの値で GatorUpColors 配列の一部を記入する
  if(CopyBuffer(ind_handle,1,-u_shift,amount,up_color_buffer)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy data from the iGator indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
 
//--- インデックス 2 を持つ指標バッファの値で GatorDownBuffer 配列の一部を記入する GatorDownColors
  if(CopyBuffer(ind_handle,2,-u_shift,amount,downs_buffer)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy data from the iGator indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
 
//--- インデックス3 を持つ指標バッファの値でGatorDownColors 配列の一部を記入する
  if(CopyBuffer(ind_handle,3,-u_shift,amount,downs_color_buffer)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy data from the iGator indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
//--- 全てが成功
  return(true);
 }
//+------------------------------------------------------------------+
//| 指標初期化解除関数                                                  |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
 {
//--- 指標の削除後チャートをクリアする
  Comment("");
 }