TypeToBytes - librería para MetaTrader 5

// MQL4&5-code

#property strict

#include <TypeToBytes.mqh>

#define PRINT(A) ::Print(#A + " = " + (string)A);

void OnStart( void )
{
  MqlTick Tick;
  ::SymbolInfoTick(::Symbol(), Tick);

  MqlTick CloneTick = Tick;

// Operación con estructuras
  if (_R(Tick) == CloneTick)             // Ahora las estructuras se pueden comparar
    ::Print("Equal");

// Obtener el valor del tipo requerido por desplazamiento
  PRINT(_R(Tick)[(datetime)0])           // Vemos el valor datetime por el desplazamiento cero en el objeto de estructura MqlTick - Tick.time

// Obtener el desplazamiento del campo de la estructura
  const int Offset = _OFFSET(Tick, bid); // Hemos localizado el desplazamiento en bytes del campo bid en el objeto de estructura MqlTick

  PRINT(Tick.bid)                        // Hemos comprobado el valor de Tick.bid
  _W(Tick)[Offset] = 1.23456;            // Escrito el valor (double)1.23456según el desplazamiento encontrado

  PRINT(Tick.bid)                        // Hemos comprobado que Tick.bid ahora es igual a 1.23456

  PRINT(_R(Tick)[(double)Offset])        // Imprimido el valor double, que se encuentra en el desplazamiento Offset, es la base de Tick.bid

  PRINT(_R(Tick).Bytes[8])               // Comprobado el valor del byte con el desplazamiento 8 en el objeto de la estructura MqlTick
  PRINT(_R(Tick)[(uchar)8])              // Lo mismo, pero con otro método

  PRINT(CloneTick.bid)                   // Comprobado el valor CloneTick.bid
  _W(CloneTick)[0] = Tick;               // Escrito en CloneTick el valor del objeto de estructura Tick según el desplazamiento cero
  PRINT(CloneTick.bid)                   // Comprobamos que CloneTick.bid == Tick.bid

// Operación con tipos estándar
  color Color = C'241,248,255';

  PRINT(_R(Color)[(uchar)1])             // Componente Green del color 248

  _W(Color)[2] = (uchar)230;             // Escribimos el valor (uchar)230 según el 2 desplazamiento.
  PRINT(Color)                           // Comprobamos que Color ahora es C'241,248,230'

// Operación simultánea con tipos mixtos
  if (_R(Tick) != Color)                 // Se pueden incluso comparar las estructuras con los tipos estándar
    ::Print("Not equal");

// Operador de asignación de byte a byte
  int i = 0;
  _W(i) = (float)12.34;                  // Escribimos en la viariable int- la presentación byte a byte del número (float)12.34
  PRINT(i)                               // Comprobamos que es 1095069860

  float f = 0;
  _W(f) = i;                             // Escribimos en la viariable float- la presentación byte a byte del número obtenido anteriormente (int)1095069860
  PRINT(f)                               // Comprobamos que ahora el valor es igual al original - (float)12.34

  return;
}