iTEMA

この関数は Triple Exponential Moving Average 指標ハンドルを返します。バッファは 1 つです。

int  iTEMA(
  string              symbol,            // 銘柄名
  ENUM_TIMEFRAMES    period,            // 期間
  int                ma_period,        // 平均期間
  int                ma_shift,          // 指標の水平シフト
  ENUM_APPLIED_PRICE  applied_price      // 価格の種類かハンドル
  );

パラメータ

symbol

[in] データが指標計算に使用される有価証券の銘柄名(NULL は現在のシンボル)

period

[in] 期間の値は ENUM_TIMEFRAMES 列挙の値の 1 つで、0 は現在の時間軸の意味です。

ma_period

[in]  計算の平均期間(バーの数)

ma_shift

[in]  価格チャートに相対した指標のシフト

applied_price

[in]  使用される価格。ENUM_APPLIED_PRICE 価格定数のいずれか、または別の指標ハンドル。

戻り値

指定されたテクニカル指標ハンドル。失敗の場合 INVALID_HANDLEIndicatorRelease() 関数に指標ハンドルを渡すことによって 、コンピュータメモリを利用されていない指標から解放することが出来ます。

例:

//+------------------------------------------------------------------+
//|                                                   Demo_iTEMA.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link     "https://www.mql5.com"
#property version   "1.00"
#property description "The indicator demonstrates how to obtain data"
#property description "of indicator buffers for the iTEMA technical indicator."
#property description "A symbol and timeframe used for calculation of the indicator,"
#property description "are set by the symbol and period parameters."
#property description "The method of creation of the handle is set through the 'type' parameter (function type)."
#property description "All the other parameters are similar to the standard Triple Exponential Moving Average."
 
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- iTEMA プロット
#property indicator_label1 "iTEMA"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1  1
//+------------------------------------------------------------------+
//| 作成を処理する方法の列挙                                              |
//+------------------------------------------------------------------+
enum Creation
 {
  Call_iTEMA,             // iTEMA を使用する
  Call_IndicatorCreate   // IndicatorCreateを使用する
 };
//--- 入力パラメータ
input Creation             type=Call_iTEMA;           // 関数の種類
input int                  ma_period=14;             // 平均期間
input int                  ma_shift=0;               // シフト
input ENUM_APPLIED_PRICE   applied_price=PRICE_CLOSE; // 価格の種類
input string               symbol=" ";               // シンボル
input ENUM_TIMEFRAMES     period=PERIOD_CURRENT;     // 時間軸
//--- 指標バッファ
double         iTEMABuffer[];
//--- iTEMA 指標ハンドルを格納する変数
int    handle;
//--- 格納に使用される変数
string name=symbol;
//--- チャートでの指標名
string short_name;
//--- Triple Exponential Moving Average 指標に値の数を保存
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数                                            |
//+------------------------------------------------------------------+
int OnInit()
 {
//--- 配列の指標バッファへの割り当て
  SetIndexBuffer(0,iTEMABuffer,INDICATOR_DATA);
//--- シフトを設定
  PlotIndexSetInteger(0,PLOT_SHIFT,ma_shift);
//--- 指標が描画するシンボルを決める
  name=symbol;
//--- 左右のスペースを削する
  StringTrimRight(name);
  StringTrimLeft(name);
//---「name」文字列の長さがゼロになった場合
  if(StringLen(name)==0)
    {
    //--- 指標が接続されているチャートのシンボルを取る
     name=_Symbol;
    }
//--- 指標ハンドルを作成する
  if(type==Call_iTEMA)
     handle=iTEMA(name,period,ma_period,ma_shift,applied_price);
  else
    {
    //--- 構造体を指標のパラメータで記入    
     MqlParam pars[3];
    //--- 期間
     pars[0].type=TYPE_INT;
     pars[0].integer_value=ma_period;
    //--- シフト
     pars[1].type=TYPE_INT;
     pars[1].integer_value=ma_shift;
    //--- 価格の種類
     pars[2].type=TYPE_INT;
     pars[2].integer_value=applied_price;
     handle=IndicatorCreate(name,period,IND_TEMA,3,pars);
    }
//--- ハンドルが作成されなかった場合
  if(handle==INVALID_HANDLE)
    {
    //--- 失敗した事実とエラーコードを出力する
    PrintFormat("Failed to create handle of the iTEMA indicator for the symbol %s/%s, error code %d",
                 name,
                EnumToString(period),
                GetLastError());
    //--- 指標が早期に中止された
    return(INIT_FAILED);
    }
//--- Triple Exponential Moving Average 指標が計算された銘柄/時間軸を表示
  short_name=StringFormat("iTEMA(%s/%s, %d, %d, %s)",name,EnumToString(period),
                          ma_period,ma_shift,EnumToString(applied_price));
  IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- 通常の指標の初期化  
  return(INIT_SUCCEEDED);
 }
//+------------------------------------------------------------------+
//| カスタム指標の反復関数                                                |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
              const int prev_calculated,
              const datetime &time[],
              const double &open[],
              const double &high[],
              const double &low[],
              const double &close[],
              const long &tick_volume[],
              const long &volume[],
              const int &spread[])
 {
//--- iTEMA 指標から複製された値の数r
  int values_to_copy;
//--- 指標で計算された値の数を決める
  int calculated=BarsCalculated(handle);
  if(calculated<=0)
    {
    PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());
    return(0);
    }
//--- これが指標計算の初めであるか iTEMA 指標の値の数が変更した
//---または、2 つ以上のバーの指標の計算が必要である場合(価格履歴で何かが変更された)
  if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
    {
    //--- iTEMABuffer 配列が銘柄/期間で iTEMA 指標の値の数より大きい場合、全体のコピーはしない
    //--- 他の場合、指標バッファサイズより少ない量をコピーをする
    if(calculated>rates_total) values_to_copy=rates_total;
    else                       values_to_copy=calculated;
    }
  else
    {
    //--- これは初回の計算ではなく、
    //--- 前回の OnCalculate() から、一以上のバーが加えられてない。
     values_to_copy=(rates_total-prev_calculated)+1;
    }
//--- 配列をTriple Exponential Moving Average 指標の値で記入
//--- FillArrayFromBuffer が false を返した場合、情報の準備が終わっていないので操作を終了する
  if(!FillArrayFromBuffer(iTEMABuffer,ma_shift,handle,values_to_copy)) return(0);
//--- メッセージを形成する
  string comm=StringFormat("%s ==>  Updated value in the indicator %s: %d",
                          TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                           short_name,
                           values_to_copy);
//--- チャートにサービスメッセージを表示する
  Comment(comm);
//--- Triple Exponential Moving Average 指標の値の数を覚える
  bars_calculated=calculated;
//--- prev_calculated 値を次の関数呼び出しのために返す
  return(rates_total);
 }
//+------------------------------------------------------------------+
//| iTEMA 指標から指標バッファを記入する                                      |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &tema_buffer[], // Triple Exponential Moving Average 値の指標バッファ
                        int t_shift,           // 線のシフト
                        int ind_handle,       // iTEMA 指標ハンドル
                        int amount             // 複製された値の数
                        )
 {
//--- エラーコードをリセットする
  ResetLastError();
//--- インデックス0 を持つ指標バッファの値で iTEMABuffer 配列の一部を記入する
  if(CopyBuffer(ind_handle,0,-t_shift,amount,tema_buffer)<0)
    {
    //--- 複製が失敗したら、エラーコードを出す
    PrintFormat("Failed to copy data from the iTEMA indicator, error code %d",GetLastError());
    //--- ゼロ結果で終了。 指標は計算されていないと見なされる
    return(false);
    }
//--- 全てが成功
  return(true);
 }
//+------------------------------------------------------------------+
//| 指標初期化解除関数                                                  |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
 {
//--- 指標の削除後チャートをクリアする
  Comment("");
 }