EventChartCustom

bool  EventChartCustom(
   long    chart_id,            // 이벤트 수신 차트의 식별자
   ushort  custom_event_id,     // 이벤트 식별자
   long    lparam,              // long 유형의 매개변수
   double  dparam,              // double 유형의 매개변수
   string  sparam               // 이벤트의 string 매개변수
   );

//+------------------------------------------------------------------+
//|                                            ButtonClickExpert.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "2009, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
string buttonID="Button";
string labelID="Info";
int broadcastEventID=5000;
//+------------------------------------------------------------------+
//| 엑스퍼트 초기화 함수                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- 사용자 지정 이벤트를 전송하기 위한 버튼 생성
   ObjectCreate(0,buttonID,OBJ_BUTTON,0,100,100);
   ObjectSetInteger(0,buttonID,OBJPROP_COLOR,clrWhite);
   ObjectSetInteger(0,buttonID,OBJPROP_BGCOLOR,clrGray);
   ObjectSetInteger(0,buttonID,OBJPROP_XDISTANCE,100);
   ObjectSetInteger(0,buttonID,OBJPROP_YDISTANCE,100);
   ObjectSetInteger(0,buttonID,OBJPROP_XSIZE,200);
   ObjectSetInteger(0,buttonID,OBJPROP_YSIZE,50);
   ObjectSetString(0,buttonID,OBJPROP_FONT,"Arial");
   ObjectSetString(0,buttonID,OBJPROP_TEXT,"Button");
   ObjectSetInteger(0,buttonID,OBJPROP_FONTSIZE,10);
   ObjectSetInteger(0,buttonID,OBJPROP_SELECTABLE,0);
 
//--- 정보 표시를 위한 레이블 생성
   ObjectCreate(0,labelID,OBJ_LABEL,0,100,100);
   ObjectSetInteger(0,labelID,OBJPROP_COLOR,clrRed);
   ObjectSetInteger(0,labelID,OBJPROP_XDISTANCE,100);
   ObjectSetInteger(0,labelID,OBJPROP_YDISTANCE,50);
   ObjectSetString(0,labelID,OBJPROP_FONT,"Trebuchet MS");
   ObjectSetString(0,labelID,OBJPROP_TEXT,"No information");
   ObjectSetInteger(0,labelID,OBJPROP_FONTSIZE,20);
   ObjectSetInteger(0,labelID,OBJPROP_SELECTABLE,0);
 
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| 엑스퍼트 초기화 해제 함수                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   ObjectDelete(0,buttonID);
   ObjectDelete(0,labelID);
  }
//+------------------------------------------------------------------+
//| 엑스퍼트 틱 함수                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
 
  }
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
//--- 마우스 버튼을 눌러 이벤트를 확인
   if(id==CHARTEVENT_OBJECT_CLICK)
     {
      string clickedChartObject=sparam;
      //--- 이름이 buttonID인 개체를 클릭하는 경우
      if(clickedChartObject==buttonID)
        {
         //--- 버튼 상태 - 누르거나 누르지 않음
         bool selected=ObjectGetInteger(0,buttonID,OBJPROP_STATE);
         //--- 디버그 메시지를 기록
         Print("버튼 눌림 = ",selected);
         int customEventID; // 전송할 사용자 지정 이벤트 수
         string message;    // 이벤트에 전송될 메시지
         //--- 버튼이 눌린 경우
         if(selected)
           {
            message="Button pressed";
            customEventID=CHARTEVENT_CUSTOM+1;
           }
         else // 버튼이 눌리지 않음
           {
            message="Button in not pressed";
            customEventID=CHARTEVENT_CUSTOM+999;
           }
         //--- 사용자 지정 이벤트 "당사" 차트 전송
         EventChartCustom(0,customEventID-CHARTEVENT_CUSTOM,0,0,message);
         ///--- 열려 있는 모든 차트에 메시지 전송
         BroadcastEvent(ChartID(),0,"Broadcast Message");
         //--- 디버그 메시지
         Print("ID를 사용하여 이벤트 전송 = ",customEventID);
        }
      ChartRedraw();// 모든 차트 개체를 강제로 다시 그리기
     }
 
//--- 이벤트가 사용자 이벤트세 속하는지 확인
   if(id>CHARTEVENT_CUSTOM)
     {
      if(id==broadcastEventID)
        {
         Print("Got broadcast message from a chart with id = "+lparam);
        }
      else
        {
         //--- 이벤트에서 문자 메시지를 읽었습니다
         string info=sparam;
         Print("ID로 사용자 이벤트 처리 = ",id);
         //--- 레이블에 메시지 표시
         ObjectSetString(0,labelID,OBJPROP_TEXT,sparam);
         ChartRedraw();// 모든 차트 개체를 강제로 다시 그리기
        }
     }
  }
//+------------------------------------------------------------------+
//| 열린 모든 차트에 브로드캐스트 이벤트 전송                         |
//+------------------------------------------------------------------+
void BroadcastEvent(long lparam,double dparam,string sparam)
  {
   int eventID=broadcastEventID-CHARTEVENT_CUSTOM;
   long currChart=ChartFirst();
   int i=0;
   while(i<CHARTS_MAX)                 // CHARTS_MAX 오픈 차트 밖에 없습니다
     {
      EventChartCustom(currChart,eventID,lparam,dparam,sparam);
      currChart=ChartNext(currChart); // 이전 차트로부터 새 차트를 받았습니다
      if(currChart==-1) break;        // 차트 목록의 끝에 도달함
      i++;// 카운터를 늘리는 것을 잊지 마십시오
     }
  }
//+------------------------------------------------------------------+