iAC

この関数はクライアント端末のグローバルキャッシュに Accelerator Oscillator ( AC オシレーター)を作成してハンドルを返します。バッファは 1 つです。

int  iAC(
  string          symbol,    // 銘柄名
  ENUM_TIMEFRAMES  period      // 期間
  );

パラメータ

symbol

[in] データが指標計算に使用される有価証券の銘柄名(NULL は現在のシンボル)

period

[in] 期間の値は ENUM_TIMEFRAMES 列挙の値の 1 つで、0 は現在の時間軸の意味です。

戻り値

指定されたテクニカル指標ハンドル。失敗の場合 INVALID_HANDLEIndicatorRelease() 関数に指標ハンドルを渡すことによって 、コンピュータメモリを利用されていない指標から解放することが出来ます。

例:

//+------------------------------------------------------------------+
//|                                                     Demo_iAC.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link     "https://www.mql5.com"
#property version   "1.00"
#property description "The indicator demonstrates how to obtain data"
#property description "of indicator buffers for the iAC technical indicator."
#property description "A symbol and timeframe used for calculation of the indicator,"
#property description "are set by the symbol and period parameters."
#property description "The method of creation of the handle is set through the 'type' parameter (function type)."
 
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   1
//--- iAC のプロット
#property indicator_label1 "iAC"
#property indicator_type1   DRAW_COLOR_HISTOGRAM
#property indicator_color1  clrGreen, clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1  1
//+------------------------------------------------------------------+
//| 作成を処理する方法の列挙                                              |
//+------------------------------------------------------------------+
enum Creation
 {
  Call_iAC,               // iAC を使用する
  Call_IndicatorCreate   // IndicatorCreateを使用する
 };
//--- 入力パラメータ
input Creation             type=Call_iAC;         // 関数の種類
input string               symbol=" ";             // シンボル
input ENUM_TIMEFRAMES     period=PERIOD_CURRENT; // 時間軸
//--- 指標バッファ
double iACBuffer[];
double iACColors[];
//--- iAC 指標ハンドルを格納する変数
int    handle;
//--- 格納に使用される変数
string name=symbol;
//--- チャートでの指標名
string short_name;
//--- ACオシレーター指標に値の数を保存
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数                                            |
//+------------------------------------------------------------------+
int OnInit()
 {
//--- 配列の指標バッファへの割り当て
  SetIndexBuffer(0,iACBuffer,INDICATOR_DATA);
  SetIndexBuffer(1,iACColors,INDICATOR_COLOR_INDEX);
//--- 指標が描画するシンボルを決める
  name=symbol;
//--- 左右のスペースを削する
  StringTrimRight(name);
  StringTrimLeft(name);
//---「name」文字列の長さがゼロになった場合
  if(StringLen(name)==0)
    {
    //--- 指標が接続されているチャートのシンボルを取る
     name=_Symbol;
    }
//--- 指標ハンドルを作成する
  if(type==Call_iAC)
     handle=iAC(name,period);
  else
     handle=IndicatorCreate(name,period,IND_AC);
//--- ハンドルが作成されなかった場合
  if(handle==INVALID_HANDLE)
    {
    //--- 失敗した事実とエラーコードを出力する
    PrintFormat("Failed to create handle of the iAC indicator for the symbol %s/%s, error code %d",
                 name,
                EnumToString(period),
                GetLastError());
    //--- 指標が早期に中止された
    return(INIT_FAILED);
    }
//--- ACオシレーターが計算された銘柄/時間軸を表示
  short_name=StringFormat("iAC(%s/%s)",name,EnumToString(period));
  IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- 通常の指標の初期化
  return(INIT_SUCCEEDED);
 }
//+------------------------------------------------------------------+
//| カスタム指標の反復関数                                                |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
              const int prev_calculated,
              const datetime &time[],
              const double &open[],
              const double &high[],
              const double &low[],
              const double &close[],
              const long &tick_volume[],
              const long &volume[],
              const int &spread[])
 {
//--- iAC 指標から複製された値の数
  int values_to_copy;
//--- 指標で計算された値の数を決める
  int calculated=BarsCalculated(handle);
  if(calculated<=0)
    {
    PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());
    return(0);
    }
//--- これが指標計算の初めであるか iAC 指標の値の数が変更した
//---または、2 つ以上のバーの指標の計算が必要である場合(価格履歴で何かが変更された)
  if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
    {
    //--- もし iACBuffer 配列が銘柄/期間で iAC 指標の値の数より大きい場合、全体のコピーはしない
    //--- 他の場合、指標バッファサイズより少ない量をコピーをする
    if(calculated>rates_total) values_to_copy=rates_total;
    else                       values_to_copy=calculated;
    }
  else
    {
    //--- これは初回の計算ではなく、
    //--- 前回の OnCalculate() から、一以上のバーが加えられてない。
     values_to_copy=(rates_total-prev_calculated)+1;
    }
//--- ACオシレーター指標の値で iACBuffer と iACColors 配列を記入する
//--- FillArraysFromBuffer が false を返した場合、情報の準備が終わっていないので操作を終了する
  if(!FillArraysFromBuffer(iACBuffer,iACColors,handle,values_to_copy)) return(0);
//--- メッセージを形成する
  string comm=StringFormat("%s ==>  Updated value in the indicator %s: %d",
                          TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                           short_name,
                           values_to_copy);
//--- チャートにサービスメッセージを表示する
  Comment(comm);
//--- ACオシレーター指標の値の数を覚える
  bars_calculated=calculated;
//--- prev_calculated 値を次の関数呼び出しのために返す
  return(rates_total);
 }
//+------------------------------------------------------------------+
//| iAC 指標から指標バッファを記入する                                        |
//+------------------------------------------------------------------+
bool FillArraysFromBuffer(double &values[],       // ACオシレーター値の指標バッファ
                        double &color_indexes[], // 色のバッファ(色インデックスを格納)
                        int ind_handle,         // iAC 指標ハンドル
                        int amount               // 複製された値の数
                         )
 {
//--- エラーコードをリセットする
  ResetLastError();
//--- インデックス0 を持つ指標バッファの値で iACBuffer 配列の一部を記入する
  if(CopyBuffer(ind_handle,0,0,amount,values)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy data from the iAC indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
//--- 色インデックスを複製する
  if(CopyBuffer(ind_handle,1,0,amount,color_indexes)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy color values from the iAC indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
//--- 全てが成功
  return(true);
 }
//+------------------------------------------------------------------+
//| 指標初期化解除関数                                                  |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
 {
  if(handle!=INVALID_HANDLE)
    IndicatorRelease(handle);
//--- 指標の削除後チャートをクリアする
  Comment("");
 }