iADXWilder

この関数は Average Directional Movement Index by Welles Wilder のハンドルを返します。

int  iADXWilder(
  string          symbol,        // 銘柄名
  ENUM_TIMEFRAMES  period,        // 期間
  int              adx_period      // 平均期間
  );

パラメータ

symbol

[in] データが指標計算に使用される有価証券の銘柄名(NULL は現在のシンボル)

period

[in] 期間の値は ENUM_TIMEFRAMES 列挙の値の 1 つで、0 は現在の時間軸の意味です。

adx_period

[in]  インデックス計算の期間

戻り値

指定されたテクニカル指標ハンドル。失敗の場合 INVALID_HANDLEIndicatorRelease() 関数に指標ハンドルを渡すことによって 、コンピュータメモリを利用されていない指標から解放することが出来ます。

注意事項

バッファ番号は 0 - MAIN_LINE、1 - PLUSDI_LINE、2 - MINUSDI_LINE です。

例:

//+------------------------------------------------------------------+
//|                                                   iADXWilder.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link     "https://www.mql5.com"
#property version   "1.00"
#property description "The indicator demonstrates how to obtain data"
#property description "of indicator buffers for the iADXWilder technical indicator."
#property description "A symbol and timeframe used for calculation of the indicator,"
#property description "are set by the symbol and period parameters."
#property description "The method of creation of the handle is set through the 'type' parameter (function type)."
 
#property indicator_separate_window
#property indicator_buffers 3
#property indicator_plots   3
//--- ADX をプロットする
#property indicator_label1 "ADX"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrLightSeaGreen
#property indicator_style1 STYLE_SOLID
#property indicator_width1  1
//--- DI_plus をプロットする
#property indicator_label2 "DI_plus"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrYellowGreen
#property indicator_style2 STYLE_SOLID
#property indicator_width2  1
//--- DI_minus をプロットする
#property indicator_label3 "DI_minus"
#property indicator_type3   DRAW_LINE
#property indicator_color3  clrWheat
#property indicator_style3 STYLE_SOLID
#property indicator_width3  1
//+------------------------------------------------------------------+
//| 作成を処理する方法の列挙                                              |
//+------------------------------------------------------------------+
enum Creation
 {
  Call_iADXWilder,       // iADXWilder を使用する
  Call_IndicatorCreate   // IndicatorCreateを使用する
 };
//--- 入力パラメータ
input Creation             type=Call_iADXWilder;   // 関数の種類
input int                  adx_period=14;         // 計算期間
input string               symbol=" ";             // シンボル
input ENUM_TIMEFRAMES     period=PERIOD_CURRENT; // 時間軸
//--- 指標バッファ
double         ADXBuffer[];
double         DI_plusBuffer[];
double         DI_minusBuffer[];
//--- iADXWilder 指標ハンドルを格納する変数
int    handle;
//--- 格納に使用される変数
string name=symbol;
//--- チャートでの指標名
string short_name;
//--- Average Directional Movement Index by Welles Wilder 指標に値の数を保存
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数                                            |
//+------------------------------------------------------------------+
int OnInit()
 {
//--- 配列の指標バッファへの割り当て
  SetIndexBuffer(0,ADXBuffer,INDICATOR_DATA);
  SetIndexBuffer(1,DI_plusBuffer,INDICATOR_DATA);
  SetIndexBuffer(2,DI_minusBuffer,INDICATOR_DATA);
//--- 指標が描画するシンボルを決める
  name=symbol;
//--- 左右のスペースを削する
  StringTrimRight(name);
  StringTrimLeft(name);
//---「name」文字列の長さがゼロになった場合
  if(StringLen(name)==0)
    {
    //--- 指標が接続されているチャートのシンボルを取る
     name=_Symbol;
    }
//--- 指標ハンドルを作成する
  if(type==Call_iADXWilder)
     handle=iADXWilder(name,period,adx_period);
  else
    {
    //--- 構造体を指標のパラメータで記入
     MqlParam pars[1];
     pars[0].type=TYPE_INT;
     pars[0].integer_value=adx_period;
     handle=IndicatorCreate(name,period,IND_ADXW,1,pars);
    }
//--- ハンドルが作成されなかった場合
  if(handle==INVALID_HANDLE)
    {
    //--- 失敗した事実とエラーコードを出力する
    PrintFormat("Failed to create handle of the iADXWilder indicator for the symbol %s/%s, error code %d",
                 name,
                EnumToString(period),
                GetLastError());
    //--- 指標が早期に中止された
    return(INIT_FAILED);
    }
//--- Average Directional Movement Index by Welles Wilder 指標が計算された銘柄/時間軸を表示
  short_name=StringFormat("iADXWilder(%s/%s period=%d)",name,EnumToString(period),adx_period);
  IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- 通常の指標の初期化    
  return(INIT_SUCCEEDED);
 }
//+------------------------------------------------------------------+
//| カスタム指標の反復関数                                                |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
              const int prev_calculated,
              const datetime &time[],
              const double &open[],
              const double &high[],
              const double &low[],
              const double &close[],
              const long &tick_volume[],
              const long &volume[],
              const int &spread[])
 {
//--- iADXWilder 指標から複製された値の数
  int values_to_copy;
//--- 指標で計算された値の数を決める
  int calculated=BarsCalculated(handle);
  if(calculated<=0)
    {
    PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());
    return(0);
    }
//--- これが指標計算の初めであるか iADXWilder 指標の値の数が変更した
//---または、2 つ以上のバーの指標の計算が必要である場合(価格履歴で何かが変更された)
  if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
    {
    //--- もし iADXWilder Buffer 配列が銘柄/期間で iADXWilder 指標の値の数より大きい場合、全体のコピーはしない
    //--- 他の場合、指標バッファサイズより少ない量をコピーをする
    if(calculated>rates_total) values_to_copy=rates_total;
    else                       values_to_copy=calculated;
    }
  else
    {
    //--- これは初回の計算ではなく、
    //--- 前回の OnCalculate() から、一以上のバーが加えられてない。
     values_to_copy=(rates_total-prev_calculated)+1;
    }
//--- 配列をAverage Directional Movement Index by Welles Wilder 指標の値で記入<81/80/82% >
//--- FillArraysFromBuffer が false を返した場合、情報の準備が終わっていないので操作を終了する
  if(!FillArraysFromBuffers(ADXBuffer,DI_plusBuffer,DI_minusBuffer,handle,values_to_copy)) return(0);
//--- メッセージを形成する
  string comm=StringFormat("%s ==>  Updated value in the indicator %s: %d",
                          TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                           short_name,
                           values_to_copy);
//--- チャートにサービスメッセージを表示する
  Comment(comm);
//--- Average Directional Movement Index 指標の値の数を覚える<55/66/79% >
  bars_calculated=calculated;
//--- prev_calculated 値を次の関数呼び出しのために返す
  return(rates_total);
 }
//+------------------------------------------------------------------+
//| iADXWilder 指標から指標バッファを記入する                                 |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &adx_values[],     // ADX 指標値の指標バッファ
                          double &DIplus_values[],   // DI+ 指標バッファ
                          double &DIminus_values[], // DI- 指標バッファ
                          int ind_handle,           // iADXWilder 指標ハンドル
                          int amount                 // 複製された値の数
                          )
 {
//--- エラーコードをリセットする
  ResetLastError();
//--- インデックス0 を持つ指標バッファの値で iADXBuffer 配列の一部を記入する
  if(CopyBuffer(ind_handle,0,0,amount,adx_values)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy data from the iADXWilder indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
 
//--- インデックス 1 を持つ指標バッファの値で DI_plusBuffer 配列の一部を記入する
  if(CopyBuffer(ind_handle,1,0,amount,DIplus_values)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy data from the iADXWilder indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
 
//--- インデックス 2 を持つ指標バッファの値で DI_minusBuffer 配列の一部を記入する
  if(CopyBuffer(ind_handle,2,0,amount,DIminus_values)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy data from the iADXWilder indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
//--- 全てが成功
  return(true);
 }
//+------------------------------------------------------------------+
//| 指標初期化解除関数                                                  |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
 {
//--- 指標の削除後チャートをクリアする
  Comment("");
 }