Demo_FileDelete - Skript für den MetaTrader 5

Das Skript sucht alle Textdateien im lokalen Terminalordner und löscht jene, dessen Erstellungsdatum kleiner ist als der Datenwert des Eingabeparameters "InpFilesDate". Der Ort des lokalen Terminal-Ordners kann durch Aufruf der TerminalInfoString() Funktion festgestellt werden.

PrintFormat("Der Pfad zum lokalen Terminal-Ordner lautet: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));

Code:

//--- zeige das Fesnter mit den Eingabeparametern beim Aufruf des Skripts
#property script_show_inputs
//--- Datum für alte Dateien
input datetime InpFilesDate=D'2010.01.01 00:00';
//+------------------------------------------------------------------+
//| Skript Programmstart Funktion                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string   file_name;      // Variable zum speichern von Dateinamen
   string   filter="*.txt"; // Filter für Suche nach Dateien
   datetime create_date;    // Dateierstellungsdatum
   string   files[];        // Liste von Dateinamen
   int      def_size=25;    // standardmäßige Arraygröße
   int      size=0;         // Anzahl von Dateien
//--- Speicher für das Array reservieren
   ArrayResize(files,def_size);
//--- Such-Handle für Wurzelverzeichnis des lokalen Ordners
   long search_handle=FileFindFirst(filter,file_name);
//--- prüfe, ob FileFindFirst() erfolgreich ausgeführt wurde
   if(search_handle!=INVALID_HANDLE)
     {
      //--- suchen von Dateien in einer Schleife
      do
        {
         files[size]=file_name;
         //--- Größe des Arrays vergrößern
         size++;
         if(size==def_size)
           {
            def_size+=25;
            ArrayResize(files,def_size);
           }
         //--- Fehlerwert zurücksetzen
         ResetLastError();
         //--- Dateierstellungsdatum beziehen
         create_date=(datetime)FileGetInteger(file_name,FILE_CREATE_DATE,false);
         //--- prüfen, ob die Datei alt ist
         if(create_date<InpFilesDate)
           {
            PrintFormat("%s Datei gelöscht!",file_name);
            //--- alte Datei löschen
            FileDelete(file_name);
           }
        }
      while(FileFindNext(search_handle,file_name));
      //--- Such-Handle schließen
      FileFindClose(search_handle);
     }
   else
     {
      Print("Dateien nicht gefunden!");
      return;
     }
//--- prüfen, welche Dateien übrig geblieben sind
   PrintFormat("Ergebnisse:");
   for(int i=0;i<size;i++)
     {
      if(FileIsExist(files[i]))
         PrintFormat("%s Datei existiert!",files[i]);
      else
         PrintFormat("%s Datei gelöscht!",files[i]);
     }
  }