EventChartCustom

bool  EventChartCustom(
   long    chart_id,            // olayın alındığı çizelgenin tanımlayıcısı
   ushort  custom_event_id,     // olay tanımlayıcı
   long    lparam,              // long tipli parametre
   double  dparam,              // double tipli parametre
   string  sparam               // string tipli olay parametresi
   );

//+------------------------------------------------------------------+
//|                                            ButtonClickExpert.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "2009, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
string buttonID="Button";
string labelID="Info";
int broadcastEventID=5000;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Özel olaylar göndermek için bir düğme oluştur
   ObjectCreate(0,buttonID,OBJ_BUTTON,0,100,100);
   ObjectSetInteger(0,buttonID,OBJPROP_COLOR,clrWhite);
   ObjectSetInteger(0,buttonID,OBJPROP_BGCOLOR,clrGray);
   ObjectSetInteger(0,buttonID,OBJPROP_XDISTANCE,100);
   ObjectSetInteger(0,buttonID,OBJPROP_YDISTANCE,100);
   ObjectSetInteger(0,buttonID,OBJPROP_XSIZE,200);
   ObjectSetInteger(0,buttonID,OBJPROP_YSIZE,50);
   ObjectSetString(0,buttonID,OBJPROP_FONT,"Arial");
   ObjectSetString(0,buttonID,OBJPROP_TEXT,"Button");
   ObjectSetInteger(0,buttonID,OBJPROP_FONTSIZE,10);
   ObjectSetInteger(0,buttonID,OBJPROP_SELECTABLE,0);
 
//--- Bilgiyi görüntülemek için bir etiket oluştur
   ObjectCreate(0,labelID,OBJ_LABEL,0,100,100);
   ObjectSetInteger(0,labelID,OBJPROP_COLOR,clrRed);
   ObjectSetInteger(0,labelID,OBJPROP_XDISTANCE,100);
   ObjectSetInteger(0,labelID,OBJPROP_YDISTANCE,50);
   ObjectSetString(0,labelID,OBJPROP_FONT,"Trebuchet MS");
   ObjectSetString(0,labelID,OBJPROP_TEXT,"No information");
   ObjectSetInteger(0,labelID,OBJPROP_FONTSIZE,20);
   ObjectSetInteger(0,labelID,OBJPROP_SELECTABLE,0);
 
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   ObjectDelete(0,buttonID);
   ObjectDelete(0,labelID);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
 
  }
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
//--- Fareyi tıklayarak olayı kontrol et
   if(id==CHARTEVENT_OBJECT_CLICK)
     {
      string clickedChartObject=sparam;
      //--- buttonID isimli nesneye tıkladıysan
      if(clickedChartObject==buttonID)
        {
         //--- Düğme durumu - basılı veya serbest
         bool selected=ObjectGetInteger(0,buttonID,OBJPROP_STATE);
         //--- bir hata düzeltme mesajını günlüğe yaz
         Print("Düğmeye basıldı = ",selected);
         int customEventID; // Gönderilecek özel olayların sayısı
         string message;    // Olay ile gönderilecek mesaj
         //--- Eğer düğmeye basılmışsa
         if(selected)
           {
            message="Düğmeye basıldı";
            customEventID=CHARTEVENT_CUSTOM+1;
           }
         else // Düğmeye basılmamışsa
           {
            message="Düğmeye basıldı";
            customEventID=CHARTEVENT_CUSTOM+999;
           }
         //--- "our" isimli bir özel olay gönder
         EventChartCustom(0,customEventID-CHARTEVENT_CUSTOM,0,0,message);
         ///--- tüm açık çizelgelere bir mesaj gönder
         BroadcastEvent(ChartID(),0,"Broadcast Message");
         //--- Hata ayıklama mesajı
         Print("Bir olay gönderildi, ID = ",customEventID);
        }
      ChartRedraw();// Tüm çizelge nesnelerinin yeniden çizilmeye zorlanması
     }
 
//--- Olayın özel bir olay olup olmadığını kontrol et
   if(id>CHARTEVENT_CUSTOM)
     {
      if(id==broadcastEventID)
        {
         Print("Bir çizelgeden yayınlanan bir mesaj alındı, id = "+lparam);
        }
      else
        {
         //--- Olaydaki metin mesajını okuruz
         string info=sparam;
         Print("Kullanıcı olayını işle, ID = ",id);
         //--- Bir etiket içerisinde mesajı görüntüle
         ObjectSetString(0,labelID,OBJPROP_TEXT,sparam);
         ChartRedraw();// Tüm çizelge nesnelerinin yeniden çizilmeye zorlanması
        }
     }
  }
//+------------------------------------------------------------------+
//| tüm açık çizelgelere yayın olayı gönderir                        |
//+------------------------------------------------------------------+
void BroadcastEvent(long lparam,double dparam,string sparam)
  {
   int eventID=broadcastEventID-CHARTEVENT_CUSTOM;
   long currChart=ChartFirst();
   int i=0;
   while(i<CHARTS_MAX)                 // Kesinlikle CHARTS_MAX değerinden daha fazla açık çizelgemiz yok
     {
      EventChartCustom(currChart,eventID,lparam,dparam,sparam);
      currChart=ChartNext(currChart); // Daha öncekilerden yeni bir çizelgemiz var
      if(currChart==-1) break;        // Çizelge listesinin sonuna gelindi
      i++;// Sayacı artırmayı unutma
     }
  }
//+------------------------------------------------------------------+