Local Timezones and Local Session Hours - librería para MetaTrader 5

//+------------------------------------------------------------------+
//| Identificadores de zona horaria|
//+------------------------------------------------------------------+
enum ENUM_ZONE_ID
  {
   ZONE_ID_SYDNEY,     // Sídney
   ZONE_ID_TOKYO,      // Tokio
   ZONE_ID_FRANKFURT,  // Fráncfort
   ZONE_ID_LONDON,     // Londres
   ZONE_ID_NEWYORK,    // Nueva York
   ZONE_ID_UTC,        // UTC
   ZONE_ID_LOCAL,      // LOCAL
   ZONE_ID_BROKER,     // BROKER
   ZONE_ID_CUSTOM      // PERSONALIZADO
  };

//+------------------------------------------------------------------+
//| Establece la opción de utilizar el símbolo XAUUSD (Oro) para estimar la ||.
//| TZ/DST del servidor por análisis del historial de citas H1. ||
//| TRUE : buscar y cargar el símbolo Gold (comportamiento por defecto). || TRUE : buscar y cargar el símbolo Gold (comportamiento por defecto).
//| FALSE : utilizar el símbolo del gráfico actual. ||
//+------------------------------------------------------------------+
void CTimeZoneInfo::SetUsingGoldSymbol(const bool enabled = true);

¿Cómo obtener la hora actual?

   Print("\n========== More information about a timezone ==========");

   CTimeZoneInfo tz(ZONE_ID_NEWYORK);
   tz.RefreshTime();

   Print("Name()                  : ", tz.Name());
   Print("TimeUTC()               : ", tz.TimeUTC());
   Print("TimeLocal()             : ", tz.TimeLocal());
   Print("TimeGMTOffset()         : ", tz.TimeGMTOffset());
   Print("TimeDaylightSavings()   : ", tz.TimeDaylightSavings());
   Print("ToString()              : ", tz.ToString());
   datetime dst_start, dst_end;
   tz.GetDaylightSwitchTimes(dst_start, dst_end);
   Print("dst_start               : ", dst_start);
   Print("dst_end                 : ", dst_end);
   Print("GetDaylightNextSwitch() : ", tz.GetDaylightNextSwitch());

   Print("\n========== Configure the built-in custom timezone ==========");

   string        name  = "Custom+3";               // Nombre de la zona horaria personalizada
   int           baseGMTOffset  = 10800;           // Desplazamiento GMT base de la zona horaria personalizada (en segundos)
   ENUM_ZONE_ID  daylightRuleId = ZONE_ID_LONDON;  // Horario DST de la zona horaria personalizada

   bool success = CTimeZoneInfo::SetCustomTimeZone(name, baseGMTOffset, daylightRuleId);

   Print("Parameter 'name'            : ", name);
   Print("Parameter 'baseGMTOffset'   : ", baseGMTOffset);
   Print("Parameter 'daylightRuleId'  : ", EnumToString(daylightRuleId));
   Print("SetCustomTimeZone() returns : ", success);

Salida:

   // ========== Configurar la zona horaria personalizada incorporada ==========
   // Parámetro 'nombre' : Personalizado+3
   // Parámetro 'baseGMTOffset' : 10800
   // Parámetro 'daylightRuleId' : ZONE_ID_LONDON
   // SetCustomTimeZone() vuelve : true

Obtener la Hora Actual en Todas las Zonas Horarias

Veamos un ejemplo para mostrar cómo podemos obtener la hora local actual en todas las zonas horarias.

   Print("\n========== Get Current Time in All Timezones ==========");

   for(ENUM_ZONE_ID id=0; id <= MAX_ZONE_ID; id++)
     {
      CTimeZoneInfo tz(id);
      tz.RefreshTime();

      PrintFormat("%-12s:  %s | %s", tz.Name(), TimeToString(tz.TimeLocal()), tz.ToString());
     }

salida:

   // ========== Obtener la hora actual en todas las zonas horarias ==========
   // Sydney : 2024.02.28 21:58 | Wed, 2024.02.28 21:58:50 GMT+11 [Sydney] (DST)
   // Tokio : 2024.02.28 19:58 | Wed, 2024.02.28 19:58:50 GMT+9 [Tokio]
   // Frankfurt : 2024.02.28 11:58 | Wed, 2024.02.28 11:58:50 GMT+1 [Frankfurt]
   // Londres : 2024.02.28 10:58 | Wed, 2024.02.28 10:58:50 GMT+0 [Londres]
   // Nueva York : 2024.02.28 05:58 | Wed, 2024.02.28 05:58:50 GMT-5 [Nueva York]
   // UTC : 2024.02.28 10:58 | Wed, 2024.02.28 10:58:50 GMT+0 [UTC]
   // Inicio : 2024.02.28 12:58 | Wed, 2024.02.28 12:58:50 GMT+2 [Inicio]
   // FXOpen-MT5 : 2024.02.28 12:58 | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]

Esto se puede hacer de la otra forma utilizando el método estático GetCurrentTimeForPlace(). Además, hay otro método estático FormatTimeForPlace() que puede usarse para formatear variables datetime de mql a una cadena ( similar a TimeToString) pero con el día de la semana, la fecha, la hora, el nombre de la zona horaria y los desfases. Estos métodos estáticos no requieren la creación de objetos para llamarlos.

   Print("\n========== GetCurrentTimeForPlace() ==========");

   for(ENUM_ZONE_ID id=0; id <= MAX_ZONE_ID; id++)
     {
      datetime time = CTimeZoneInfo::GetCurrentTimeForPlace(id);

      PrintFormat("Time        :  %s | %s", TimeToString(time), CTimeZoneInfo::FormatTimeForPlace(time, id));
     }

salida:

   // ========== GetCurrentTimeForPlace() ==========
   // Hora : 2024.02.28 21:58 | Wed, 2024.02.28 21:58:50 GMT+11 [Sydney] (DST)
   // Hora : 2024.02.28 19:58 | Wed, 2024.02.28 19:58:50 GMT+9 [Tokyo]
   // Hora : 2024.02.28 11:58 | Wed, 2024.02.28 11:58:50 GMT+1 [Frankfurt]
   // Hora : 2024.02.28 10:58 | Wed, 2024.02.28 10:58:50 GMT+0 [Londres]
   // Hora : 2024.02.28 05:58 | Wed, 2024.02.28 05:58:50 GMT-5 [Nueva York]
   // Hora : 2024.02.28 10:58 | Wed, 2024.02.28 10:58:50 GMT+0 [UTC]
   // Hora : 2024.02.28 12:58 | Wed, 2024.02.28 12:58:50 GMT+2 [Inicio]
   // Hora : 2024.02.28 12:58 | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]

¿Cómo establecer la hora local de la zona horaria?

   Print("\n========== Set the local time for a timezone ==========");

   CTimeZoneInfo tz(ZONE_ID_NEWYORK);

   if(tz.SetLocalTime(D'2021.07.15 09:31'))
      PrintFormat("%-12s:  %s | %s", tz.Name(), TimeToString(tz.TimeLocal()), tz.ToString());

   if(tz.SetLocalTime(D'2022.01.23 17:04'))
      PrintFormat("%-12s:  %s | %s", tz.Name(), TimeToString(tz.TimeLocal()), tz.ToString());

   if(tz.SetLocalTime(D'2023.03.12 02:21'))
      PrintFormat("%-12s:  %s | %s", tz.Name(), TimeToString(tz.TimeLocal()), tz.ToString());

salida:

   // ========== Establecer la hora local para una zona horaria ==========
   // Nueva York : 2021.07.15 09:31 | Thu, 2021.07.15 09:31:00 GMT-4 [Nueva York] (DST)
   // Nueva York : 2022.01.23 17:04 | Sun, 2022.01.23 17:04:00 GMT-5 [Nueva York]
   // >>Error: La hora 2023.03.12 02:21 no existe en Nueva York. Esto se debe a que el horario de verano se ha saltado una hora.

La causa del último mensaje de error que obtenemos se explicará en el siguiente párrafo.

Horario de verano (DST):

En Estados Unidos, el DST comienza siempre a las 02:00 (2 am) hora local. En el momento en que la hora alcanza por primera vez la 1:59:59 hora estándar, los relojes se adelantan a las 3:00:00 hora de verano. Por lo tanto, la hora que va de las 2:00:00 a las 2:59:59 no existe en la noche del cambio.

Veamos un ejemplo para mostrar cómo podemos obtener el nombre de la zona horaria, el desplazamiento UTC y el desplazamiento DST actual si el DST está en efecto.

   Print("\n========== UTC offset and current DST offset ==========");

   for(ENUM_ZONE_ID id=0; id <= MAX_ZONE_ID; id++)
     {
      CTimeZoneInfo tz(id);
      tz.RefreshTime(); // rellenar la información de la zona horaria actual

      PrintFormat("%-12s: GMT%+g | DST%+g", tz.Name(), tz.TimeGMTOffset()/3600., tz.TimeDaylightSavings()/3600.);
     }

salida:

   // ========== desfase UTC y desfase DST actual ==========
   // Sydney : GMT+11 | DST+1
   // Tokio : GMT+9 | DST+0
   // Frankfurt : GMT+1 | DST+0
   // Londres : GMT+0 | DST+0
   // Nueva York : GMT-4 | DST+1
   // UTC : GMT+0 | DST+0
   // Inicio : GMT+2 | DST+0
   // FXOpen-MT5 : GMT+2 | DST+0

Notas:

- El método TimeGMTOffset() devuelve la diferencia actual entre la hora local de esta zona horaria y la hora GMT en segundos, teniendo en cuenta el cambio a horario de invierno o verano. El offset devuelto incluye el ajuste DST de la zona horaria actual. El desfase GMT es positivo si la zona horaria está al este de (por delante de) GMT, y es negativo si la zona horaria está al oeste de (por detrás de) GMT.

- El método TimeDaylightSavings() devuelve el ajuste del horario de verano (DST) en segundos, si se ha realizado el cambio al horario de verano en las zonas donde el DST está en vigor. Si se ha realizado el cambio al horario de invierno (estándar) (o, si la zona horaria no soporta DST), devuelve 0. El ajuste dst ya forma parte del TimeGMTOffset.

2. Cambio de horario DST para el año en curso

Veamos un ejemplo para mostrar cómo podemos obtener la información DST.

   Print("\n========== DST switch times for the current year ==========");

   datetime dst_start, dst_end;

   for(ENUM_ZONE_ID id=0; id <= MAX_ZONE_ID; id++)
     {
      CTimeZoneInfo tz(id);
      tz.RefreshTime(); // rellenar la información de la zona horaria actual

      //--- sólo para zonas horarias que observan el horario de verano.
      if(tz.GetDaylightSwitchTimes(dst_start, dst_end))
        {
         PrintFormat("%-12s:  DST starts on %s |  DST ends on %s", tz.Name(), TimeToString(dst_start), TimeToString(dst_end));
        }
     }

salida:

   // ========== Horario de verano para el año en curso ==========
   // Sydney : DST comienza el 2024.04.07 03:00 | DST termina el 2024.10.06 02:00
   // Frankfurt : DST comienza el 2024.03.31 02:00 | DST termina el 2024.10.27 03:00
   // Londres : DST comienza el 2024.03.31 01:00 | DST termina el 2024.10.27 02:00
   // New York : DST comienza el 2024.03.10 02:00 | DST termina el 2024.11.03 02:00

3. Hora del próximo cambio DST

Veamos un ejemplo para mostrar como podemos obtener la hora del próximo cambio DST.

   Print("\n========== Time of the next DST switch ==========");

   for(ENUM_ZONE_ID id=0; id <= MAX_ZONE_ID; id++)
     {
      CTimeZoneInfo tz(id);
      tz.RefreshTime();

      datetime nxswitch = tz.GetDaylightNextSwitch();

      //--- sólo para zonas horarias que observan el horario de verano.
      if(nxswitch)
        {
         PrintFormat("%-12s:  Time: %s |  dstNextSwitch: %s", tz.Name(), TimeToString(tz.TimeLocal()), TimeToString(nxswitch));
        }
     }

salida:

   // ========== Hora del próximo cambio DST ==========
   // Sydney : Hora: 2024.02.28 21:58 | dstNextSwitch: 2024.04.07 03:00
   // Frankfurt : Hora: 2024.02.28 11:58 | dstNextSwitch: 2024.03.31 02:00
   // Londres : Hora: 2024.02.28 10:58 | dstNextSwitch: 2024.03.31 01:00
   // Nueva York : Hora: 2024.02.28 05:58 | dstNextSwitch: 2024.03.10 02:00

4. Lista DST

Veamos un ejemplo para mostrar cómo podemos obtener la información DST para todas las zonas horarias en esta biblioteca para un rango de años.

   Print("\n========== DST List ==========");

   datetime dst_start, dst_end;
   int delta_start, delta_end;  // cambios de reloj en seg

   for(ENUM_ZONE_ID id=0; id <= MAX_ZONE_ID; id++)
     {
      CTimeZoneInfo timezone(id);

      PrintFormat("========= %s Summer Time (DST) =========", timezone.Name());
      for(int year=2008; year<=2030; year++)
        {
         //--- sólo para zonas horarias que observan el horario de verano.
         if(CTimeZoneInfo::GetDaylightSwitchTimes(id, year, dst_start, dst_end))
           {
            CTimeZoneInfo::GetDaylightSwitchDeltas(id, year, delta_start, delta_end);

            PrintFormat("DST starts on %s (%+d) and ends on %s (%+d)",TimeToString(dst_start), delta_start/3600, TimeToString(dst_end), delta_end/3600);
           }
        }

     }

salida:

   // ========== Lista DST ==========
   // ========= Horario de verano de Sydney (DST) =========
   // DST comienza el 2008.04.06 03:00 (-1) y termina el 2008.10.05 02:00 (+1)
   // DST comienza el 2009.04.05 03:00 (-1) y termina el 2009.10.04 02:00 (+1)
   // DST comienza el 2010.04.04 03:00 (-1) y termina el 2010.10.03 02:00 (+1)
   // DST comienza el 2011.04.03 03:00 (-1) y termina el 2011.10.02 02:00 (+1)
   // DST comienza el 2012.04.01 03:00 (-1) y termina el 2012.10.07 02:00 (+1)
   // ...
   // ...
   // ...

5. Offset GMT del Servidor (Actual)

El offset GMT del broker indica cuántos segundos está adelantada la hora del broker con respecto a GMT, offset broker = TimeTradeServer() - TimeGMT(). Valores positivos indican que la hora del servidor está adelantada respecto a GMT. Veamos un ejemplo para mostrar como podemos obtener el offset GMT actual del broker.

   Print("\n========== Current GMT offset of the broker ========== ");

   CTimeZoneInfo broker(ZONE_ID_BROKER);
   broker.RefreshTime();

   Print("Name()          : ", broker.Name());
   Print("TimeLocal()     : ", broker.TimeLocal());  // tiempo de agente
   Print("ToString()      : ", broker.ToString());
   Print("TimeGMTOffset() : ", broker.TimeGMTOffset());

salida:

   // ========== Desplazamiento GMT actual del corredor ==========
   // Nombre() : ICMarketsSC-Demo
   // HoraLocal() : 2024.03.08 06:33:06
   // ToString() : Fri, 2024.03.08 06:33:06 GMT+2 [ICMarketsSC-Demo]
   // TimeGMTOffset() : 7200

Nota: Una nota importante para el TimeGMTOffset() es que devolverá el offset utc incluyendo la corrección dst (UTC+DST). Valores positivos indican que la hora del servidor está adelantada (al este) de GMT.

6. Offset GMT del servidor (Histórico)

   Print("\n========== Past GMT offsets of the broker (chart candles) ==========");

   datetime bartimes[];
   int copied = CopyTime(Symbol(), PERIOD_D1, D'2022.03.18', 9, bartimes);
   if(copied<=0)
      Print("CopyTime() failed.");

   for(int i =0; i < copied; i++)
     {
      datetime t = bartimes[i];

      CTimeZoneInfo broker(ZONE_ID_BROKER);
      broker.SetLocalTime(t);

      PrintFormat("bar #%i  Time: %s |  offset: %5d (GMT%+g) |  %s",
                  i+1,
                  TimeToString(broker.TimeLocal()),
                  broker.TimeGMTOffset(),
                  broker.TimeGMTOffset()/3600.0,
                  broker.ToString());
     }

salida:

   // ========== Desplazamientos GMT pasados del corredor (velas del gráfico) ==========
   // bar #1 Hora: 2022.03.08 00:00 | offset: 7200 (GMT+2) | Tue, 2022.03.08 00:00:00 GMT+2 [ICMarketsSC-Demo]
   // bar #2 Hora: 2022.03.09 00:00 | offset: 7200 (GMT+2) | Wed, 2022.03.09 00:00:00 GMT+2 [ICMarketsSC-Demo]
   // bar #3 Hora: 2022.03.10 00:00 | offset: 7200 (GMT+2) | Thu, 2022.03.10 00:00:00 GMT+2 [ICMarketsSC-Demo]
   // bar #4 Hora: 2022.03.11 00:00 | offset: 7200 (GMT+2) | Fri, 2022.03.11 00:00:00 GMT+2 [ICMarketsSC-Demo]
   // bar #5 Hora: 2022.03.14 00:00 | offset: 10800 (GMT+3) | Mon, 2022.03.14 00:00:00 GMT+3 [ICMarketsSC-Demo]
   // bar #6 Hora: 2022.03.15 00:00 | offset: 10800 (GMT+3) | Tue, 2022.03.15 00:00:00 GMT+3 [ICMarketsSC-Demo]
   // bar #7 Hora: 2022.03.16 00:00 | offset: 10800 (GMT+3) | Wed, 2022.03.16 00:00:00 GMT+3 [ICMarketsSC-Demo]
   // bar #8 Hora: 2022.03.17 00:00 | offset: 10800 (GMT+3) | Thu, 2022.03.17 00:00:00 GMT+3 [ICMarketsSC-Demo]
   // bar #9 Hora: 2022.03.18 00:00 | offset: 10800 (GMT+3) | Fri, 2022.03.18 00:00:00 GMT+3 [ICMarketsSC-Demo]

Como, usted ve en la barra #5, el servidor ha cambiado de +2 horario de invierno a +3 horario de verano, y el tiempo del cambio sigue el horario DST de EE.UU. (2do Domingo de Marzo). Hay cinco velas D1 por semana, y no hay velas en Sábado y Domingo. El tiempo en estos servidores es siempre 7 horas adelante de Nueva York a través del año y representado como NY+7. Note que NY es -5 en invierno, y -4 en verano.

Esta es la primera biblioteca en el código base capaz de determinar el desfase GMT del servidor en el pasado (desfases GMT históricos). El algoritmo implementado en los cálculos es muy rápido y preciso, y es compatible - en la medida de lo posible - con diferentes brokers (probado en un gran número de brokers con diferentes desfases GMT u horarios DST).

III. Conversión entre zonas horarias

Utilice el método ConvertLocalTime() para convertir la hora local de esta instancia de zona horaria a una zona horaria específica. Este método devuelve una nueva hora de una zona horaria determinada.

Veamos un ejemplo para mostrar cómo podemos convertir la hora local"actual" a una zona horaria específica.

   Print("\n========== Convert current local time in Sydney to New York ==========");

   CTimeZoneInfo sydney(ZONE_ID_SYDNEY);
   sydney.RefreshTime();

   datetime localtime = sydney.TimeLocal();
   datetime converted = sydney.ConvertLocalTime(ZONE_ID_NEWYORK);

   PrintFormat("%s | %s", TimeToString(localtime), sydney.ToString());
   PrintFormat("%s | %s", TimeToString(converted), CTimeZoneInfo::FormatTimeForPlace(converted, ZONE_ID_NEWYORK));

salida:

   // ========== Convertir la hora local actual de Sydney a Nueva York ==========
   // 2024.02.28 21:58 | Wed, 2024.02.28 21:58:50 GMT+11 [Sydney] (DST)
   // 2024.02.28 05:58 | Wed, 2024.02.28 05:58:50 GMT-5 [Nueva York]

Convertir una hora local concreta a otra zona horaria

Veamos un ejemplo para mostrar cómo podemos convertir una hora local específica a una zona horaria específica.

   Print("\n========== Convert a specific local time in Sydney to New York ==========");

   CTimeZoneInfo sydney(ZONE_ID_SYDNEY);
   sydney.SetLocalTime(D'2016.05.21 14:47:08');

   datetime localtime = sydney.TimeLocal();
   datetime converted = sydney.ConvertLocalTime(ZONE_ID_NEWYORK);

   PrintFormat("%s | %s", TimeToString(localtime), sydney.ToString());
   PrintFormat("%s | %s", TimeToString(converted), CTimeZoneInfo::FormatTimeForPlace(converted, ZONE_ID_NEWYORK));

salida:

   // ========== Convertir una hora local específica de Sydney a Nueva York ==========
   // 2016.05.21 14:47 | Sat, 2016.05.21 14:47:08 GMT+10 [Sydney]
   // 2016.05.21 00:47 | Sat, 2016.05.21 00:47:08 GMT-4 [Nueva York] (DST)

Convertir la hora local actual en todas las zonas horarias a la hora del broker

Veamos un ejemplo para mostrar como podemos convertir la hora local actual en todas las zonas horarias a la hora del broker.

   Print("\n========== Convert the current local time in all timezones to the broker time ==========");

   for(ENUM_ZONE_ID id=0; id <= MAX_ZONE_ID; id++)
     {
      datetime localtime = CTimeZoneInfo::GetCurrentTimeForPlace(id);
      datetime converted = CTimeZoneInfo::ConvertTimeForPlace(localtime, id, ZONE_ID_BROKER);

      PrintFormat("%-49s | %s", CTimeZoneInfo::FormatTimeForPlace(localtime, id), CTimeZoneInfo::FormatTimeForPlace(converted, ZONE_ID_BROKER));
     }

salida:

   // ========== Convertir la hora local actual en todas las zonas horarias a la hora del broker ==========
   // Wed, 2024.02.28 21:58:50 GMT+11 [Sydney] (DST) | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]
   // Wed, 2024.02.28 19:58:50 GMT+9 [Tokyo] | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]
   // Wed, 2024.02.28 11:58:50 GMT+1 [Frankfurt] | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]
   // Wed, 2024.02.28 10:58:50 GMT+0 [Londres] | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]
   // Wed, 2024.02.28 05:58:50 GMT-5 [New York] | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]
   // Wed, 2024.02.28 10:58:50 GMT+0 [UTC] | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]
   // Wed, 2024.02.28 12:58:50 GMT+2 [Home] | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]
   // Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5] | Wed, 2024.02.28 12:58:50 GMT+2 [FXOpen-MT5]

IV. Trabajar con las horas locales de la sesión

A. Clase CTimeZoneInfo

Tenga en cuenta que el uso de la clase CTimeZoneInfo padre, en lugar de la clase CSessionHours , no es preferible, ya que requiere más codificación y por lo tanto propenso a errores. Veamos un ejemplo para mostrar como obtenemos las horas de la sesión Forex en todas las zonas horarias, y las convertimos a la hora del broker.

   Print("\n======= Local Session Hours (CTimeZoneInfo Class) =======");

   const ENUM_ZONE_ID ids[] = {ZONE_ID_SYDNEY, ZONE_ID_TOKYO, ZONE_ID_FRANKFURT, ZONE_ID_LONDON, ZONE_ID_NEWYORK};

   for(int i = 0; i < ArraySize(ids); i++)
     {
      ENUM_ZONE_ID id = ids[i];

      CTimeZoneInfo tz(id);
      tz.RefreshTime();

      datetime localtime = tz.TimeLocal();

      //--- fijar el horario de la sesión de 8:00 a 17:00 hora local
      datetime beginlocal = StringToTime(TimeToString(localtime, TIME_DATE) + " " + "08:00");
      datetime endlocal   = StringToTime(TimeToString(localtime, TIME_DATE) + " " + "17:00");

      //--- conversión a tiempo de broker
      tz.SetLocalTime(beginlocal);
      datetime beginbroker = tz.ConvertLocalTime(ZONE_ID_BROKER);

      tz.SetLocalTime(endlocal);
      datetime endbroker = tz.ConvertLocalTime(ZONE_ID_BROKER);

      //--- día local de la semana en zona horaria
      MqlDateTime st;
      TimeToStruct(localtime, st);
      int dow = st.day_of_week;

      //string state_str = ((dow != SÁBADO && dow != DOMINGO) && (localtime >= beginlocal && localtime < endlocal)) ? "abierto" : "cerrado";
      string state_str = ((dow != SATURDAY && dow != SUNDAY) && (TimeTradeServer() >= beginbroker && TimeTradeServer() < endbroker)) ? "open" : "closed";

      PrintFormat("%-12s:  %s |  %s  [session %s]", tz.Name(), CTimeZoneInfo::FormatTimeForPlace(beginbroker, ZONE_ID_BROKER), CTimeZoneInfo::FormatTimeForPlace(endbroker, ZONE_ID_BROKER), state_str);
     }

   Print("-----------------------------------");
   Print("broker time :  ", TimeTradeServer());
   Print("broker time :  ", CTimeZoneInfo::FormatTimeForPlace(TimeTradeServer(), ZONE_ID_BROKER));

salida:

   // ======= Horario de sesión local (Clase CTimeZoneInfo) =======
   // Sydney : Wed, 2024.02.28 23:00:00 GMT+2 [FXOpen-MT5] | Thu, 2024.02.29 08:00:00 GMT+2 [FXOpen-MT5] [sesión cerrada]
   // Tokio : Mié, 2024.02.28 01:00:00 GMT+2 [FXOpen-MT5] | Mié, 2024.02.28 10:00:00 GMT+2 [FXOpen-MT5] [sesión cerrada].
   // Frankfurt : Wed, 2024.02.28 09:00:00 GMT+2 [FXOpen-MT5] | Wed, 2024.02.28 18:00:00 GMT+2 [FXOpen-MT5] [sesión abierta].
   // Londres : Mié, 2024.02.28 10:00:00 GMT+2 [FXOpen-MT5] | Mié, 2024.02.28 19:00:00 GMT+2 [FXOpen-MT5] [sesión abierta].
   // Nueva York : Wed, 2024.02.28 15:00:00 GMT+2 [FXOpen-MT5] | Thu, 2024.02.29 00:00:00 GMT+2 [FXOpen-MT5] [sesión abierta]
   // -----------------------------------
   // broker time : 2024.02.28 15:32:30
   // broker time : Wed, 2024.02.28 15:32:30 GMT+2 [FXOpen-MT5]

B. Clase CSessionHours

Propósito: Clase para acceder a las horas locales de la sesión de negociación para la ubicación especificada.

Deriva de la clase CTimeZoneInfo.

Nota: El horario de sesión por defecto para los nuevos objetos CSessionHours es de 8:00 am - 5:00 pm hora local. Estos valores predeterminados pueden modificarse según se desee.

Trabajar con objetos CSessionHours

   Print("\n========== Working with CSessionHours Objects  ==========");

   CSessionHours tz(ZONE_ID_SYDNEY);
   tz.RefreshTime(); // rellenar la zona horaria y la información de la sesión

   //--- del padre
   Print("Name()                : ", tz.Name());
   Print("TimeUTC()             : ", tz.TimeUTC());
   Print("TimeLocal()           : ", tz.TimeLocal());
   Print("ToString()            : ", tz.ToString());
   //--- de la clase
   Print("BeginLocalTime()      : ", tz.BeginLocalTime());
   Print("EndLocalTime()        : ", tz.EndLocalTime());
   Print("CheckLocalSession()   : ", tz.CheckLocalSession());
   Print("SecRemainingSession() : ", tz.SecRemainingSession());
   Print("SecondsToString()     : ", CSessionHours::SecondsToString(tz.SecRemainingSession()));

salida:

   // ========== Trabajar con objetos CSessionHours ==========
   // Nombre() : Sydney
   // TimeUTC() : 2024.02.28 10:58:50
   // HoraLocal() : 2024.02.28 21:58:50
   // ToString() : Wed, 2024.02.28 21:58:50 GMT+11 [Sydney] (DST)
   // BeginLocalTime() : 2024.02.28 08:00:00
   // EndLocalTime() : 2024.02.28 17:00:00
   // CheckLocalSession() : false
   // SecRemainingSession() : 0
   // SecondsToString() : 00:00:00

Local Session Hours

El CSessionHours proporciona más funcionalidad con menos código. Veamos un ejemplo para mostrar como obtenemos las horas de sesión Forex en todas las zonas horarias utilizando la Clase CSessionHours , y las convertimos a la hora del broker. Tenga en cuenta que la conversión a la hora del broker es un paso opcional, y no es necesario para comprobar las horas de inicio y fin de cada sesión.

   Print("\n======= Local Session Hours (CSessionHours Class) =======");

   const ENUM_ZONE_ID ids[] = {ZONE_ID_SYDNEY, ZONE_ID_TOKYO, ZONE_ID_FRANKFURT, ZONE_ID_LONDON, ZONE_ID_NEWYORK};

   for(int i = 0; i < ArraySize(ids); i++)
     {
      ENUM_ZONE_ID id = ids[i];

      CSessionHours tz(id);
      tz.RefreshTime();

      //--- el horario de sesión por defecto es de 8:00 a 17:00 hora local
      datetime beginlocal = tz.BeginLocalTime();
      datetime endlocal   = tz.EndLocalTime();

      //--- conversión a tiempo de broker
      datetime beginbroker = CTimeZoneInfo::ConvertTimeForPlace(beginlocal, id, ZONE_ID_BROKER);
      datetime endbroker = CTimeZoneInfo::ConvertTimeForPlace(endlocal, id, ZONE_ID_BROKER);

      string state_str = tz.CheckLocalSession() ? "open, ends in " + CSessionHours::SecondsToString(tz.SecRemainingSession()) : "closed";

      PrintFormat("%-12s:  %s |  %s  [session %s]", tz.Name(), CTimeZoneInfo::FormatTimeForPlace(beginbroker, ZONE_ID_BROKER), CTimeZoneInfo::FormatTimeForPlace(endbroker, ZONE_ID_BROKER), state_str);
     }

   Print("-----------------------------------");
   Print("broker time :  ", TimeTradeServer());
   Print("broker time :  ", CTimeZoneInfo::FormatTimeForPlace(TimeTradeServer(), ZONE_ID_BROKER));
   Print("Fx close    :  ", CTimeZoneInfo::FormatTimeForPlace(CSessionHours::ForexCloseTime(), ZONE_ID_BROKER));
   int sec = CSessionHours::SecRemainingForex();
   Print("closes in   :  ", sec, " sec = ", CSessionHours::SecondsToString(sec));

salida:

   // ======= Horas de la sesión local (Clase CSessionHours) =======
   // Sydney : Wed, 2024.02.28 23:00:00 GMT+2 [FXOpen-MT5] | Thu, 2024.02.29 08:00:00 GMT+2 [FXOpen-MT5] [sesión cerrada]
   // Tokio : Mié, 2024.02.28 01:00:00 GMT+2 [FXOpen-MT5] | Mié, 2024.02.28 10:00:00 GMT+2 [FXOpen-MT5] [sesión cerrada].
   // Frankfurt : Wed, 2024.02.28 09:00:00 GMT+2 [FXOpen-MT5] | Wed, 2024.02.28 18:00:00 GMT+2 [FXOpen-MT5] [sesión abierta, finaliza en 02:27:29].
   // Londres : Mié, 2024.02.28 10:00:00 GMT+2 [FXOpen-MT5] | Mié, 2024.02.28 19:00:00 GMT+2 [FXOpen-MT5] [sesión abierta, termina en 03:27:29].
   // Nueva York : Wed, 2024.02.28 15:00:00 GMT+2 [FXOpen-MT5] | Thu, 2024.02.29 00:00:00 GMT+2 [FXOpen-MT5] [sesión abierta, termina en 08:27:29].
   // -----------------------------------
   // broker time : 2024.02.28 15:32:30
   // broker time : Wed, 2024.02.28 15:32:30 GMT+2 [FXOpen-MT5]
   // Cierre Fx : Sat, 2024.03.02 00:00:00 GMT+2 [FXOpen-MT5]
   // cierra en : 203249 seg = 2d 08:27:29

¿Cómo anular las horas locales de sesión por defecto?

Veamos un ejemplo para mostrar cómo podemos anular las horas de sesión por defecto en la clase CSessionHours .

   Print("\n=========== Override the default session hours ===========");

   CSessionHours frankfurt(ZONE_ID_FRANKFURT);

   // cambiar los tiempos de sesión por defecto
   frankfurt.BeginLocalTime(9, 0);
   frankfurt.EndLocalTime(19, 0);

   frankfurt.RefreshTime(); // rellenar las horas de la nueva sesión

   datetime beginlocal = frankfurt.BeginLocalTime();
   datetime endlocal   = frankfurt.EndLocalTime();

   PrintFormat("new session hours  :  %s | %s", CTimeZoneInfo::FormatTimeForPlace(beginlocal, ZONE_ID_FRANKFURT), CTimeZoneInfo::FormatTimeForPlace(endlocal, ZONE_ID_FRANKFURT));
   PrintFormat("current local time :  %s", frankfurt.ToString());

salida:

   // =========== Anular las horas de sesión por defecto ===========
   // nuevo horario de sesión : Mié, 2024.02.28 09:00:00 GMT+1 [Frankfurt] | Mié, 2024.02.28 19:00:00 GMT+1 [Frankfurt]
   // hora local actual : Wed, 2024.02.28 11:58:50 GMT+1 [Frankfurt]

¿Cómo Comprobar el Cierre de Posiciones en Fin de Semana?

El método estático SecRemainingForex() devolverá el tiempo restante en segundos hasta el cierre del mercado Forex para esta semana. Este método debería ser llamado desde el manejador de eventos OnTick()(o mejor desde OnTimer() en caso de que no haya ticks justo antes del fin de semana) para comprobar repetidamente la condición de cierre. Veamos un ejemplo para mostrar como podemos comprobar las posiciones de cierre en fin de semana.

   Print("\n======= Check For Closing Positions at Weekend =======");

   int InpHours   = 2;   // Horas antes del fin de semana
   int InpMinutes = 30;  // Minutos antes del fin de semana

   int sec = CSessionHours::SecRemainingForex();
   PrintFormat("Time remaining till the weekend : %s", CSessionHours::SecondsToString(sec));
   PrintFormat("Close all if remaining time becomes %s or less.", CSessionHours::SecondsToString(InpHours * 3600 + InpMinutes * 60));

   // comprueba si el tiempo restante ha alcanzado el objetivo
   if(sec <= InpHours * 3600 + InpMinutes * 60)
     {
      // CerrarTodos();
     }

Alternativamente, se puede comprobar la condición anterior utilizando tiempos absolutos:

   // comprueba que el tiempo del corredor ha alcanzado el objetivo
   if(TimeTradeServer() >= CSessionHours::ForexCloseTime() - (InpHours * 3600 + InpMinutes * 60))
     {
      // CerrarTodos();
     }

salida:

   // ======= Compruebe los puestos que se cierran el fin de semana en =======
   // Tiempo restante hasta el fin de semana : 3d 03:32:27
   // Cerrar todo si el tiempo restante es 02:30:00 o menos.

Fin de Semana - Zona Horaria del Broker y Horario DST

El mercado Forex abre el domingo a las 17:00 hora de Nueva York (GMT-5 en invierno y GMT-4 en verano) y cierra el viernes a la misma hora. La hora de apertura en NYC corresponde al dom, 10:00 PM UTC en invierno (y al dom, 09:00 PM UTC en verano). El mercado de divisas cierra el viernes a las 22:00 UTC en invierno (y a las 21:00 UTC en verano). El mercado al contado del oro y la plata suele comenzar una hora más tarde. enlace

Cada corredor de divisas tiene su zona horaria y la hora de su servidor. Por lo tanto, el inicio de la semana de negociación (velas H1) es variable entre los brokers, y puede variar desde elDom, 02:00 PM hora del servidor para brokers en San Francisco (GMT-8), hastael Lun, 09:00 AM hora del servidor para brokers en Sydney (GMT+11). El final de la semana de negociación también varía desde elviernes alas 14:00, horadel servidor, hastael sábado a las 09:00, hora del servidor.

Cada broker es libre de elegir su horario de verano (DST). Y el DST no es necesariamente el mismo para esa zona horaria. A veces lo mezclan usando una zona horaria de la UE y un DST de EE.UU. en lugar del DST de la UE. Para los corredores que no siguen el horario de EE.UU., la hora del servidor para el inicio (y fin) de semana varía en +/- una hora para el mismo corredor a lo largo del año . El método ForexCloseTime() maneja estas variaciones inter e intra corredor convirtiendo la hora de cierre en NYC en Vie, 17:00 a la hora del corredor, teniendo en cuenta los desfases horarios y el DST, proporcionando así resultados precisos.

El uso de una zona horaria de +2 (y +3 en verano en el horario de EE.UU.) significa, por tanto, que hay cinco velas D1 por semana. No hay velas los sábados y domingos de todo el año. Simplemente, la hora en estos servidores está siempre 7 horas por delante de Nueva York y se representa como NY+7. Con mucho, esta es la configuración más común, pero hay un montón de variaciones menos comunes.

Ejemplo de indicador TestIndi.mq5

iForexSessions - indicador para MetaTrader 5

Destaca las Sesiones del Mercado Forex

Consígalo aquí https://www.mql5.com/es/code/48842

Enlaces

Reloj mundial: https: //www.timeanddate.com/worldclock/

Convertidor de zona horaria: https: //www.timeanddate.com/worldclock/converter-classic.html

Actualizaciones:

2024.03.01 - v.1.40 : Eliminado código redundante en la clase CTimeZoneInfo (utilizada durante las pruebas), añadidos más métodos a la clase CSessionHours, actualizado TestIndi.mq5 para reflejar los nuevos cambios.

2024.03.03 - v.1.45 : Actualizado el código de ejemplo para "Trabajar con horas de sesión local - Clase CTimeZoneInfo".

2024.03.08 - v.1.50 : Añadidos dos métodos internos HistoryBrokerOffset y FirstBarOfWeek a la clase CTimeZoneInfo. Manejo de la hora del servidor en el pasado (desplazamiento UTC, formato de texto, conversiones, etc.).

2024.03.15 - v.1.56 : Añadido script "SydneySession_Script.mq5" para mostrar cómo fluctúan las horas de sesión en Sydney a lo largo del año.

2024.03.30 - v.1.65 : Corregido el offset GMT del broker. Actualmente, la librería escanea barras H1 sólo en el gráfico GOLD ya que tiene las horas de inicio más precisas en todos los brokers que he probado.

2024.04.01 - v.1.67 : Corregido un posible problema en el cálculo del offset GMT del broker durante la primera hora de la semana de negociación.

2024.04.03 - v.1.70 : Almacenamiento en caché de las desviaciones GMT del corredor en un mapa hash para una recuperación más rápida (por ejemplo, desde los indicadores). La caché de offset de broker contendrá una entrada por semana de negociación.

2024.04.08 - v.1.72 : Mejorado el rendimiento de la biblioteca por lo menos 2-3 veces. Ahora se utiliza StructToTime en lugar de StringToTime dentro del método GetNthSunday.

2024.04.09 - v.1.75 : Corregido problema potencial en el cálculo del offset GMT del broker durante las vacaciones de Navidad en brokers GMT+0.

2024.04.11 - v.1.77 : Aceleración del método GetDaylightSwitchTimes. Ahora utiliza una matriz estática para memorizar las horas de cambio para el año en curso.

2024.04.12 - v.1.80 : Corregido problema en el cálculo del offset GMT del broker en brokers que no ofrecen trading en oro.

2024.04.15 - v.1.82 : Añadido el método SetCustomTimeZone a la clase CTimeZoneInfo, que puede utilizar para configurar la zona horaria personalizada incorporada con un nombre especificado, desplazamiento GMT e identificador DST. Se puede acceder a la zona horaria personalizada a través de ZONE_ID_CUSTOM.

2024.04.16 - v.1.85 : Sustituido el método interno GetNthSunday por el método más optimizado GetMonthTime.

2024.04.17 - v.1.87 : Sustituido el método interno TimeYear por el método más optimizado GetYear.

2024.04.18 - v.1.88 : Añadido el método interno CreateDateTime para construir valores datetime a partir de componentes de fecha (año, mes y día). Esto es 100-120 veces más rápido que llamar a la función StructToTime.