Demo_FileDelete - script para MetaTrader 5

O script pesquisa todos os arquivos de texto na pasta local do terminal e exclui aqueles com os dados de construção menor do que o valor no parâmetro de entrada "InpFilesDate". A posição da pasta local do terminal pode ser obtida chamando a função TerminalInfoString().

PrintFormat("O caminho para a pasta local do terminal: %s\\Arquivos\\",TerminalInfoString(TERMINAL_DATA_PATH));

Código:

//--- Mostra a janela de parâmetros de entrada, ao lançar o script 
#property script_show_inputs
//--- data para os arquivos antigos
input datetime InpFilesDate=D'2010.01.01 00:00';
//+------------------------------------------------------------------+
//| Função iniciar do Script de programa                             |
//+------------------------------------------------------------------+
void OnStart()
  {
   string   file_name;      // variável para armazenar os nomes dos arquivos
   string   filter="*.txt"; // filtrar os arquivos por pesquisa
   datetime create_date;    // arquivo da data de criação
   string   files[];        // lista de nomes dos arquivos
   int      def_size=25;    // tamanho da array por padrão 
   int      size=0;         // número de arquivos
//--- alocação de memória para a array
   ArrayResize(files,def_size);
//--- receber o buscador handle na raiz da pasta local 
   long search_handle=FileFindFirst(filter,file_name);
//--- verificar se FileFindFirst() é executado com sucesso
   if(search_handle!=INVALID_HANDLE)
     {
      //--- pesquisando arquivos no loop
      do
        {
         files[size]=file_name;
         //--- aumentando o tamanho da array
         size++;
         if(size==def_size)
           {
            def_size+=25;
            ArrayResize(files,def_size);
           }
         //--- redefinir o valor de erro
         ResetLastError();
         //--- receber a data de criação do arquivo
         create_date=(datetime)FileGetInteger(file_name,FILE_CREATE_DATE,false);
         //--- verificar se o arquivo é antigo
         if(create_date<InpFilesDate)
           {
            PrintFormat("%s arquivo deletado!",file_name);
            //--- exclui o arquivo antigo
            FileDelete(file_name);
           }
        }
      while(FileFindNext(search_handle,file_name));
      //--- fecha o buscador handle
      FileFindClose(search_handle);
     }
   else
     {
      Print("Arquivos não encontrados!");
      return;
     }
//--- Verificar quais arquivos permaneceram 
   PrintFormat("Resultados:");
   for(int i=0;i<size;i++)
     {
      if(FileIsExist(files[i]))
         PrintFormat("%s arquivos existentes!",files[i]);
      else
         PrintFormat("%s arquivos excluídos!",files[i]);
     }
  }