От новичка до эксперта: Мониторинг бэкэнд операций с использованием MQL5

MetaTrader 5 — Примеры | 3 ноября 2025, 09:20

336

Clemence Benjamin

Содержание обсуждения:

Введение

Успешная компиляция торгового инструмента в MetaEditor 5 - важная веха, но это только начало. Компиляция подтверждает, что код синтаксически корректен, но не гарантирует производительность, стабильность или корректность. Настоящее тестирование начинается, когда мы запускаем систему в MetaTrader 5, будь то на реальной платформе или в тестере стратегий, чтобы увидеть, как теория воплощается в практику.

На данном этапе разработчики сталкиваются с общей проблемой: несмотря на то, что мы написали логику, мы не всегда знаем, как советник будет вести себя в реальных условиях. Программа выполняет каждое правило механически, иногда приводя к результатам, которых мы не ожидали. Чтобы усовершенствовать и оптимизировать наши системы, нам нужно нечто большее, чем просто результаты — нам нужна наглядная информация о внутренней работе советника, о том, что происходит, когда это происходит и откуда в коде это берет начало.

Возможности встроенного ведения лога и наше решение

MetaTrader 5 предоставляет два основных инструмента для мониторинга активности:

Вкладка "Experts", на которой отображаются логи, сгенерированные всеми запущенными советниками и индикаторами.
Вкладка «Journal», в которой записываются события терминала и сервера.

Несмотря на то, что они полезны, у них есть важное ограничение: во всех советниках используется одна и та же вкладка "Experts". Несмотря на то, что в строках лога указано название советника, выходные данные нескольких систем быстро смешиваются, создавая беспорядок и неразбериху. Когда активны несколько советников, становится трудно выделить логи для одного конкретного инструмента, что замедляет отладку и снижает уверенность в результатах.

Ниже приведены примеры записей в логе советника для трех различных программ, перечисленных в одной и той же последовательности.

2025.09.21 08:10:42.006 BEODemoEA (EURAUD,H4)   Abnormal termination
2025.09.21 08:20:15.056 Correlation Matrix 3D (EURAUD,M5)       Symbol 'EURUSD' is not synchronized
2025.09.21 08:20:40.862 Correlation Matrix 3D (EURAUD,M5)       Symbol 'EURGBP' is not synchronized
2025.09.21 08:20:44.065 Correlation Matrix 3D (EURAUD,M5)       Symbol 'EURCHF' is not synchronized
2025.09.21 08:20:44.067 Correlation Matrix 3D (EURAUD,M5)       Symbol 'EURJPY' is not synchronized
2025.09.21 08:20:44.078 Correlation Matrix 3D (EURAUD,M5)       Symbol 'GBPUSD' is not synchronized
2025.09.21 08:20:44.080 Correlation Matrix 3D (EURAUD,M5)       Symbol 'GBPCHF' is not synchronized
2025.09.21 08:20:44.082 Correlation Matrix 3D (EURAUD,M5)       Symbol 'GBPJPY' is not synchronized
2025.09.21 08:20:44.095 Correlation Matrix 3D (EURAUD,M5)       Symbol 'USDCHF' is not synchronized
2025.09.21 08:20:44.112 Correlation Matrix 3D (EURAUD,M5)       Symbol 'USDJPY' is not synchronized
2025.09.21 08:20:44.114 Correlation Matrix 3D (EURAUD,M5)       Symbol 'CHFJPY' is not synchronized
2025.09.21 08:20:44.114 Correlation Matrix 3D (EURAUD,M5)       Try again #0
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       Some symbols not ready to use:
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       EURUSD 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       EURGBP 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       EURCHF 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       EURJPY 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       GBPUSD 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       GBPCHF 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       GBPJPY 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       USDCHF 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       USDJPY 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       CHFJPY 
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       Error. Symbols not synchronized.
2025.09.21 08:20:44.125 Correlation Matrix 3D (EURAUD,M5)       Error. Rates data is not loaded.
2025.09.21 09:00:00.112 Institutional Trading Zones (EURAUD,M5) indicator | EURAUD,5 | Session Alert: Sydney End at 2025.09.21 07:00
2025.09.21 10:00:00.177 Institutional Trading Zones (EURAUD,M5) indicator | EURAUD,5 | Session Alert: London Start at 2025.09.21 08:00
2025.09.21 10:05:00.172 Institutional Trading Zones (EURAUD,M5) indicator | EURAUD,5 | Bearish overlap, look to sell

Именно здесь начинается наше обсуждение класса внутренних операций (Backend Operations, BEO). Вместо того чтобы полагаться исключительно на общую вкладку "Experts", мы можем разработать специальную систему мониторинга и регистрации, которая отображает и систематизирует информацию непосредственно на графике. Создавая класс специально для внутренних операций, разработчики получают;

Чистый интерфейс отладки под конкретный советник.
Отображение показателей производительности и внутренних событий в режиме реального времени.
Упрощается идентификация ошибок, некорректного поведения и потока выполнения.

В сегодняшней статье мы рассмотрим, как создать такой класс, чтобы улучшить наш рабочий процесс отладки и предоставить трейдерам и разработчикам надежный инструмент для понимания того, что происходит на серверной части их советников.

Концептуальное исследование

Реализуемость концепции внутренних операций (BEO) зависит от того, предоставляют ли MetaTrader 5 и MQL5 достаточное количество системных подключений для мониторинга и диагностики внутри советника. К счастью, платформа предоставляет богатый набор функций для доступа к состоянию счета, среде терминала и торговым операциям. Они варьируются от AccountInfo*() и TerminalInfo*() для получения подробной информации о среде до MqlTradeRequest и MqlTradeResult для получения результатов исполнения сделок. Это гарантирует, что любой серверный уровень, который мы создаем, всегда может ссылаться на ту же низкоуровневую информацию, на которую опирается сам терминал, что делает концепцию технически обоснованной.

Еще одним важным фактором является то, как представлены эти детали. MQL5 предлагает несколько каналов вывода: вкладка "Experts" для логов советников, вкладка "Journal" для сообщений терминала и сервера, а также визуализация на основе диаграмм с использованием Comment(), ObjectCreate() или более продвинутых инструментов, таких как CCanvas. Наш пользовательский класс использует их для преобразования торговых результатов, кодов ошибок и диагностических заметок в структурированные выходные данные, позволяя разработчикам отличать внутреннюю работу одного советника от работы другого. Это устраняет ограничение на смешанные журналы на вкладке "Experts", где в противном случае несколько программ могут сливаться в один поток сообщений.

Наконец, возможность интеграции поддерживается функциями обработки ошибок платформы и ведения лога. С помощью функции GetLastError() и доступа к истории наш системный уровень может фиксировать как проблемы в реальном времени, так и контекст прошлых сделок, а затем отображать или регистрировать их удобным для разработчиков способом. Организовав для этого специальный бэкенд-класс, мы доказываем, что идея выполнима, а также открываем возможности для последовательной отладки, упрощения обновлений и прозрачного мониторинга торговых систем в MetaTrader 5.

В следующем разделе нашего обсуждения мы продолжим развивать эту идею, шаг за шагом изучая ее реализацию. Мы подробно рассмотрим код класса внутренних операций (BEO), подчеркнув, как он собирает, упорядочивает и отображает важную отладочную информацию. Как только основа будет ясна, мы приступим к тестированию на графике, где система будет отображать обратную связь в режиме реального времени непосредственно на торговом графике.

Наконец, мы поделимся полным решением, чтобы разработчики и трейдеры могли интегрировать его в собственные рабочие процессы, сокращая разрыв между теорией, кодом и практическим исполнением.

Реализация и код

Переход к серверным операциям начинается со структурированного подхода, который обеспечивает баланс между ясностью и эффективностью. Разработав специальный класс мониторинга CBEOMonitor, мы можем отделить ответственность за отслеживание и отображение диагностических данных от самой торговой логики. Это упрощает отладку и создает многоразовый блок разработки, который можно интегрировать в любой советник, не переписывая одни и те же процедуры снова и снова. Концепция здесь заключается в модульности — выделении одной мощной единицы кода для обслуживания множества различных систем.

Чтобы воплотить эту концепцию в жизнь, я реализовал ее в два продуманных этапа. Во-первых, сам класс был создан со всеми основными механизмами для записи событий, форматирования информации и её аккуратного отображения на графике. Затем интеграция в демонстрационный советник показала, насколько легко такой класс может быть интегрирован в реальную торговую среду. Эта двухэтапная разработка подчеркивает эффективность: один хорошо разработанный инструмент может масштабироваться во все более сложные системы. Теперь, когда основа заложена, пришло время открыть код и посмотреть, как каждый элемент работает на практике.

Шаг 1: Класс CBEOMonitor

Включает в себя — от чего зависит мониторинг и почему

Этот класс мониторинга создан поверх примитивов пользовательского интерфейса MQL5 и стандартных контейнеров. Строки #include отображают Canvas для рендеринга растровых меток, List для небольшого кольцевого буфера сообщений в памяти, Object.mqh и ChartObject.mqh для констант и помощников объектов графика, а также Trade.mqh, где связанные с торговлей помощники используются помощниками монитора для ведения лога. enums определяют уровни серьезности сообщений и режим отображения; они используются повсеместно для фильтрации, раскрашивания и выбора количества строк для отображения. Использование небольших эксплицитных перечислений позволяет легко читать API и избегать использования магических чисел в коде советника.

#include <Object.mqh>
#include <Canvas\Canvas.mqh>
#include <Arrays\List.mqh>
#include <Trade\Trade.mqh>
#include <ChartObjects\ChartObject.mqh>

// enums
enum BEO_Level { BEO_L_INFO=0, BEO_L_SUCCESS, BEO_L_WARNING, BEO_L_ERROR, BEO_L_TRADE, BEO_L_DEBUG };
enum BEO_DisplayMode { BEO_DM_COMPACT=0, BEO_DM_EXPANDED };

BEO_Item—единица регистрируемой информации

Каждая запись в логе представлена классом BEO_Item. В нем хранится удобочитаемый текст, уровень серьезности, временная метка datetime и метка с микросекундным разрешением для показателей perf, а также необязательная метка источника (откуда в советнике пришло сообщение). Хранение сообщений в виде объектов позволяет использовать циклический буфер фиксированной емкости (через CList), упрощая при этом управление памятью. Эта небольшая структура является компоновочным блоком для предаставления и распечатки журнала экспертов.

class BEO_Item : public CObject
{
public:
   string    text;
   BEO_Level level;
   datetime  time;
   ulong     micro;
   string    origin;

   BEO_Item() { text=""; level=BEO_L_INFO; time=0; micro=0; origin=""; }
   BEO_Item(string _text, BEO_Level _lvl, datetime _t, ulong _m, string _orig = "")
     { text=_text; level=_lvl; time=_t; micro=_m; origin=_orig; }
   void CopyFrom(const BEO_Item &src)
     { text=src.text; level=src.level; time=src.time; micro=src.micro; origin=src.origin; }
};

Состояние основы монитора и цветовая схема — зачем нужны непрозрачные цвета и сплошной текст?

Монитор поддерживает собственные CCanvas плюс счетчики геометрии, видимости, буфера и производительности. Я решил сохранить основной текст полностью непрозрачным (сплошным белым) и использовал четкие, непрозрачные технические цвета для заголовков, выделения, сообщений об успехе, предупреждениях и ошибках. Цель: предсказуемая разборчивость на любом фоне графика и согласованное отображение значений (например, m_error = red). Эти цвета сохраняются как цветовые элементы и применяются при рисовании линий. Сохранение имени шрифта и фиксированного значения m_font_size защищает от передачи неподдерживаемых значений в CCanvas::FontSizeSet() — вот почему мы вычисляем безопасное значение CanvasFontSizeValue() перед вызовом Canvas API.

// color and font members (excerpt)
color m_text;       // solid white
color m_caption;    // header/caption color
color m_error;      // error messages
string m_font;
int    m_font_size;
int    m_transparent; // canvas transparency 0..255
// CanvasFontSizeValue() clamps m_font_size into safe range used by CCanvas::FontSizeSet

Create/Recreate/Destroy—жизненный цикл с непосредственным видимым заполнителем

При создании холста сразу же отображается небольшой заполнитель ("Инициализация движка BEO..."), так что пользователи получают мгновенную визуальную обратную связь при подключении советника — это ценно для устранения проблем с созданием вложений. CreateBitmapLabel() используется для создания растрового объекта диаграммы, затем FontNameSet()/FontSizeSet()/TransparentLevelSet() настраивает рендеринг. Функция RecreateCanvas() безопасно уничтожает и воссоздает холст при изменении положения или размера. Функция Destroy() очищает как холст, так и буфер сообщений в памяти; она также удаляет все резервные метки, оставшиеся после предыдущих сбоев. Эти шаги отражают эффективные принципы управления ресурсами, изложенные в документах MQL5 (при необходимости создают/обновляют/уничтожают объекты диаграммы и ресурсы canvas, исключают утечки).

bool CBEOMonitor::Create(string name,int x,int y,int w,int h)
{
   m_res_name = StringFormat("BEOMON_%s", name);
   if(!m_canvas.CreateBitmapLabel(m_res_name, x, y, w, h, COLOR_FORMAT_ARGB_RAW)) return(false);
   m_canvas.FontNameSet(m_font);
   m_canvas.FontSizeSet(CanvasFontSizeValue());                     // safe/clamped
   m_canvas.TransparentLevelSet((uchar)MathMax(0, MathMin(255, m_transparent)));
   // placeholder UI so chart shows something immediately
   m_canvas.Erase(m_bg);
   m_canvas.FillRectangle(2,2,w-4,24, ARGB(255,44,44,44));
   m_canvas.TextOut(20,7,"BEO: " + name, m_caption, ALIGN_RIGHT);
   m_canvas.Update(true);
   return(true);
}

Ведение лога, подгонка буфера и вывод экспертов — отслеживание как на графике, так и в логах

Когда советник вызывает функцию Log(...) (или вспомогательные средства, такие как Info()/Error()), монитор создает BEO_Item, помещает его в буфер CList и отправляет сообщение PrintFormat() в журнал эксперта, чтобы это же сообщение отображалось на стандартной вкладке Expert. Буфер подгоняется до такой емкости, чтобы сохранить объем памяти ограниченным. Этот двойной подход — холст на графике плюс вывод в Experts - обеспечивает как быструю визуальную диагностику, так и постоянную текстовую запись в логе терминала.

void CBEOMonitor::Log(string text,BEO_Level lvl,string origin)
{
   if(lvl==BEO_L_DEBUG && !m_show_debug) return;
   BEO_Item it; it.text=text; it.level=lvl; it.time=TimeCurrent(); it.micro=_nowMicros(); it.origin=origin;
   _pushItem(it);
   PrintFormat("BEO[%s] %s%s", (lvl==BEO_L_INFO?"INFO": "..."), (origin!=""?("["+origin+"] "):""), text);
   Update();
}
void CBEOMonitor::_pushItem(const BEO_Item &it)
{
   BEO_Item *p = new BEO_Item; p.CopyFrom(it); m_buf.Add(p);
   while(m_buf.Total() > m_capacity) { BEO_Item *old=(BEO_Item*)m_buf.GetNodeAtIndex(0); if(old) delete old; m_buf.Delete(0); }
}

Тайминг выполнения — микросекундное разрешение для полезного профилирования

Вызывает OnStartTick() в начале обработки тиков и OnEndTick() в конце; внутренне монитор использует GetMicrosecondCount() (на MQL5) или возвращается к GetTickCount(), умноженному на грубое разрешение. Она сохраняет скользящее среднее значение (m_tick_avg_ms) и счетчик, чтобы на графике было видно, насколько дорогостоящей является обработка тиков. Это быстрое профилирование имеет неоценимое значение при отслеживании регрессий после добавления новых функций — если время тика внезапно увеличивается, монитор немедленно показывает это.

void CBEOMonitor::OnStartTick(void) { m_last_tick_start = _nowMicros(); }
void CBEOMonitor::OnEndTick(void)
{
   if(m_last_tick_start==0) return;
   ulong endm=_nowMicros();
   double durms=(double)((endm>m_last_tick_start)?(endm-m_last_tick_start):0)/1000.0;
   m_tick_avg_ms=(m_tick_avg_ms*m_tick_count+durms)/(m_tick_count+1);
   m_tick_count++;
   m_last_tick_start=0;
   Update();
}
ulong CBEOMonitor::_nowMicros(void) const { #ifdef __MQL5__ return (ulong)GetMicrosecondCount(); #else return (ulong)GetTickCount()*1000; #endif }

Отрисовка и обрезка — удобочитаемый, выровненный по правому краю вывод, который не будет переполняться

Функция draw() создает холст: границу, подпись, строку perf, резюме по серверной части советника и строки последних сообщений. Каждая текстовая строка обрезается с помощью функции _clipLineToWidth() (которая использует m_canvas.TextWidth() для измерения пикселей), чтобы исключить переполнение или невидимость текста. Все вызовы TextOut() используют ALIGN_RIGHT в соответствии с запросом, а цвет основного текста - сплошной белый, в то время как подписи и выделения используются в специальных непрозрачных цветах. После рендеринга m_canvas.Update(true) удаляет растровое изображение с диаграммы, а BringToFrontInternal() восстанавливает свойства объекта диаграммы, чтобы canvas оставался видимым над другими объектами. Такой подход обеспечивает согласованность и удобочитаемость диагностики на графике при различных размерах и разрешении графиков.

void CBEOMonitor::_draw(void)
{
   if(!m_canvas_created) return;
   m_canvas.Erase(m_bg);
   m_canvas.Rectangle(1,1,m_w-2,m_h-2,m_border);
   m_canvas.FillRectangle(2,2,m_w-4,22, ARGB(255,44,44,44));
   m_canvas.TextOut(20,6,"BEO: " + m_name, m_caption, ALIGN_RIGHT);
   // perf
   int y=28;
   string perf = StringFormat("TickAvg: %.2f ms | Ticks: %d | Mem: %d KB", m_tick_avg_ms, (int)m_tick_count, (int)m_mem_kb);
   m_canvas.TextOut(20,y, _clipLineToWidth(perf, MathMax(20,m_w-40)), m_text, ALIGN_RIGHT);
   y += 18;
   // messages (most recent first)
   for(int i=m_buf.Total()-1; i>=0 && drawn<max_lines; i--)
   {
      BEO_Item *it=_getItemAt(i);
      string line = _clipLineToWidth(TimeToString(it.time,TIME_MINUTES|TIME_SECONDS) + " " + it.text, avail_px);
      m_canvas.TextOut(20,y,line,_colorFor(it.level),ALIGN_RIGHT);
      y+=14;
      drawn++;
   }
   m_canvas.Update(true);
   BringToFrontInternal();
}

Шаг 2: Пример интеграции CBEOMonitor в пользовательский демонстрационный советник

Заголовок советника и Includes

В самом верху советника мы разместили все основные библиотеки, которые необходимы как для совершения сделок, так и для визуализации на графике. Сюда относятся Trade.mqh для управления всеми торговыми операциями, Controls\Button.mqh для создания интерактивных кнопок графика и BEOMonitor.mqh, который предоставляет надежную систему мониторинга со структурированным протоколированием и диагностикой.

Сразу после этого мы объявляем входные данные, чтобы любой, кто подключит советник, мог настроить его поведение, не меняя код. Входные данные - это заданные разработчиком значения по умолчанию, которые советник считывает в OnInit(); они не меняют логику кода. Сохраняйте четкость имен и разумность значений по умолчанию. При использовании пиксельных/позиционных входных данных (MonitorW/MonitorH) помните, что советник передаст их в beo.Create(...) во время выполнения, а монитор будет использовать их для создания объекта canvas.

#include <Trade\Trade.mqh>
#include <Controls\Button.mqh>
#include <BEOMonitor.mqh>

input string   DemoEAName        = "BEO Demo EA";
input bool     EnableMonitor     = true;
input int      MonitorX          = 10;
input int      MonitorY          = 60;
input int      MonitorW          = 400;
input int      MonitorH          = 220;
input bool     ShowDebugMessages = false;
input int      UpdateIntervalSec = 1;
input bool     AllowTrading      = false;
input double   DemoLotSize       = 0.01;
input double   DemoTakeProfit    = 30;
input double   DemoStopLoss      = 30;

Глобальные объекты и помощники

Определяем глобальные экземпляры для торговли (CTrade), мониторинга (CBEOMonitor) и наших интерактивных кнопок (CButton). Эти объекты будут управлять собственным жизненным циклом, но на них будут ссылки во всем советнике. Мы также вводим вспомогательные функции для создания резервных меток. Эти метки действуют как защитный механизм на случай, если холст монитора не удастся инициализировать. Они обеспечивают мгновенную обратную связь на графике, так что мы знаем, что система работает, даже если графический монитор не может быть отображен.

CTrade      trade;
CBEOMonitor beo;

CButton      m_buyButton;
CButton      m_sellButton;

static double g_prevBid = 0.0;
static double g_prevAsk = 0.0;
static datetime g_lastLogTime = 0;

string MakeFallbackName(const string base) { return ("BEO_FALLBACK_" + base); }

Функции резервных меток (CreateFallbackLabel, UpdateFallbackLabel, RemoveFallbackLabel) позволяют ему динамически отображать или обновлять сообщения на графике, не прерывая работу советника. Они обеспечивают видимость состояния советника, такого как “инициализация” или “сбой canvas”, что неоценимо при тестировании и отладке.

Диагностика графика

Чтобы облегчить мониторинг, мы реализуем диагностическую функцию PrintChartObjects(). Эта функция выполняет перебор по всем объектам диаграммы и выводит их свойства, включая название, тип, угол, положение и видимость. Это важно для устранения конфликтов ресурсов или проверки корректности создания BEO canvas. Она отражает наш принцип прозрачности: знание того, что есть на графике, предотвращает неожиданные изменения во время выполнения и повышает воспроизводимость тестов.

void PrintChartObjects()
{
   int total = ObjectsTotal(0);
   PrintFormat("BEO Diagnostic: ObjectsTotal = %d", total);
   for(int i=0;i<total;i++)
   {
      string nm = ObjectName(0,i);
      long type   = ObjectGetInteger(0,nm,OBJPROP_TYPE);
      long corner = ObjectGetInteger(0,nm,OBJPROP_CORNER);
      long xdist  = ObjectGetInteger(0,nm,OBJPROP_XDISTANCE);
      long ydist  = ObjectGetInteger(0,nm,OBJPROP_YDISTANCE);
      bool hidden = (ObjectGetInteger(0,nm,OBJPROP_HIDDEN) != 0);
      PrintFormat("  [%d] name='%s' type=%d corner=%d x=%d y=%d hidden=%d",
                  i, nm, (int)type, (int)corner, (int)xdist, (int)ydist, hidden ? 1 : 0);
   }
}

Инициализация (OnInit)

В функции OnInit мы выполняем структурированную настройку как для монитора, так и для кнопок быстрых ордеров. Если мониторинг включен, программа попытается создать CBEOMonitor canvas. Затем проверяет его создание и, в случае успешного выполнения, включает отладку и регистрирует сообщение о запуске. Если создание холста завершится неудачей, резервная метка гарантирует, что она по-прежнему имеет обратную связь на графике.

Советник также фиксирует начальные цены bid и ask, используя их в качестве базовой линии для отслеживания последующих изменений на рынке. Используя эти данные, он создает кнопки быстрых ордеров, которые позволяют моделировать или исполнять сделки вручную. Этот механизм обеспечивает практичный способ проверки торговой логики в интерактивном режиме, вместо того чтобы полагаться исключительно на автоматические триггеры. Чтобы обеспечить актуальность отображения результатов мониторинга, советник также устанавливает таймер, который обновляет холст через регулярные промежутки времени.

int OnInit()
{
   if(EnableMonitor)
   {
      bool created = beo.Create(DemoEAName, MonitorX, MonitorY, MonitorW, MonitorH);
      if(created && beo.IsCanvasCreated())
      {
         beo.EnableDebug(ShowDebugMessages);
         beo.Log("BEO engine initialized...", BEO_L_SUCCESS, "OnInit");
         RemoveFallbackLabel(DemoEAName);
      }
      else
      {
         CreateFallbackLabel(DemoEAName, MonitorX, MonitorY, 12, clrSilver);
      }
   }

   g_prevBid = SymbolInfoDouble(_Symbol, SYMBOL_BID);
   g_prevAsk = SymbolInfoDouble(_Symbol, SYMBOL_ASK);

   if(EnableQuickButtons)
   {
      // Create BUY and SELL buttons...
   }

   EventSetTimer(MathMax(1, UpdateIntervalSec));
   return(INIT_SUCCEEDED);
}

Деинициализация (OnDeinit)

Во время выключения советник полностью уничтожает холст монитора и кнопки быстрого доступа, а также удаляет все резервные метки. Если параметры изменены, он пропускает ненужное ведение лога, чтобы обеспечить бесперебойное обновление. Управляя своими ресурсами таким образом, советник избегает загромождения графика неиспользуемыми объектами или оставления оборванных ссылок. Эта тщательная очистка отражает лучшие практики управления жизненным циклом автоматизированных торговых систем.

void OnDeinit(const int reason)
{
   if(EnableMonitor && reason != REASON_PARAMETERS)
   {
      beo.Log("Shutting down demo EA", BEO_L_INFO, "OnDeinit");
      beo.ClearHistory();
      beo.Destroy();
      RemoveFallbackLabel(DemoEAName);
   }

   m_buyButton.Destroy(reason);
   m_sellButton.Destroy(reason);
   EventKillTimer();
}

Обновления таймера (OnTimer)

Событие OnTimer управляет периодическими обновлениями. Это гарантирует, что холст монитора будет воссоздан, если он отсутствует, обновит резервные метки и обновит изображение на мониторе. Кроме того, он регистрирует частоту сердечных сокращений каждые 30 секунд, что позволяет получить представление о количестве сообщений, работе тиков и работоспособности системы. Этот механизм регулярного обновления делает советник устойчивым к временным проблемам с графиками или ресурсами.

void OnTimer()
{
   if(!EnableMonitor) return;

   if(!beo.IsCanvasCreated())
   {
      static int tries = 0;
      tries++;
      bool ok = beo.Create(DemoEAName, MonitorX, MonitorY, MonitorW, MonitorH);
      if(ok) { /* recovered canvas */ }
      else
      {
         string txt = StringFormat("BEO fallback: msgs=%d | TickAvg=%.3f ms", beo.MessagesCount(), beo.GetTickAvgMs());
         UpdateFallbackLabel(DemoEAName, txt, MonitorX, MonitorY, 11, clrWhite);
      }
   }
   else RemoveFallbackLabel(DemoEAName);

   beo.Update(true);

   if(TimeCurrent() - g_lastLogTime >= 30)
   {
      string summary = StringFormat("Msgs:%d | TickAvg: %.3f ms | LastMicros: %llu",
                                    beo.MessagesCount(), beo.GetTickAvgMs(), beo.GetLastMicros());
      beo.Log("Periodic heartbeat: " + summary, BEO_L_DEBUG, "OnTimer");
      g_lastLogTime = TimeCurrent();
   }
}

Обработка тиков (OnTick)

Функция OnTick - это основная логика реагирования советника. На каждом тике советник обновляет монитор, отслеживает изменения bid и ask и регистрирует соответствующие движения цен. Простая демонстрационная стратегия в советнике фиксирует значительные изменения цен и, когда включена функция AllowTrading, она также позволяет совершать сделки. Разделив свою логику на OnStartTick и OnEndTick, советник сохраняет четкие границы взаимодействия с мониторами, усиливая модульность и улучшая читаемость.

void OnTick()
{
   if(EnableMonitor) beo.OnStartTick();

   double bid = SymbolInfoDouble(_Symbol, SYMBOL_BID);
   double ask = SymbolInfoDouble(_Symbol, SYMBOL_ASK);

   if(EnableMonitor && (bid != g_prevBid || ask != g_prevAsk))
   {
      string txt = StringFormat("Bid: %.*f Ask: %.*f",
                                (int)SymbolInfoInteger(_Symbol,SYMBOL_DIGITS), bid,
                                (int)SymbolInfoInteger(_Symbol,SYMBOL_DIGITS), ask);
      beo.Info(txt, "OnTick");
      g_prevBid = bid; g_prevAsk = ask;
   }

   // Simple demo strategy: log and optionally trade on price movement
}

Кнопки быстрых ордеров

Система обрабатывает взаимодействие с пользователем через OnChartEvent и ExecuteQuickOrder. Нажатие на кнопку запускает либо имитируемую, либо реальную сделку, в зависимости от флага AllowTrading. Это позволяет нам безопасно демонстрировать торговую логику, полностью интегрируя систему мониторинга внутренних операций, которая фиксирует подробные логи и торговые события для проверки.

void OnChartEvent(const int id, const long& lparam, const double& dparam, const string& sparam)
{
   if(id == CHARTEVENT_OBJECT_CLICK)
   {
      if(sparam == "BEO_BUY_BTN") ExecuteQuickOrder(ORDER_TYPE_BUY);
      else if(sparam == "BEO_SELL_BTN") ExecuteQuickOrder(ORDER_TYPE_SELL);
   }
}

void ExecuteQuickOrder(ENUM_ORDER_TYPE orderType)
{
   if(!AllowTrading) { /* simulate */ return; }

   MqlTradeRequest req; MqlTradeResult res;
   ZeroMemory(req); ZeroMemory(res);

   if(orderType == ORDER_TYPE_BUY) { /* set buy parameters */ }
   else { /* set sell parameters */ }

   if(!OrderSend(req, res)) beo.LogErrorDetails(...);
   else beo.LogTradeDetails(res, ..., "QuickButton");
}

Такой подход демонстрирует полную интеграцию CBEOMonitor; каждое крупное действие советника — инициализация, обновление тиков, события таймера, исполнение сделок и взаимодействие с кнопками — выводит структурированные логи, фиксирует данные об эффективности и позволяет отображать резервный вариант в случае сбоя в работе холста монитора. Система является модульной, удобочитаемой и надежной, обеспечивая ясность и удобство обслуживания как для реальной торговли, так и для тестирования.

Тестирование

Для проведения тестирования в терминале как советник, так и заголовочный файл, содержащий класс BEOMonitor, должны быть успешно скомпилированы без ошибок. BEODemoEA будет доступна для использования в разделе "Experts" в навигаторе терминала MetaTrader 5. Просто перетащите её на нужный график и позвольте инициализироваться с настройками по умолчанию. После инициализации система автоматически создаст холст монитора, настроит кнопки быстрых ордеров и начнет обработку входящих тиковых данных.

На графике результаты выполнения кода становятся видимыми в режиме реального времени. На полотне будут отображаться обновления bid и ask в соответствии с поступающими тиками, в то время как сообщения об инициализации подтверждают, что монитор и кнопки успешно созданы. В то же время параллельные логи на вкладке "Experts" предоставляют серверное подтверждение, позволяющее проверить соответствие отображаемой информации внутренним операциям советника. Такая прямая визуализация гарантирует, что тестирование будет не только функциональным, но и интерактивным, позволяя сразу получить представление о поведении системы на основе реальных данных рынка.

BEO testing on EURUSD

Рисунок 1: Использование советника на графике

BEO testing

Рисунок 2: Отображение взаимодействия серверной части с кнопками быстрой торговли для моделирования торговли

Регистрация в журнале эксперта терминала MetaTrader 5:

2025.09.23 12:49:41.142 BEODemoEA (USDCHF,H1)   BEOMonitor: Created canvas resource 'BEOMON_BEO Demo EA' at 10,60 size 600x220
2025.09.23 12:49:41.170 BEODemoEA (USDCHF,H1)   BEO Demo: beo.Create returned true
2025.09.23 12:49:41.170 BEODemoEA (USDCHF,H1)   BEO Demo: beo.IsCanvasCreated() = true
2025.09.23 12:49:41.170 BEODemoEA (USDCHF,H1)   BEO Demo: expected canvas name = 'BEOMON_BEO Demo EA'
2025.09.23 12:49:41.178 BEODemoEA (USDCHF,H1)   BEO Diagnostic: ObjectsTotal = 3
2025.09.23 12:49:41.179 BEODemoEA (USDCHF,H1)     [0] name='BEOMON_BEO Demo EA' type=106 corner=0 x=10 y=60 hidden=0
2025.09.23 12:49:41.179 BEODemoEA (USDCHF,H1)     [1] name='BEO_BUY_BTN' type=103 corner=0 x=10 y=300 hidden=1
2025.09.23 12:49:41.180 BEODemoEA (USDCHF,H1)     [2] name='BEO_SELL_BTN' type=103 corner=0 x=100 y=300 hidden=1
2025.09.23 12:49:41.196 BEODemoEA (USDCHF,H1)   BEO[OK] [OnInit] BEO engine initialized...
2025.09.23 12:49:41.228 BEODemoEA (USDCHF,H1)   BEO[INFO] [OnInit] Quick Order Buttons (CButton) created: BUY/SELL for ops testing
2025.09.23 12:49:59.941 BEODemoEA (USDCHF,H1)   BEO[INFO] [OnTick] Bid: 0.79537 Ask: 0.79551

Приведенные выше диагностические записи подтверждают, что canvas был инициализирован с заданными координатами и размерами, а проверки, такие как beo.Create и beo.IsCanvasCreated(), вернули значение true. Это указывает на то, что интеграция между пользовательским классом monitor и графической средой стабильна. Кроме того, ожидаемое название холста было правильно подобрано, что обеспечило надлежащую идентификацию ресурса. В диагностическом отчете также были перечислены связанные объекты, включая скрытые кнопки быстрых ордеров BUY и SELL, что показывает, что система стабильно работает со своим основным компонентом дисплея и управляет вспомогательными элементами управления.

С функциональной точки зрения логи инициализации демонстрируют, что движок BEO надежно переходит в рабочее состояние и что кнопки тестирования быстрых ордеров генерируются должным образом, хотя и скрыты на данном этапе. Поступление OnTick в режиме реального времени подтверждает возможность сбора и отображения рыночных данных на мониторе, а цены bid и ask транслируются в режиме реального времени на область canvas.

Это подтверждает концепцию, что теперь можно визуализировать работу бэкенд-советника в его собственной пользовательской среде, а не полагаться исключительно на текстовые логи терминала. Несмотря на то, что основа заложена прочная, будущие улучшения должны быть направлены на усовершенствование уровня представления, улучшение взаимодействия с элементами управления быстрыми ордерами и расширение области диагностической обратной связи за счет включения более сложных операций советника. Это знаменует собой многообещающее начало, подтверждающее правильность архитектуры и предлагающее надежную платформу для итеративной разработки.

Заключение

Мы успешно воплотили концепцию BEO в жизнь, теперь холст отрисовывает в настраиваемых размерах и динамически отображает внутренние операции советника в режиме реального времени. На этом пути мы столкнулись с несколькими трудностями. Изначально видимость текста была плохой, потому что мы выбрали прозрачный цвет, который сливался с фоном; позже это было исправлено с помощью однотонного, более яркого цвета для большей четкости.

Выравнивание также оказалось непростой задачей — при первых попытках текст выходил за пределы левой границы. Переключившись на ALIGN_RIGHT, мы добились четкого представления, хотя обычно в текстовых редакторах требуется выравнивание по левому краю. Благодаря этим исправлениям отображение на графике стало функциональным и визуально согласованным, и, что самое главное, оно не является статичным: тик за тиком активно отображается внутренняя активность советника.

Результат подтверждает идею, но это всего лишь основа. Мы решили ключевую проблему, предоставив советнику собственное специализированное пространство для ведения лога, отделенное от переполненной вкладки "Experts" терминала, но при этом учитывая, что терминал предлагает удобное копирование лога для целей отладки. В настоящее время мы можем визуализировать важные детали серверной части непосредственно на графике, но будущие усовершенствования могут расширить функциональность, обеспечить более полную настройку данных лога, расширенную фильтрацию или даже интерактивное копирование логов с холста. Работа здесь закладывает прочную основу, но есть место и для роста. Представленный в такой форме проект показывает, что возможно, однако будущие обновления могут значительно продвинуть его вперед.

Исследуйте, экспериментируйте и расширяйте эту идею в собственных проектах. Краткая таблица с ключевыми уроками и прилагаемый код дополняют это обсуждение — ваши комментарии и вклады помогут определить, что будет дальше.

Основные уроки

Урок	Описание:
Разработка пользовательских классов на MQL5	Создание такого специального класса, как CBEOMonitor, демонстрирует, как сложную функциональность можно инкапсулировать в модули многократного использования, улучшая удобство обслуживания и масштабируемость торговых систем.
Интеграция пользовательских классов и встроенных библиотечных классов MQL5	Сочетание пользовательских классов со стандартными библиотечными компонентами, такими как CTrade и CButton, демонстрирует гибкость MQL5 в сочетании пользовательских функций с надежной встроенной функциональностью.
Интеграция Canvas	Использование пользовательского холста позволяет советникам визуально отображать внутренние операции на графике, создавая выделенное пространство для мониторинга, не зависящее от окна лога терминала.
Управление цветом и видимостью	Выбор подходящих однотонных цветов вместо прозрачных важен для обеспечения наглядности, гарантируя, что диагностический текст и данные останутся видимыми на разных фоновых диаграммах.
Выравнивание текста	Точное выравнивание предотвращает перестановку или неправильное расположение отображаемого текста. Понимание того, как ведут себя значения ALIGN_LEFT, ALIGN_RIGHT и смещения графика, помогает поддерживать ясность представления.
Резервные механизмы	Реализация меток в качестве запасного варианта при сбое создания холста обеспечивает надежность. Это обеспечивает, по крайней мере, базовую обратную связь о состоянии, даже если дополнительные ресурсы не могут быть инициализированы.
Диагностика в режиме реального времени	Регистрируя тиковые данные, изменения спреда и торговые сигналы непосредственно на графике, советник создает живой цикл обратной связи, который упрощает отладку и проверку работоспособности.

Вложения

Название файла	Версия	Описание
BEOMonitor.mqh	1.00	Базовый класс мониторинга, который управляет холстом, логами и визуальной диагностикой внутренних операций советника. Предоставляет повторно используемые методы для рисования, ведения лога и структурированного вывода на графике.
BEODemoEA.mq5	1.00	Демонстрационный советник, интегрирующий CBEOMonitor для демонстрации ведения лога в реальном времени, визуализации диагностики и тестирования быстрых ордеров с настраиваемыми элементами управления.

Перевод с английского произведен MetaQuotes Ltd.
Оригинальная статья: https://www.mql5.com/en/articles/19649

Прикрепленные файлы |

Загрузить ZIP

BEOMonitor.mqh (48.41 KB)

BEODemoEA.mq5 (27.26 KB)

Предупреждение: все права на данные материалы принадлежат MetaQuotes Ltd. Полная или частичная перепечатка запрещена.

Данная статья написана пользователем сайта и отражает его личную точку зрения. Компания MetaQuotes Ltd не несет ответственности за достоверность представленной информации, а также за возможные последствия использования описанных решений, стратегий или рекомендаций.

Другие статьи автора

Перейти к обсуждению на форуме трейдеров

Нейросети в трейдинге: Модели многократного уточнения прогнозов (Окончание)

Представляем фреймворк RAFT — мощный инструмент для анализа и прогнозирования финансовых временных рядов. Его гибкая и оптимизированная архитектура обеспечивает точность прогнозов, стабильность работы и ускоряет обработку данных. RAFT снижает риски ошибок и облегчает создание эффективных торговых стратегий.

Моделирование рынка (Часть 05): Создание класса C_Orders (II)

В данной статье я расскажу, как Chart Trade вместе с советником будет обрабатывать запрос на закрытие всех открытых позиций пользователя. Звучит просто, но есть несколько осложняющих моментов, и нужно знать, как управлять ими.

Моделирование рынка (Часть 06): Перенос данных из MetaTrader 5 в Excel

Многим, особенно тем, кто не занимается программированием, очень сложно передавать информацию между MetaTrader 5 и другими программами. Одной из таких программ является Excel. Многие люди используют Excel для управления и контроля своих рисков, так как это очень хорошая программа, которую легко освоить даже тем, кто не является программистом на VBA. Далее мы рассмотрим, как установить связь между MetaTrader 5 и Excel (очень простой метод).

Нейросети в трейдинге: Модели многократного уточнения прогнозов (Основные компоненты)

В статье мы раскрываем внутреннюю механику фреймворка RAFT — одного из самых точных и элегантных подходов к анализу динамических процессов. Мы шаг за шагом адаптируем его идею итеративного уточнения под финансовые временные ряды, создавая прочный фундамент для будущей модели. Читателя ждёт живое погружение в архитектуру, где каждый компонент имеет свой смысл и функцию.